批处理文件上的多项选择菜单? [英] Multiple choices menu on batch file?

问题描述

我想制作一个批处理文件菜单，询问选择要安装的应用程序?"例如

Hi I want to make a batch file menu, that asks 'Select app you want to install?' for example

1. 应用1
2. App2
3. App3
4. App4
5. App5
6. 所有应用

选择什么应用:_

我想要的是，例如我想安装 App2、App3 和 App5，所以我可以通过 App ID 的 'Select what app:2,3,5' 输入.当用户选择选项 6 时，它将安装所有应用程序！

What I want is, for example I want to install App2, App3, and App5, so I can type on by App ID's 'Select what app:2,3,5' . And when user Select option 6, it will install all Applications!

我知道这在 bash 脚本上是可行的，但我不确定批处理脚本?

I know this is possible on bash scripting, but Im not sure on batch scripting?

批处理菜单的一个例子是http://mintywhite.com/software-reviews/productivity-software/create-multiple-choice-menu-batchfile/

An example of batch menu is http://mintywhite.com/software-reviews/productivity-software/create-multiple-choice-menu-batchfile/

推荐答案

答案

这会做你想做的.如果您有任何问题，请告诉我.您所要做的就是按照脚本中列出的两个步骤进行操作.

Answer

This will do what you want. Let me know if you have any questions. All you have to do is follow the two steps listed in the script.

:: Hide Command and Set Scope
@echo off
setlocal EnableExtensions

:: Customize Window
title My Menu

:: Menu Options
:: Specify as many as you want, but they must be sequential from 1 with no gaps
:: Step 1. List the Application Names
set "App[1]=One"
set "App[2]=Two"
set "App[3]=Three"
set "App[4]=Four"
set "App[5]=Five"
set "App[6]=All Apps"

:: Display the Menu
set "Message="
:Menu
cls
echo.%Message%
echo.
echo.  Menu Title
echo.
set "x=0"
:MenuLoop
set /a "x+=1"
if defined App[%x%] (
    call echo   %x%. %%App[%x%]%%
    goto MenuLoop
)
echo.

:: Prompt User for Choice
:Prompt
set "Input="
set /p "Input=Select what app:"

:: Validate Input [Remove Special Characters]
if not defined Input goto Prompt
set "Input=%Input:"=%"
set "Input=%Input:^=%"
set "Input=%Input:<=%"
set "Input=%Input:>=%"
set "Input=%Input:&=%"
set "Input=%Input:|=%"
set "Input=%Input:(=%"
set "Input=%Input:)=%"
:: Equals are not allowed in variable names
set "Input=%Input:^==%"
call :Validate %Input%

:: Process Input
call :Process %Input%
goto End


:Validate
set "Next=%2"
if not defined App[%1] (
    set "Message=Invalid Input: %1"
    goto Menu
)
if defined Next shift & goto Validate
goto :eof


:Process
set "Next=%2"
call set "App=%%App[%1]%%"

:: Run Installations
:: Specify all of the installations for each app.
:: Step 2. Match on the application names and perform the installation for each
if "%App%" EQU "One" echo Run Install for App One here
if "%App%" EQU "Two" echo Run Install for App Two here
if "%App%" EQU "Three" echo Run Install for App Three here
if "%App%" EQU "Four" echo Run Install for App Four here
if "%App%" EQU "Five" echo Run Install for App Five here
if "%App%" EQU "All Apps" (
    echo Run Install for All Apps here
)

:: Prevent the command from being processed twice if listed twice.
set "App[%1]="
if defined Next shift & goto Process
goto :eof


:End
endlocal
pause >nul

这篇关于批处理文件上的多项选择菜单?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！