调试和发布库链接与 CMAKE (VISUAL STUDIO) [英] Debug and Release Library Linking with CMAKE (VISUAL STUDIO)

问题描述

已经有一个线程，但实际上并没有帮助.我希望能够链接例如 Foo.lib 用于 Release 配置和 Foo_d.lib 用于 Debug 配置，我怎样才能做到这一点?如果我这样做:

There was already a Thread which did not help really. I want to be able to link for example Foo.lib for Release Config and Foo_d.lib for Debug Config , how can I achieve this? If I do this:

target_link_libraries(MyEXE debug Foo_d)
target_link_libraries(MyEXE optimized Foo)

那么我的项目中有两个库用于调试配置?为什么没有发布选项?

then I have both libraries in my project for the debug config? Why is there no Release option?

非常感谢！

推荐答案

当你的库是项目的一部分或者你是使用 find_package 命令的配置模式导入它(参见 文档 和 example).如果你不能修改 3rd 方，它会产生 Config.cmake(它可能不使用 cmake 工具或者您不想这样做)答案是模拟这样的过程:

There is no problems when your library is a part of the project or you're importing it using config mode of find_package command (see documentation and example). In case you can't modify 3rd party so it will produce <package>Config.cmake (it may not use cmake tool or you don't want to do it) the answer is to emulate such process:

add_library(foo STATIC IMPORTED)
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/foo-d.lib")
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/foo.lib")

target_link_libraries(MyEXE foo)

请注意，与调试"/优化"功能不同，这种方法不仅限于调试/发布配置:

note that unlike "debug"/"optimized" feature such approach is not limited to Debug/Release configs:

set_target_properties(foo PROPERTIES IMPORTED_LOCATION_MINSIZEREL "/path/to/foo-small.lib")

你还有一些好东西，比如INTERFACE_INCLUDE_DIRECTORIES:

also you've got some goodies like INTERFACE_INCLUDE_DIRECTORIES:

set_target_properties(foo PROPERTIES INTERFACE_INCLUDE_DIRECTORIES "/path/to/foo/includes")

include_directories("/path/to/foo/includes") # this line not needed
target_link_libraries(MyEXE foo) # this command will add "/path/to/foo/includes" for you

和传递链接:

add_library(boo STATIC IMPORTED)
set_target_properties(boo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/boo-d.lib")
set_target_properties(boo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/boo.lib")

add_library(foo STATIC IMPORTED)
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_DEBUG "/path/to/foo-d.lib")
set_target_properties(foo PROPERTIES IMPORTED_LOCATION_RELEASE "/path/to/foo.lib")

set_target_properties(foo PROPERTIES INTERFACE_LINK_LIBRARIES boo) # foo depends on boo

target_link_libraries(MyEXE foo) # boo will be linked automatically

当然，您可以使用常规的 cmake 命令，例如 find_library 和 find_package(... MODULE) 来估计位置，而不是对其进行硬编码.

Of course you can use regular cmake commands like find_library and find_package(... MODULE) to estimate locations instead of hardcoding them.

这篇关于调试和发布库链接与 CMAKE (VISUAL STUDIO)的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！