Delphi XE和ZLib问题（II） [英] Delphi XE and ZLib Problems (II)

问题描述

我所有人，
我记得你关于ZLib问题的问题...。
Delphi XE和ZLib问题

David Heffernan的出色回答让我感到困惑（再次感谢@David）...

David Heffernan put me on the way with his excellent answer (Thanks again @David)...

总结答案...
用于压缩器的流如下所示：string-> UTF-8字节->压缩字节-> base64字符串。
显然，您可以反向箭头进行解压缩。

Summarizing the answer ... "This flow for the compressor looks like this: string -> UTF-8 bytes -> compressed bytes -> base64 string. Obviously you reverse the arrows to decompress."

我不知道我必须将其发布在同一帖子中，还是必须附加一个新的问题。 ..

I don't know I must post it in the same post or i must append a new question like this...

嗯，我上周末在工作...

Well, I was working last weekend...

我遵循了流程字符串-> UTF -8字节->压缩字节-> base64字符串

I followed the flow string -> UTF-8 bytes -> compressed bytes -> base64 string

这是compress函数，可以正常工作...

This is the compress function and it works...

function CompressStrToCode64Str(const aText: string; aCompressionLevel: TZCompressionLevel): string;
var
  strStreamIN,
  strStreamOUT: TStringStream;
begin
  result := '';
  /// Putting the string received to a Stream.
  strStreamIN := TStringStream.Create(aText, TEncoding.UTF8);
  try
    /// Creating the output stream for compression.
    strStreamOUT := TStringStream.Create('', TEncoding.UTF8);
    try
      /// Compressing streamIN to streamOUT
      ZCompressStream(strStreamIN, strStreamOUT, aCompressionLevel);
      /// Encoding to base64 for string handling.
      result := string(EncodeBase64(strStreamOUT, strStreamOUT.Size));
    finally
      strStreamOUT.Free;
    end;
  finally
    strStreamIN.Free;
  end;
end;

这是Uncompress函数...但是它不起作用...（返回空

and this is the Uncompress functions... but it doesn't works... (returns empty string)

function TForm1.Code64StrToUncompressStr(Const aText: string): string;
var
  strStreamIN,
  strStreamOUT: TStringStream;
  data: TBytes;
begin
  result := '';
  /// Creating the input stream.
  strStreamIN := TStringStream.Create('', TEncoding.UTF8);
  try
    /// Decoding base64 of received string to a TBytes
    data := DecodeBase64(ansistring(aText));
    /// Putting the TBytes to a Stream
    strStreamIN.Write(data[0], Length(data));
    /// Creating uncompressed stream
    strStreamOUT := TStringStream.Create('', TEncoding.UTF8);
    try
      /// Decompressing streamIN to StreamOUT
      ZDeCompressStream(strStreamIN, strStreamOUT);
      result := strStreamOUT.DataString;
    finally
      strStreamOUT.Free;
    end;
  finally
    strStreamIN.Free;
  end;
end;

有些想法为什么解压缩功能不起作用。它返回一个空字符串。
TIA，请耐心等待。

Some idea why doesn't work the uncompress function. It returns an empty string. TIA for your patience.

推荐答案

这就是我的想法：

{$APPTYPE CONSOLE}

uses
  SysUtils, Classes, ZLib, EncdDecd;

function CompressAndEncodeString(const Str: string): string;
var
  Utf8Stream: TStringStream;
  Compressed: TMemoryStream;
  Base64Stream: TStringStream;
begin
  Utf8Stream := TStringStream.Create(Str, TEncoding.UTF8);
  try
    Compressed := TMemoryStream.Create;
    try
      ZCompressStream(Utf8Stream, Compressed);
      Compressed.Position := 0;
      Base64Stream := TStringStream.Create('', TEncoding.ASCII);
      try
        EncodeStream(Compressed, Base64Stream);
        Result := Base64Stream.DataString;
      finally
        Base64Stream.Free;
      end;
    finally
      Compressed.Free;
    end;
  finally
    Utf8Stream.Free;
  end;
end;

function DecodeAndDecompressString(const Str: string): string;
var
  Utf8Stream: TStringStream;
  Compressed: TMemoryStream;
  Base64Stream: TStringStream;
begin
  Base64Stream := TStringStream.Create(Str, TEncoding.ASCII);
  try
    Compressed := TMemoryStream.Create;
    try
      DecodeStream(Base64Stream, Compressed);
      Compressed.Position := 0;
      Utf8Stream := TStringStream.Create('', TEncoding.UTF8);
      try
        ZDecompressStream(Compressed, Utf8Stream);
        Result := Utf8Stream.DataString;
      finally
        Utf8Stream.Free;
      end;
    finally
      Compressed.Free;
    end;
  finally
    Base64Stream.Free;
  end;
end;

var
  EncodedAndCompressed: AnsiString;

begin
  EncodedAndCompressed := CompressAndEncodeString('ZLib, Utf-8, compression test');
  Writeln(EncodedAndCompressed);
  Writeln(DecodeAndDecompressString(EncodedAndCompressed));
  Readln;
end.

输出

eJyL8slM0lEILUnTtdBRSM7PLShKLS7OzM9TKEktLgEAjjwKMA==
ZLib, Utf-8, compression test

，当您包含base64时，它并不是真正的压缩。可能是使用较大的输入字符串进行压缩。这就是为什么我认为您最好传输二进制文件，正如我在上一个问题中所解释的。

As you can see, by the time you include base64, it is not really compression. It might be compression with a larger input string. That's why I think you are better to transmit binary, as I explained in your previous question.

这篇关于Delphi XE和ZLib问题（II）的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！