如何使用批处理获取最新版本号 [英] How to get latest version number using batch

问题描述

我有一个包含多个子目录的文件夹

I have a folder that contains multiple sub-directories

版本格式为[major].[minor].[update][phase][build]，如1.0.0d0.有效相位为d(ev)，a(lpha)，b(eta)，f(inal)，请注意d< < b< f.

The version format is [major].[minor].[update][phase][build], like 1.0.0d0. And valid phases are d(ev), a(lpha), b(eta), f(inal), please note d < a < b < f.

我想使用批处理脚本获取最新的版本号16.0.0a2.我写了这样的代码，但是不起作用，因为子目录是按字母顺序排序的.因此它将给出结果16.0.0d24.

I'd like to get the latest version number which is 16.0.0a2 using batch script. I write such codes, but doesn't work, because the sub-directories are sorted by alphabetical order. So it will give a result 16.0.0d24.

SET BASEPATH=.....
SET TEMPFILE=%TEMP%\%~n0%RANDOM%
echo get latest export.
DIR /A:D /B /ON "%BASEPATH%" > "%TEMPFILE%"
FOR /F "usebackq delims=;" %%I IN ("%TEMPFILE%") DO (SET LATEST_VERSION=%%I)
echo LATEST_VERSION

推荐答案

以下脚本可满足您的需求:

The following script does what you want:

@echo off
setlocal EnableExtensions EnableDelayedExpansion

set "LOC=%~1"
if not defined LOC set "LOC=."
set /A "PADV=100, PADB=10000"
set "SRCH=d" & set "REPL=@"

for /F "tokens=1,2,* delims=." %%A in ('
    dir /B /A:D /O:D /T:C "%LOC%" ^| ^
        findstr /I /R "[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*[dabf][0-9][0-9]*"
') do (
    set /A "MAJOR=%%A+PADV, MINOR=%%B+PADV"
    for /F "tokens=1,* delims=DdAaBbFf" %%E in ("%%C") do (
        set /A "FIX=%%E+PADV, BUILD=%%F+PADB"
        set "PHASE=%%C" & set "PHASE=!PHASE:*%%E=!" & set "PHASE=!PHASE:~,1!"
        set "PHASE=!PHASE:%SRCH%=%REPL%!"
    )
    set "VERSION[!MAJOR!.!MINOR!.!FIX!!PHASE!!BUILD!]=%%A.%%B.%%C"
)

for /F "tokens=2 delims==" %%V in ('2^> nul set VERSION[') do (
    set "LATEST=%%V"
    echo(%%V
)
if defined LATEST echo Latest: & echo(%LATEST%

endlocal
exit /B

基本概念是修改版本号，以便(字母)数字排序提供与字母排序相同的结果.这可以通过在版本号的每个数字部分增加一个数字来实现，以便每个数字始终具有相同的数字.另外，由于相位图的优先级不是按字母顺序排列的，因此可以进行足够的替换.

The basic concept is to adapt the version numbers so that (alpha-)numeric sorting provides the same result as alphabetic sorting. This can be achieved by adding a great number to every numeric part of the version numbers so that each one always has got the same number of digits. In addition, since the priority of the phase figure is not of alphabetical order, adequate replacements are done.

核心思想摘自此答案，并记入

The core idea is taken from this answer and is credited to Aacini.

这篇关于如何使用批处理获取最新版本号的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！