将范围从Excel复制到Outlook时如何保留格式 [英] How to keep formats when I copy a range from Excel to outlook

问题描述

您好，我有一个Excel表格，其中的某些格式为 10(红色)-> 15(绿色)，但是最后我松开了我所有的格式精益求精.我使用下一个代码从范围发送和通过电子邮件发送到Outlook

Hello i have an Excel table with some formats 10(Red) -> 15(Green), but at the end I loose all the formats i have in my excel. I use the next code to send and email from a range to outlook

Sub email()

    Dim OutApp As Object
    Dim OutMail As Object
    Dim Fname As String
    Dim hoja As String
    Dim rng As Range
    Dim celdas As String

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    Set rng = Range("C3:Q22")
    On Error Resume Next
    With OutMail

        .To = "juan"
        .CC = "Maria"
        .BCC = ""
        .Subject = "XXXX"
        .HTMLBody = "Hey" & RangetoHTML(rng)

        .Display   'or use .Display
    End With
    On Error GoTo 0

    'Kill Fname
    Set OutMail = Nothing
    Set OutApp = Nothing

End Sub

和下一个功能，我从下一个链接如何从excel发送邮件

and the next function, I copied from the next link How to send mails from excel

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2010
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

推荐答案

好，当我粘贴值时，我在rangetoHtml()中找到了制作方法的方法:

Ok I found how to made it, in rangetoHtml(), when is pasting the values I changed the code for:

    With TempWB.Sheets(1)
        '.Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial
        '.Cells(1).PasteSpecial xlPasteValues, , False, False
        '.Cells(1).PasteSpecial xlPasteFormats, , False, False
        '.Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

如果我只是复制并粘贴，我不会丢失任何格式.

Becase If I made just a copy and paste I dont lost any format.

这篇关于将范围从Excel复制到Outlook时如何保留格式的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！