SVN预提交钩子以确保.csproj中引用的所有文件都已版本化? [英] SVN pre-commit hook to ensure all files referenced in .csproj are versioned?
本文介绍了SVN预提交钩子以确保.csproj中引用的所有文件都已版本化?的处理方法,对大家解决问题具有一定的参考价值,需要的朋友们下面随着小编来一起学习吧!
问题描述
有时,我们将C#项目文件提交到SVN,该文件引用了我们忘记添加到SVN的文件.是否有任何预提交的钩子脚本可以解析.csproj文件,如果它引用了未版本控制的文件,则拒绝提交?
Occasionally we commit a C# project file to SVN that references files we forgot to add to SVN. Are there any pre-commit hook scripts out there that parse the .csproj file and reject the commit if it references unversioned files?
推荐答案
#!/usr/bin/perl
# Checks for source files which have been added to a csproj in a commit
# but haven't themselves been committed.
use Modern::Perl;
use warnings FATAL => 'syntax';
use File::Basename qw(basename);
use XML::Simple;
die "usage: $0 repo transaction\n" if @ARGV != 2;
my $opt = "-t"; # -r for testing
my ($repos, $txn) = @ARGV;
# If you really, really want to add a file to the proj and
# not commit it, start your commit message with a !
my @info = `svnlook info $opt $txn "$repos"`;
exit 0 if ($info[3] =~ /\A!/);
my @lines = `svnlook changed $opt $txn "$repos"`;
my @projects = grep { /\AU/ }
grep { /[.]csproj\z/ }
map { chomp; $_ } @lines;
my @filelist = `svnlook tree $opt $txn "$repos" --full-paths`;
my %present;
foreach (@filelist) {
chomp;
$present{$_} = 1;
}
foreach (@projects) {
m"\AU.\s\s([\w/.]+/)([\w]+\.csproj)\z" or die "bad line $_";
my ($path, $proj) = ($1, $2);
my $projfile = `svnlook cat $opt $txn "$repos" $path/$proj`;
my $xml = XMLin($projfile);
# Tested with VS 2012 project files
my @includes = @{$xml->{ItemGroup}->[1]->{Compile}};
# All the source files in the csproj
my @filenames = map {$_->{Include}} @includes;
foreach (@filenames) {
# ignore "../etc", not below the project file in the tree
next if /\A[.][.]/;
# if you have files that are in the proj but shouldn't be committed
# eg some generated files, add checks for them here
# next if /MyGeneratedFile.cs\z/;
my $file = $path . $_;
# The csproj file speaks windows paths, but svn will output unix ones
$file =~ tr|\\|/|;
if (!defined $present{$file}) {
die "The file $file is included in the project $path\\$proj, but is not present in the tree, did you forget to commit it?";
}
}
}
这篇关于SVN预提交钩子以确保.csproj中引用的所有文件都已版本化?的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!
查看全文