xsl:如何拆分字符串? [英] xsl: how to split strings?

问题描述

我想用分号 (;) 将地址拆分为由 <br/> 分隔的行:

I want to split an address on semicolons (;) into rows separated by <br />:

例如如果address=123 Elm Street，我想输出123 Elm Street，

e.g. if address=123 Elm Street, I want to output 123 Elm Street,

但是如果address=123 Elm Street;PO Box 222，我想输出

123 Elm Street<br />PO Box 222

如果address=123 Elm Street;PO Box 222;c/o James Jones，我想输出

123 Elm Street<br />PO Box 222<br />c/o James Jones

有没有办法做到这一点?(可能很容易，但我对 XSLT 不太熟悉)

Is there a way to do this? (probably easy but I'm not that familiar with XSLT)

普通的 XSL 选择器是

The plain XSL selector is

<xsl:value-of select="address"/>

我想修改这个 XSLT 片段以在分号上拆分.

and I would like to modify this XSLT fragment to split on semicolon.

update:显然答案涉及使用 和函数 substring-before() 和substring-after().

update: Apparently the answer involves the use of <xsl:call-template> and the functions substring-before() and substring-after().

但我是 XSLT 的初学者，我真的可以使用一些帮助来了解如何做到这一点.

But I'm a beginner to XSLT and I could really use some help for how to do this.

推荐答案

I.纯 XSLT 1.0 解决方案:

I. Plain XSLT 1.0 solution:

这种转变:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()" name="split">
  <xsl:param name="pText" select="."/>
  <xsl:if test="string-length($pText)">
   <xsl:if test="not($pText=.)">
    <br />
   </xsl:if>
   <xsl:value-of select=
    "substring-before(concat($pText,';'),';')"/>
   <xsl:call-template name="split">
    <xsl:with-param name="pText" select=
     "substring-after($pText, ';')"/>
   </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

应用于此 XML 文档时:

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

产生想要的、更正的结果:

123 Elm Street<br />PO Box 222<br />c/o James Jones

二.FXSL 1(用于 XSLT 1.0):

这里我们只使用 FXSL 模板 str-map(第999次不用写递归模板):

Here we just use the FXSL template str-map (and do not have to write recursive template for the 999th time):

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:f="http://fxsl.sf.net/"
xmlns:testmap="testmap"
exclude-result-prefixes="xsl f testmap"
>
   <xsl:import href="str-dvc-map.xsl"/>

   <testmap:testmap/>

   <xsl:output omit-xml-declaration="yes" indent="yes"/>

   <xsl:template match="/">
     <xsl:variable name="vTestMap" select="document('')/*/testmap:*[1]"/>
     <xsl:call-template name="str-map">
       <xsl:with-param name="pFun" select="$vTestMap"/>
       <xsl:with-param name="pStr" select=
       "'123 Elm Street;PO Box 222;c/o James Jones'"/>
     </xsl:call-template>
   </xsl:template>

    <xsl:template name="replace" mode="f:FXSL"
         match="*[namespace-uri() = 'testmap']">
      <xsl:param name="arg1"/>

      <xsl:choose>
       <xsl:when test="not($arg1=';')">
        <xsl:value-of select="$arg1"/>
       </xsl:when>
       <xsl:otherwise><br /></xsl:otherwise>
      </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

当此转换应用于任何 XML 文档(未使用)时，会产生相同的、想要的正确结果:

123 Elm Street<br/>PO Box 222<br/>c/o James Jones

三.使用 XSLT 2.0

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()">
  <xsl:for-each select="tokenize(.,';')">
   <xsl:sequence select="."/>
   <xsl:if test="not(position() eq last())"><br /></xsl:if>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

在此 XML 文档上应用此转换时:

<t>123 Elm Street;PO Box 222;c/o James Jones</t>

产生想要的、正确的结果:

123 Elm Street<br />PO Box 222<br />c/o James Jones

这篇关于xsl:如何拆分字符串?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！