过滤维基数据中500米以上的摩天大楼 [英] Filter skyscrapers higher than 500 meters in Wikidata
本文介绍了过滤维基数据中500米以上的摩天大楼的处理方法,对大家解决问题具有一定的参考价值,需要的朋友们下面随着小编来一起学习吧!
问题描述
我尝试构造一个SPARQL查询,其中我得到一个高度超过500米的摩天大楼列表。
我意识到,物业高度(P2048)是以不同的单位(米、英尺、厘米)来测量的。将不同的单位计算成米对我来说不是问题。
但我的问题是,这个单位是用来计算物业高度的。
所以我的问题是:如何获得物业高度的单位?
我到目前为止的查询,其中?unit
只是空的:
SELECT ?skyscraper ?skyscraperLabel ?height ?unit WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?skyscraper wdt:P31 wd:Q11303.
?skyscraper wdt:P2048 ?height.
FILTER(?height > 500)
OPTIONAL { ?skyscraper wdt:P2876 ?unit. }
}
LIMIT 100
推荐答案
若要获取设备本身,请使用:P2048/psv:P2048/wikibase:quantityUnit
:
SELECT ?skyscraper ?skyscraperLabel ?height ?unit ?unitLabel WHERE {
?skyscraper wdt:P31 wd:Q11303.
?skyscraper p:P2048/psv:P2048 ?vn.
?vn wikibase:quantityAmount ?height.
?vn wikibase:quantityUnit ?unit.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100
然而,在AKSW和Stanislav Kralin的上述评论之后,最好使用psn:
前缀:p:P2048/psn:P2048/wikibase:quantityAmount
:
SELECT ?skyscraper ?skyscraperLabel ?height WHERE {
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
?skyscraper wdt:P31 wd:Q11303.
?skyscraper p:P2048/psn:P2048/wikibase:quantityAmount ?height.
FILTER(?height >= 500)
}
ORDER BY DESC(?height)
LIMIT 1000
由于某些建筑物包含多个高度值(例如,One World Trade Center同时具有architectural height (Q24192182)和height to pinnacle (Q26970842)值),因此需要进行一些聚合才能在SPARQL:
中为每个建筑物检索一个值SELECT ?skyscraper ?skyscraperLabel (MAX(?h) AS ?height) WHERE {
?skyscraper wdt:P31 wd:Q11303.
?skyscraper p:P2048/psn:P2048/wikibase:quantityAmount ?h.
FILTER(?h >= 500)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?skyscraper ?skyscraperLabel
ORDER BY DESC(?height)
LIMIT 1000
这篇关于过滤维基数据中500米以上的摩天大楼的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!
查看全文