使用VBS更新注册表 [英] Update registry using VBS
问题描述
我正在尝试使用VBScript更新PC上的法律标题.到目前为止,我已经能够读取值,但是似乎无法获取它来写入任何值.运行脚本时我没有收到错误,只是没有任何改变.这是我第一次这样做,经验有限;任何见识将不胜感激:
I'm trying to update the legal caption on our PCs using a VBScript. So far, I've been able to read values but I can't seem to get it to write any values. I don't get an error when I run the script, it just doesn't change anything. It's the first time I'm doing this and I have limited experience; any insight would be appreciated:
Dim objShell
Dim strMessage, strWelcome, strWinLogon
' Set the string values
strWelcome = "legalnoticecaption"
strMessage = "did this work"
strWinLogon = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System\"
' Create the Shell object
Set wshShell = CreateObject("WScript.Shell")
'Display string Values
Wscript.Echo "key to update: " & strWelcome
Wscript.Echo "key value to enter: " & strMessage
Wscript.Echo "Existing key value: " & wshShell.RegRead(strWinLogon & strWelcome)
' the crucial command in this script - rewrite the registry
wshShell.RegWrite strWinLogon & strWelcome, strMessage, "REG_SZ"
' Did it work?
Wscript.Echo "new key value: " & wshShell.RegRead(strWinLogon & strWelcome)
set wshShell = Nothing
注意:这些是目前的测试值.
NOTE: These are testing values at the moment.
推荐答案
您的脚本似乎没有错误.但是,由cscript 28416995.vbs
启动会返回下一个错误(其中22 = WshShell.RegWrite
行):
Your script seems to be bug-less. However, launched by cscript 28416995.vbs
returns next error (where 22 = WshShell.RegWrite
line):
28416995.vbs(22,1)WshShell.RegWrite:注册表项"HKLM \ SOFTWARE \ Microsoft \ Windows \ CurrentVersion \ Policies \ System \ legalnoticecaption"中的无效根.
28416995.vbs(22, 1) WshShell.RegWrite: Invalid root in registry key "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System\legalnoticecaption".
这不是无效的根,类似于访问被拒绝,而是因为写入HKLM
需要提升的特权(或以管理员身份运行)
It's not invalid root, it's something like access denied rather because writing to HKLM
requires elevated privileges (or run as administrator).
注意:
- 您应同时更改
LegalNoticeText
值和LegalNoticeCaption
值. - 在
HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\
注册表项下,两个值也都存在.在这种情况下(如果计算机未连接到域或禁用了组策略)应该在下一个脚本中工作.
- You should change
LegalNoticeText
value together withLegalNoticeCaption
one. - Under the
HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\
registry key there both values reside as well. For this case (if a computer is not connected to a domain or with group policy disabled) should work next script.
以管理员身份运行:
option explicit
On Error Goto 0
Dim wshShell
Dim strResult, strMessage, strWelcome, strWinLogon, strWinLog_2, strWinLTxt
strResult=Wscript.ScriptName
' Set the string values
strWinLTxt = "legalnoticetext"
strWelcome = "legalnoticecaption"
strMessage = "did this work"
strWinLogon = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon\"
strWinLog_2 = "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System\"
' Create the Shell object
Set wshShell = CreateObject("WScript.Shell")
'Display string Values
' continue execution if requested registry values not present
On Error Resume Next
strResult = strResult & vbNewLine & "Existing Caption Policies: " _
& wshShell.RegRead(strWinLog_2 & strWelcome)
strResult = strResult & vbNewLine & "Existing Text Policies: " _
& wshShell.RegRead(strWinLog_2 & strWinLTxt)
On Error Goto 0
strResult = strResult & vbNewLine & "Existing Caption Winlogon: " _
& wshShell.RegRead(strWinLogon & strWelcome)
strResult = strResult & vbNewLine & "Existing Text Winlogon: " _
& wshShell.RegRead(strWinLogon & strWinLTxt)
strResult = strResult & vbNewLine
strResult = strResult & vbNewLine & "key to update: " & strWelcome
strResult = strResult & vbNewLine & "key value to enter: " & strMessage
' the crucial command in this script - rewrite the registry
wshShell.RegWrite strWinLogon & strWelcome, strMessage, "REG_SZ"
wshShell.RegWrite strWinLogon & strWinLTxt, UCase( strMessage), "REG_SZ"
' Did it work?
strResult = strResult & vbNewLine
strResult = strResult & vbNewLine _
& "new key Capt. value: " & wshShell.RegRead(strWinLogon & strWelcome)
strResult = strResult & vbNewLine _
& "new key Text value: " & wshShell.RegRead(strWinLogon & strWinLTxt)
Wscript.Echo strResult
set wshShell = Nothing
这篇关于使用VBS更新注册表的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!