如何在Inno Setup中使用BASS库使音频静音(更改音量) [英] How to mute audio (change volume) with BASS library in Inno Setup

问题描述

此代码来自低音音频库打开/关闭按钮，它执行暂停"，如何将其更改为静音" ?

This code from Bass Audio Library on/off Button does "Pause", how to change it to "Mute"?

我应该改变什么?

const  
  BASS_SAMPLE_LOOP = 4;
  BASS_ACTIVE_STOPPED = 0;
  BASS_ACTIVE_PLAYING = 1;
  BASS_ACTIVE_STALLED = 2;
  BASS_ACTIVE_PAUSED  = 3;
  BASS_UNICODE = $80000000;
  BASS_CONFIG_GVOL_STREAM = 5;
const
  #ifndef UNICODE
    EncodingFlag = 0;
  #else
    EncodingFlag = BASS_UNICODE;
  #endif
type
  HSTREAM = DWORD;

function BASS_Init(device: LongInt; freq, flags: DWORD; 
  win: HWND; clsid: Cardinal): BOOL;
  external 'BASS_Init@files:bass.dll stdcall';
function BASS_StreamCreateFile(mem: BOOL; f: string; offset1: DWORD; 
  offset2: DWORD; length1: DWORD; length2: DWORD; flags: DWORD): HSTREAM;
  external 'BASS_StreamCreateFile@files:bass.dll stdcall';
function BASS_Start: BOOL;
  external 'BASS_Start@files:bass.dll stdcall';
function BASS_Pause: BOOL;
  external 'BASS_Pause@files:bass.dll stdcall';
function BASS_ChannelPlay(handle: DWORD; restart: BOOL): BOOL; 
  external 'BASS_ChannelPlay@files:bass.dll stdcall';
function BASS_SetConfig(option: DWORD; value: DWORD ): BOOL;
  external 'BASS_SetConfig@files:bass.dll stdcall';
function BASS_ChannelIsActive(handle: DWORD): DWORD;
  external 'BASS_ChannelIsActive@files:bass.dll stdcall';
function BASS_Free: BOOL;
  external 'BASS_Free@files:bass.dll stdcall';

var
  SoundStream: HSTREAM;
  SoundCtrlButton: TNewButton;

procedure SoundCtrlButtonClick(Sender: TObject);
begin
  case BASS_ChannelIsActive(SoundStream) of
    BASS_ACTIVE_PLAYING: 
    begin
      if BASS_Pause then
        SoundCtrlButton.Caption := 
          ExpandConstant('{cm:SoundCtrlButtonCaptionSoundOn}');
    end;
    BASS_ACTIVE_PAUSED: 
    begin
      if BASS_Start then
        SoundCtrlButton.Caption :=
          ExpandConstant('{cm:SoundCtrlButtonCaptionSoundOff}');
    end;
  end;
end;

procedure InitializeWizard;
begin
  ExtractTemporaryFile('tune.mp3');
  if BASS_Init(-1, 44100, 0, 0, 0) then
  begin
    SoundStream := BASS_StreamCreateFile(False, 
      ExpandConstant('{tmp}\tune.mp3'), 0, 0, 0, 0, 
      EncodingFlag or BASS_SAMPLE_LOOP);
    BASS_SetConfig(BASS_CONFIG_GVOL_STREAM, 2500);
    BASS_ChannelPlay(SoundStream, False);

    SoundCtrlButton := TNewButton.Create(WizardForm);
    SoundCtrlButton.Parent := WizardForm;
    SoundCtrlButton.Left := 8;
    SoundCtrlButton.Top := WizardForm.ClientHeight - 
      SoundCtrlButton.Height - 8;
    SoundCtrlButton.Width := 40;
    SoundCtrlButton.Caption :=
      ExpandConstant('{cm:SoundCtrlButtonCaptionSoundOff}');
    SoundCtrlButton.OnClick := @SoundCtrlButtonClick;
  end;
end;

procedure DeinitializeSetup;
begin
  BASS_Free;
end;

推荐答案

要控制音量，请使用

To control volume level, use the BASS_SetConfig with option set to:

为流"创建
• BASS_CONFIG_GVOL_STREAM ，例如使用 BASS_StreamCreateFile ;
为音乐"
• BASS_CONFIG_GVOL_MUSIC 创建的使用 BASS_MusicLoad .

• BASS_CONFIG_GVOL_STREAM for "stream", created e.g. using the BASS_StreamCreateFile;
• BASS_CONFIG_GVOL_MUSIC for "music", created e.g. using BASS_MusicLoad.

SoundCtrlButtonClick代替了您问题中同名函数的暂停/恢复实现.

The SoundCtrlButtonClick is replacement for the pause/resume implementation of the same-named function from your question.

var
  Muted: Boolean;

procedure SoundCtrlButtonClick(Sender: TObject);
begin
  if not Muted then
  begin
    if BASS_SetConfig(BASS_CONFIG_GVOL_STREAM, 0) then
    begin
      SoundCtrlButton.Caption := 'unmute'; 
      Muted := True;
    end;
  end
    else
  begin
    if BASS_SetConfig(BASS_CONFIG_GVOL_STREAM, 2500) then
    begin
      SoundCtrlButton.Caption := 'mute'; 
      Muted := False;
    end;
  end;
end;

这篇关于如何在Inno Setup中使用BASS库使音频静音(更改音量)的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！