Perl 计算两个时间戳之间的差异 [英] Perl calculate difference between 2 timestamps
本文介绍了Perl 计算两个时间戳之间的差异的处理方法,对大家解决问题具有一定的参考价值,需要的朋友们下面随着小编来一起学习吧!
问题描述
我有 2 个带有以下时间戳的变量,并想了解它们之间的差异
I have 2 variables with the following time stamp and would like to get the difference between them
my $startdate = "2015/01/13 13:57:02.079-05:00";
my $enddate ="2015/01/13 13:59:02.079-05:00";
如何实现时差?
推荐答案
使用 DateTime,很简单
Using DateTime, it's simply
$edt->subtract_datetime_absolute($sdt)->in_units('nanoseconds') / 1e9
剩下的就是生成 DateTime 对象.为此,DateTime::Format::Strptime 几乎是完美的.
All that's left is generating the DateTime objects. For that, DateTime::Format::Strptime is almost perfect.
use DateTime::Format::Strptime qw( );
my $sts = "2015/01/13 13:57:02.079-05:00";
my $ets = "2015/01/13 13:59:02.079-05:00";
my $format = DateTime::Format::Strptime->new(
pattern => '%Y/%m/%d %H:%M:%S.%3N%z',
on_error => 'croak',
);
my $sdt = $format->parse_datetime( $sts =~ s/:(?=\d\d\z)//r );
my $edt = $format->parse_datetime( $ets =~ s/:(?=\d\d\z)//r );
my $diff = $edt->subtract_datetime_absolute($sdt)->in_units('nanoseconds') / 1e9;
printf("%.3f\n", $diff); # 120.000
如果您希望代码也能在 5.14 之前的 Perl 版本上运行,请替换
If you want the code to also run on Perl versions older than 5.14, replace
my $sdt = $format->parse_datetime( $sts =~ s/:(?=\d\d\z)//r );
my $edt = $format->parse_datetime( $ets =~ s/:(?=\d\d\z)//r );
与
s/:(?=\d\d\z)// for $sts, $ets;
my $sdt = $format->parse_datetime($sts);
my $edt = $format->parse_datetime($ets);
这篇关于Perl 计算两个时间戳之间的差异的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!
查看全文