netlogo:如何让海龟停止一定数量的滴答声然后继续 [英] netlogo: how to make turtles stop for a set number of ticks then continue

问题描述

我正在尝试创建一个模型，让海龟随机行走(但有向前移动的趋势)，直到它们落在代表被诱饵物体的黄色斑块上.

I'm trying to create a model where turtles walk randomly (but with a tendency for forward movement) until they land on a yellow coloured patch which represents a baited object.

当一只海龟落在其中一个黄色斑块上时，我希望它在那个黄色斑块上停下来并在那里停留 15 次，同时它调查"诱饵.

When a turtle lands on one of the yellow patches, I'd like it to stop on that patch and stay there for 15 ticks whilst it 'investigates' the bait.

经过 15 个刻度后，我希望海龟像往常一样继续移动，直到遇到另一个黄色斑块.

After 15 ticks have elapsed I want the turtles to continue moving as usual until they encounter another yellow patch.

我试图在 netlogo 建模共享中修改此停放卡片模型的部分内容，但无法真正理解它(我是 netlogo 的新手)http://modelingcommons.org/browse/one_model/3205#model_tabs_browse_procedures

I've attempted to modify parts of this parked card model in the netlogo modelling commons but couldn't really make sense of it (I'm new to netlogo) http://modelingcommons.org/browse/one_model/3205#model_tabs_browse_procedures

我也试过实现这个线程中描述的倒数计时器如何在 NetLogo 中创建倒数计时器?

I've also tried implementing a count-down timer as described in this thread How can one create a countdown timer in NetLogo?

然而，当我尝试运行模拟时，我收到一个运行时错误只有观察者可以询问所有海龟的集合".谁能告诉我我哪里错了?大概几个地方！谢谢.

However I receive a runtime error 'Only the observer can ASK the set of all turtles' when I try to run the simulation. Can anyone tell me where I'm going wrong? Probably several places! Thanks.

这是导致运行时错误的代码:

Here's the code that's causing the runtime error:

turtles-own [count-down]

to setup 
clear-all
ask patches with [count neighbors != 8]
[set pcolor blue]                   

create-turtles 20
ask turtles 
 [setxy random-xcor random-ycor 
 pen-down]   

ask n-of 20 patches
[ set pcolor yellow ]                   

reset-ticks
end

to go
 move-turtles
 tick
 if ticks >= 720 [stop]

 end


to move-turtles
ask turtles
  [ ifelse pcolor != yellow
  [continue]
  [stay]
  ]
 end

 to continue
ask turtles   
[rt -90 + random 181]
ask turtles
[ifelse [pcolor] of patch-ahead 1 = blue [ lt random-float 360 ]   
[fd 1]  
]
end

to stay
ask turtles 
[
setup-timer
decrement-timer
if timer-expired? [continue]
]
end

to setup-timer
set count-down 15
end

to decrement-timer
set count-down count-down - 1
end

to-report timer-expired?
report ( count-down <= 0 )
end

推荐答案

这只是一个例子，他们应该在黄色区域停留多少滴答声?我假设有 15 个刻度，我要求海龟也在它们的标签上打印它们的刻度编号，如果它跑得太快，你可能会错过它们的停留，所以调整模型的运行速度，看看它们什么时候停留，什么时候移动.你可以有不同的方法来继续，在这个方法中他们只是向前移动 1 个补丁.

This is just one example, How many ticks they should stay in the yellow area? i Assumed 15 ticks and I ask turtles to print their tick number on their label too, if it runs too fast you might miss their stay so adjust running speed for your model to see when they stay and when they move. You can have different methods to continue , in this one they just move 1 patch forward.

turtles-own [count-down]

to setup 
  clear-all
  ask patches with [count neighbors != 8]
  [set pcolor blue]                   

  create-turtles 20
  ask turtles 
  [setxy random-xcor random-ycor 
    pen-down
    set count-down 15
  ]   

  ask n-of 20 patches
  [ set pcolor yellow ]                   

  reset-ticks
end

to go
  move-turtles
  tick
  if ticks >= 720 [stop]

end


to move-turtles
  ask turtles
  [ ifelse pcolor != yellow
    [continue]
    [stay]
  ]
end

To continue   
  rt random 10
  fd 1 
end


to stay   
  set count-down count-down - 1   ;decrement-timer
  set label count-down    
  if count-down = 0 
    [
      Continue
      set label ""
      reset-count-down
    ]    

end

to reset-count-down   
  set count-down 15 
end

这篇关于netlogo:如何让海龟停止一定数量的滴答声然后继续的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！