使用 Hash::Merge 将哈希与数组合并 [英] Merge hashes with arrays with Hash::Merge
本文介绍了使用 Hash::Merge 将哈希与数组合并的处理方法,对大家解决问题具有一定的参考价值,需要的朋友们下面随着小编来一起学习吧!
问题描述
我正在尝试使用 Hash::Merge 合并包含一个或多个数组的两个散列
.例如:
I am trying to merge two hashes which contains one or more arrays using Hash::Merge
. For example:
use strict;
use warnings;
use feature qw(say);
use Data::Dump qw(dump);
use Hash::Merge qw(merge);
my $h1 = { a => [ { aa => 1 }, 3 ] };
my $h2 = { a => [ { bb => 2 } ] };
my $hLeft = merge( $h1, $h2 );
my $hRight = merge( $h2, $h1 );
say " hLeft: " . dump($hLeft);
say " hRight: " . dump($hRight);
my $hDesired = { a => [ { aa => 1, bb => 2 }, 3 ] };
say "Desired: " . dump($hDesired);
这给出了输出:
hLeft: { a => [{ aa => 1 }, 3, { bb => 2 }] }
hRight: { a => [{ bb => 2 }, { aa => 1 }, 3] }
Desired: { a => [{ aa => 1, bb => 2 }, 3] }
如何使用 Hash::Merge
获得正确的输出?
How can I get the correct output using Hash::Merge
?
推荐答案
合并数组的默认行为是追加它们:
The default behavior for merging arrays is to append them:
sub { [ @{$_[0]}, @{$_[1]} ] },
要获得不同的行为,必须使用 Hash::Merge::specify_behavior
.
To get different behavior, one must use Hash::Merge::specify_behavior
.
下面的解决方案是LEFT_PRECEDENT,将数组元素合并到元素:
The following solution is LEFT_PRECEDENT, and merges arrays element to element:
use strict;
use warnings;
use feature qw(say);
use Data::Dump qw(dump);
use Hash::Merge qw(merge);
Hash::Merge::specify_behavior(
{ 'SCALAR' => {
'SCALAR' => sub { $_[0] },
'ARRAY' => sub { $_[0] },
'HASH' => sub { $_[0] },
},
'ARRAY' => {
'SCALAR' => sub { [ @{ $_[0] }, $_[1] ] },
'ARRAY' => sub {
my ( $left, $right ) = @_;
my @merged = @$left;
my @to_add = @$right;
for (@merged) {
last if !@to_add;
$_ = Hash::Merge::merge( $_, shift @to_add );
}
return [ @merged, @to_add ];
},
'HASH' => sub { [ @{ $_[0] }, values %{ $_[1] } ] },
},
'HASH' => {
'SCALAR' => sub { $_[0] },
'ARRAY' => sub { $_[0] },
'HASH' => sub { Hash::Merge::_merge_hashes( $_[0], $_[1] ) },
},
},
'My Behavior',
);
my $h1 = { a => [ { aa => 1 }, 3 ] };
my $h2 = { a => [ { bb => 2 } ] };
my $merged = merge( $h1, $h2 );
say "Merged: " . dump($merged);
输出:
Merged: { a => [{ aa => 1, bb => 2 }, 3] }
这篇关于使用 Hash::Merge 将哈希与数组合并的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!
查看全文