将 Outlook 附件保存到磁盘 [英] Save Outlook attachment to disk

问题描述

我发现了无数个 VBA 脚本示例，可以自动将附件移动到我的硬盘上.当我在 Outlook 中按原样运行宏时，我在网上找到的这个可以工作，但是当我将它设置为规则时将无法工作.

I found numerous examples of VBA scripts to automatically move attachments to my hard drive. This one I've found online works when I run the macro in Outlook as is, but will not work when I set it to a rule.

当我在子标题中没有item as outlook.mailitem"参数的情况下运行宏并选择包含我想要保存的文件的电子邮件时，它会正常运行.

When I run the macro without the "item as outlook.mailitem" parameter in the sub header and have the email containing the file I want saved selected, it will function properly.

但是，一旦我添加了该信息以便我可以正常运行它，Outlook 就会抛出错误并禁用该规则.

However, as soon as I add that information so I can run it as a rule, outlook throws an error and it disables the rule.

Option Explicit

Public Sub moveAttachmentsAlpha(item As Outlook.MailItem)

Dim objOL As Outlook.Application
Dim objMsg As Outlook.MailItem 'Object
Dim objAttachments As Outlook.Attachments
Dim objSelection As Outlook.Selection
Dim i As Long
Dim lngCount As Long
Dim strFile As String
Dim strFolderpath As String
Dim strDeletedFiles As String

' Get the path to your My Documents folder
strFolderpath = "C:DailyFlash"
On Error Resume Next

' Instantiate an Outlook Application object.

Set objOL = CreateObject("Outlook.Application")

' Get the collection of selected objects.
Set objSelection = objOL.ActiveExplorer.Selection

' Check each selected item for attachments. If attachments exist,
' save them to the strFolderPath folder and strip them from the item.
For Each objMsg In objSelection

' This code only strips attachments from mail items.
' If objMsg.class=olMail Then
' Get the Attachments collection of the item.
Set objAttachments = objMsg.Attachments
lngCount = objAttachments.Count
strDeletedFiles = ""

If lngCount > 0 Then

' We need to use a count down loop for removing items
' from a collection. Otherwise, the loop counter gets
' confused and only every other item is removed.

    For i = lngCount To 1 Step -1

        ' Save attachment before deleting from item.
        ' Get the file name.
        strFile = objAttachments.item(i).FileName

    ' Combine with the path to the Temp folder.
    strFile = strFolderpath & strFile

    ' Save the attachment as a file.
    objAttachments.item(i).SaveAsFile strFile

    'write the save as path to a string to add to the message
    'check for html and use html tags in link
    If objMsg.BodyFormat <> olFormatHTML Then
        strDeletedFiles = strDeletedFiles & vbCrLf & "<file://" & strFile & ">"
        Else
        strDeletedFiles = strDeletedFiles & "<br>" & "<a href='file://" & _
        strFile & "'>" & strFile & "</a>"
    End If

    'Use the MsgBox command to troubleshoot. Remove it from the final code.
    'MsgBox strDeletedFiles

Next i

' Adds the filename string to the message body and save it
' Check for HTML body
If objMsg.BodyFormat <> olFormatHTML Then
    objMsg.Body = vbCrLf & "The file(s) were saved to " & strDeletedFiles & vbCrLf & objMsg.Body
Else
    objMsg.HTMLBody = "<p>" & "The file(s) were saved to " & strDeletedFiles & "</p>" &  objMsg.HTMLBody
End If
    objMsg.Save
End If
Next

ExitSub:

Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing

End Sub

推荐答案

保留大部分脚本.删除对 Outlook.Selection 的引用以及与之关联的 for 循环.然后，在它的位置，将 item 分配给 objMsg 以允许脚本的其余部分正常运行.经过测试，我决定窃取它并自己使用它.

Keep most of the script. Remove the reference to Outlook.Selection and the for loop associated to it. Then, in it's place, assign item to objMsg to allow the rest of the of the script to function as normal. After testing I have decided to steal it and use it myself as well.

Public Sub moveAttachmentsAlpha(item As Outlook.MailItem)

Dim objMsg As Outlook.MailItem 'Object
Dim objAttachments As Outlook.Attachments
Dim i As Long
Dim lngCount As Long
Dim strFile As String
Dim strFolderpath As String
Dim strDeletedFiles As String

' Get the path to your My Documents folder
strFolderpath = "C:	emp"
On Error Resume Next

Set objMsg = item

' This code only strips attachments from mail items.
' If objMsg.class=olMail Then
' Get the Attachments collection of the item.
Set objAttachments = objMsg.Attachments
lngCount = objAttachments.Count
strDeletedFiles = ""

If lngCount > 0 Then

    ' We need to use a count down loop for removing items
    ' from a collection. Otherwise, the loop counter gets
    ' confused and only every other item is removed.

    For i = lngCount To 1 Step -1

        ' Save attachment before deleting from item.
        ' Get the file name.
        strFile = objAttachments.item(i).FileName

        ' Combine with the path to the Temp folder.
        strFile = strFolderpath & strFile

        ' Save the attachment as a file.
        objAttachments.item(i).SaveAsFile strFile

        'write the save as path to a string to add to the message
        'check for html and use html tags in link
        If objMsg.BodyFormat <> olFormatHTML Then
            strDeletedFiles = strDeletedFiles & vbCrLf & "<file://" & strFile & ">"
        Else
            strDeletedFiles = strDeletedFiles & "<br>" & "<a href='file://" & _
            strFile & "'>" & strFile & "</a>"
        End If

    Next i

    ' Adds the filename string to the message body and save it
    ' Check for HTML body
    If objMsg.BodyFormat <> olFormatHTML Then
        objMsg.Body = vbCrLf & "The file(s) were saved to " & strDeletedFiles & vbCrLf & objMsg.Body
    Else
        objMsg.HTMLBody = "<p>" & "The file(s) were saved to " & strDeletedFiles & "</p>" & objMsg.HTMLBody
    End If
    objMsg.Save
End If

ExitSub:

Set objAttachments = Nothing
Set objMsg = Nothing
Set objSelection = Nothing
Set objOL = Nothing

End Sub

仅供参考:我在 ' 行之后没有做任何更改，此代码仅从邮件项目中删除附件. 除了 Next

FYI: I changed nothing after the line ' This code only strips attachments from mail items. Except for a Next

这篇关于将 Outlook 附件保存到磁盘的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！