展望2011年：添加一些消息到＆QUOT;等待回复＆QUOT;夹 [英] Outlook 2011: Adding some messages to "Waiting for reply" folder

问题描述

我的用例是，我要跟踪的一些消息我写响应。我的方法现在是等待从发送文件夹发送的消息，此举它的等待答复的文件夹，我在定期去了。

My use case is that I want to track for responses on some messages I write. My methodology now is to wait for the message to be sent the move it from the sent folder to the "Waiting for reply" folder which I go over periodically.

我正在寻找一种方式来自动完成这个。最好的是，如果我preSS的关键，这使得双方的Outlook发送邮件，并把它在等待文件夹中。例如，通过使用一个AppleScript

I'm looking for a way to automate this. Best would be if I press a key which makes Outlook both send the message and put it in the Waiting folder. E.g., by using an applescript.

另外，我还以为pressing一键将加我为BCC，并且还添加了 WF 的在邮件的底部字符串。再次，与AppleScript的。然后，当我发送的消息也将到达我的收件箱，我将有一个规则，将邮件移动到等待，如果它们包含 WF 的

Alternatively, I thought that pressing a key will add me as BCC, and also add a "WF" string at the bottom of the message. Again, with applescript. Then when I send the message it will also arrive at my Inbox where I'll have a rule to move messages to "Waiting" if they contain "WF"

推荐答案

我扩大从你的<一个脚本href=\"http://stackoverflow.com/questions/12170878/applescript-changes-to-outlook-messages-are-not-saved?rq=1\"标题=螺纹>其他线程这个位置：

I expanded the script from your other thread to this here:

tell application "Microsoft Outlook"
    -- Simple definition of target mail folder
    -- Works fine this way if only one folder with this name is available
    set waitingForReplyFolder to folder "Waiting for reply"

    -- bring Outlook to front
    activate

    -- remember the front window
    set theWindow to window 1

    -- check it's really draft
    if class of theWindow is not draft window then
        display dialog "Not a draft"
        return
    end if

    -- save the draft
    save theWindow

    -- get the id of the object of the draft window
    set myObjectID to id of (object of theWindow)

    -- close the message window
    close theWindow

    -- checking the message' subject
    set theSubject to subject of message id myObjectID

    -- send the message
    send message id myObjectID

    -- check and wait until Outlook has moved the mail to the sent folder
    -- move it to target folder after we have found it
    set mailFoundAndMoved to false
    repeat 20 times
        -- check the next 20 message ids
        repeat with idCounter from 1 to 20
            try
                set freshSentMail to outgoing message id (myObjectID + idCounter)
                -- check if the subject is the same (just to be safe)
                if subject of freshSentMail is equal to theSubject then
                    -- move the sent mail to the "waiting for reply" folder
                    move freshSentMail to waitingForReplyFolder
                    set mailFoundAndMoved to true
                    exit repeat
                end if
            on error errstr
            end try
        end repeat
        if mailFoundAndMoved then exit repeat
        delay 0.5
    end repeat

end tell

现在，你要进去看看如何触发这一点。打开一个新的消息，写的内容等，并运行此脚本。它会发送邮件，并将其移动到目标文件夹，刚过就出现在发送文件夹中。

Now you must just see how to trigger this. Open a new message, write the content etc. and run this script. It will send the mail and move it to your target folder, just after it appeared inside the sent folder.

干杯，
迈克尔/汉堡

Cheers, Michael / Hamburg

这篇关于展望2011年：添加一些消息到＆QUOT;等待回复＆QUOT;夹的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！