为Access导入(XSLT 1.0)定义良好的平面XML的分组 [英] Grouping of a well defined flat XML for Access import (XSLT 1.0)

问题描述

我有一个本地会计系统的输出，该输出由一个信封标记和只是重复的字段序列组成，但未分组.我没有使用XSL的经验，但是一直在尝试为此找到解决方案，并且找到了适用于XSLT 2.0的解决方案.不幸的是，Access 2007似乎只接受XSLT 1.0转换.

I have an output from our local accounting system, which consists of an envelope tag and just a repeated sequence of the fields, but not grouped. I have no prior experience in XSL but have been trying to find a solution for this and have found a solution, which works for XSLT 2.0. Unfortunately, it seems that Access 2007 only accepts XSLT 1.0 transformations.

您能帮我找到一个行之有效的XSLT 1.0解决方案吗?

Can you please help me find a XSLT 1.0 solution that works?

这是原始平面XML中的两条记录:

These are two records in the original flat XML:

<ENVELOPE>
  <DBCFIXED>  <DBCDATE>1-Apr-2011</DBCDATE>
    <DBCPARTY></DBCPARTY>
  </DBCFIXED>
  <DBCVCHTYPE>Stock Journal</DBCVCHTYPE>
  <DBCVCHNO>1</DBCVCHNO>
  <DBCVCHREF></DBCVCHREF>
  <DBCSTNO></DBCSTNO>
  <DBCSERVICETAXNO></DBCSERVICETAXNO>
  <DBCPANNO></DBCPANNO>
  <DBCCSTNO></DBCCSTNO>
  <DBCNARR>Opening balance transfar</DBCNARR>
  <DBCQTY>0.000 Kg</DBCQTY>
  <DBCRATE></DBCRATE>
  <DBCAMOUNT></DBCAMOUNT>
  <DBCADDLCOST></DBCADDLCOST>
  <DBCGROSSAMT></DBCGROSSAMT>
  <DBCLEDAMT></DBCLEDAMT>
  <DBCFIXED>  <DBCDATE></DBCDATE>
    <DBCPARTY>ME KN YARN BL 1</DBCPARTY>
  </DBCFIXED>
  <DBCVCHTYPE></DBCVCHTYPE>
  <DBCVCHNO></DBCVCHNO>
  <DBCVCHREF></DBCVCHREF>
  <DBCSTNO></DBCSTNO>
  <DBCSERVICETAXNO></DBCSERVICETAXNO>
  <DBCPANNO></DBCPANNO>
  <DBCCSTNO></DBCCSTNO>
  <DBCNARR></DBCNARR>
  <DBCQTY>0.150 Kg</DBCQTY>
  <DBCRATE>566.00/Kg</DBCRATE>
  <DBCAMOUNT>-84.90</DBCAMOUNT>
  <DBCADDLCOST></DBCADDLCOST>
  <DBCGROSSAMT></DBCGROSSAMT>
  <DBCLEDAMT></DBCLEDAMT>
</ENVELOPE>

对于导入Access，我需要将数据分组为从DBCFIXED开始直到下一个DBCFIXED的记录.像这样:

For the import into Access, I need the data to be grouped into records starting with DBCFIXED until the next DBCFIXED. Something like:

<InventoryDaybook>
  <record>
    <DBCFIXED>  
      <DBCDATE>1-Apr-2011</DBCDATE>
      <DBCPARTY/>
    </DBCFIXED>
    <DBCVCHTYPE>Stock Journal</DBCVCHTYPE>
    <...></...>
  </record>
  <record>
    <...></...>
  </record>
/<InventoryDaybook>

有效的XSLT 2.0代码是

The XSLT 2.0 code that works is

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/*">
  <InventoryDaybook>
    <xsl:for-each-group select="*" group-starting-with="DBCFIXED">
      <record>
        <xsl:copy-of select="current-group()"/>
      </record>
    </xsl:for-each-group>
  </InventoryDaybook>
</xsl:template>
</xsl:stylesheet>

使用XSL可以完成的操作令人惊讶，但是我的知识似乎太少了..在此先感谢您的帮助和理解.

It is amazing what can be done with XSL but my knowledge seems just too little.. Thanks in advance for your help and your understanding.

推荐答案

这可以在XSLT1.0中通过 xsl:key 来实现，该匹配非DBCFIXED元素并使用前面的第一个DBCFIXED元素作为键

This could be achieved in XSLT1.0 by means of a xsl:key, that matches non-DBCFIXED elements, and uses the first preceding DBCFIXED element as the key

<xsl:key 
    name="records" 
    match="ENVELOPE/*[not(self::DBCFIXED)]" 
    use="generate-id(preceding-sibling::DBCFIXED[1])" />

然后，当您匹配各个 DBCFIXED 元素时，您可以轻松地查找组成记录的关联元素

Then, when you match the individual DBCFIXED elements, you can easily look-up the associated elements that make up the record

<xsl:apply-templates select="key('records', generate-id())" />

这是完整的XLST

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="records" match="ENVELOPE/*[not(self::DBCFIXED)]" use="generate-id(preceding-sibling::DBCFIXED[1])" />
   <xsl:template match="/ENVELOPE">
      <InventoryDaybook>
         <xsl:apply-templates select="DBCFIXED" />
      </InventoryDaybook>
   </xsl:template>

   <xsl:template match="DBCFIXED">
      <record>
         <xsl:copy-of select="." />
         <xsl:apply-templates select="key('records', generate-id())" />
      </record>
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

应用于输入XML时，将输出以下内容

When applied to the input XML, the following is output

<InventoryDaybook>
   <record>
      <DBCFIXED>
         <DBCDATE>1-Apr-2011</DBCDATE>
         <DBCPARTY/>
      </DBCFIXED>
      <DBCVCHTYPE>Stock Journal</DBCVCHTYPE>
      <DBCVCHNO>1</DBCVCHNO>
      <DBCVCHREF/>
      <DBCSTNO/>
      <DBCSERVICETAXNO/>
      <DBCPANNO/>
      <DBCCSTNO/>
      <DBCNARR>Opening balance transfar</DBCNARR>
      <DBCQTY>0.000 Kg</DBCQTY>
      <DBCRATE/>
      <DBCAMOUNT/>
      <DBCADDLCOST/>
      <DBCGROSSAMT/>
      <DBCLEDAMT/>
   </record>
   <record>
      <DBCFIXED>
         <DBCDATE/>
         <DBCPARTY>ME KN YARN BL 1</DBCPARTY>
      </DBCFIXED>
      <DBCVCHTYPE/>
      <DBCVCHNO/>
      <DBCVCHREF/>
      <DBCSTNO/>
      <DBCSERVICETAXNO/>
      <DBCPANNO/>
      <DBCCSTNO/>
      <DBCNARR/>
      <DBCQTY>0.150 Kg</DBCQTY>
      <DBCRATE>566.00/Kg</DBCRATE>
      <DBCAMOUNT>-84.90</DBCAMOUNT>
      <DBCADDLCOST/>
      <DBCGROSSAMT/>
      <DBCLEDAMT/>
   </record>
</InventoryDaybook>

这篇关于为Access导入(XSLT 1.0)定义良好的平面XML的分组的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！