如何在 vb.net 中闪烁/闪烁任务栏图标? [英] How to flash/blink taskbar icon in vb.net?
问题描述
我需要让我的 vb.net 应用程序能够在应用程序中收到通知时闪烁/闪烁以吸引用户的注意力.
I need to make my vb.net application be able to flash/blink to attract a user's attention when a notification is received within the application.
就像这张图片中的 DW 图标一样:
Like the DW icon does in this image:
我已经在谷歌上搜索了一段时间并尝试了各种代码示例,但都没有成功.
I've been Googling this for a while and have tried various code examples, all with no success.
这是我到目前为止所得到的:
Here's what I've got so far:
Public Class FlashWindow
Private Declare Function FlashWindow Lib "user32" (ByVal hwnd As Long, ByVal bInvert As Long) As Long
Shared Sub main()
FlashWindow(Me.Handle, 1)
End Sub
End Class
此代码立即抛出以下错误:
This code throws the following error straight away:
'Me' 仅在实例方法中有效
'Me' is valid only within an instance method
谁能告诉我我哪里出错了或者如何实现这一点?
Can anyone let me know where I'm going wrong or how to achieve this?
推荐答案
首先 Me
用于引用当前类.当该代码位于 Form 类中时,它具有属性 Handle
.在您的示例中,FlashWindow 类没有属性 Handle,因此无法编译.
Firstly Me
is used to reference the current class. When that code is in a Form class it has a property Handle
. In your example the FlashWindow class does not have a property Handle so this will not compile.
其次,我认为您对 API 函数的定义有点偏离.
Secondly I think that your definition of the API function is a little off.
将此类添加到您的项目中:
Add this class to your project:
Public Class WindowsApi
Private Declare Function FlashWindowEx Lib "User32" (ByRef fwInfo As FLASHWINFO) As Boolean
' As defined by: http://msdn.microsoft.com/en-us/library/ms679347(v=vs.85).aspx
Public Enum FlashWindowFlags As UInt32
' Stop flashing. The system restores the window to its original state.
FLASHW_STOP = 0
' Flash the window caption.
FLASHW_CAPTION = 1
' Flash the taskbar button.
FLASHW_TRAY = 2
' Flash both the window caption and taskbar button.
' This is equivalent to setting the FLASHW_CAPTION | FLASHW_TRAY flags.
FLASHW_ALL = 3
' Flash continuously, until the FLASHW_STOP flag is set.
FLASHW_TIMER = 4
' Flash continuously until the window comes to the foreground.
FLASHW_TIMERNOFG = 12
End Enum
Public Structure FLASHWINFO
Public cbSize As UInt32
Public hwnd As IntPtr
Public dwFlags As FlashWindowFlags
Public uCount As UInt32
Public dwTimeout As UInt32
End Structure
Public Shared Function FlashWindow(ByRef handle As IntPtr, ByVal FlashTitleBar As Boolean, ByVal FlashTray As Boolean, ByVal FlashCount As Integer) As Boolean
If handle = Nothing Then Return False
Try
Dim fwi As New FLASHWINFO
With fwi
.hwnd = handle
If FlashTitleBar Then .dwFlags = .dwFlags Or FlashWindowFlags.FLASHW_CAPTION
If FlashTray Then .dwFlags = .dwFlags Or FlashWindowFlags.FLASHW_TRAY
.uCount = CUInt(FlashCount)
If FlashCount = 0 Then .dwFlags = .dwFlags Or FlashWindowFlags.FLASHW_TIMERNOFG
.dwTimeout = 0 ' Use the default cursor blink rate.
.cbSize = CUInt(System.Runtime.InteropServices.Marshal.SizeOf(fwi))
End With
Return FlashWindowEx(fwi)
Catch
Return False
End Try
End Function
End Class
然后可以像这样闪烁窗口 - 传入对主应用程序表单的引用:
Then can flash the window like this - passing in the reference to the main application form:
Dim res = WindowsApi.FlashWindow(Process.GetCurrentProcess().MainWindowHandle, True, True, 5)
注意:
我编辑了此处找到的代码:http://pinvoke.net/default.aspx/user32.FlashWindowEx
I edited the code found here: http://pinvoke.net/default.aspx/user32.FlashWindowEx
并使用此处定义的定义:在不窃取焦点的情况下获得用户注意力
and used the definition defined here: Get user attention without stealing focus
两者都可能对您有用
这篇关于如何在 vb.net 中闪烁/闪烁任务栏图标?的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!