如何检查ole-db的oracle provider的版本. OraOLEDB.Oracle提供程序 [英] How to check the version of oracle provider for ole-db. OraOLEDB.Oracle provider

问题描述

如何检查ole-db的oracle provider的版本. Windows 10和Windows 7上的OraOLEDB.Oracle提供程序?

How to check the version of oracle provider for ole-db. OraOLEDB.Oracle provider on windows 10 and windows 7 ?

推荐答案

例如，您可以使用工具 RegDllView .搜索"OraOLEDB"，结果可能是这样的:

You can use for example tool RegDllView. Search for "OraOLEDB", result could be this:

一种更简单的方法是导航到您的ORACE_HOME\bin目录并找到文件OraOLEDB??.dll.用鼠标右键单击版本->属性->详细信息检查版本.

A simpler approach would be this navigate to your ORACE_HOME\bin directory and locate file OraOLEDB??.dll. Check version with right-hand mouse click -> Properties -> Details.

但是，您仅获得文件的版本，并不一定意味着该DLL也已注册并可以使用.

However, you just get the version of the file, it does not necessarily mean that this DLL is also registered and ready for use.

或使用此VBScript:

Or use this VBScript:

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

OLE DB提供程序可能存在于32位或/和64位中，因此您可以执行两次脚本:

OLE DB provider may exist in 32-bit or/and in 64-bit, so you may execute the script twice:

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs

这篇关于如何检查ole-db的oracle provider的版本. OraOLEDB.Oracle提供程序的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！