如何在Perl中获得本周的日期？ [英] How can I get this week's dates in Perl?

问题描述

我有以下循环来计算当前周的日期并将其打印出来。它的作品，但我正在游泳在Perl的日期/时间的可能性，并想得到你的意见是否有更好的方法。这是我写的代码：

I have the following loop to calculate the dates of the current week and print them out. It works, but I am swimming in the amount of date/time possibilities in Perl and want to get your opinion on whether there is a better way. Here's the code I've written:

#!/usr/bin/env perl
use warnings;
use strict;

use DateTime;

# Calculate numeric value of today and the 
# target day (Monday = 1, Sunday = 7); the
# target, in this case, is Monday, since that's
# when I want the week to start
my $today_dt = DateTime->now;
my $today = $today_dt->day_of_week;
my $target = 1;

# Create DateTime copies to act as the "bookends"
# for the date range
my ($start, $end) = ($today_dt->clone(), $today_dt->clone());

if ($today == $target)
{
  # If today is the target, "start" is already set;
  # we simply need to set the end date
  $end->add( days => 6 );
}
else
{
  # Otherwise, we calculate the Monday preceeding today
  # and the Sunday following today
  my $delta = ($target - $today + 7) % 7;
  $start->add( days => $delta - 7 );
  $end->add( days => $delta - 1 );
}

# I clone the DateTime object again because, for some reason,
# I'm wary of using $start directly...
my $cur_date = $start->clone();

while ($cur_date <= $end)
{
  my $date_ymd = $cur_date->ymd;
  print "$date_ymd\n";
  $cur_date->add( days => 1 );
}

如上所述，这是有效的，但它是最快还是最有效率？我猜测速度和效率可能不一定在一起，但您的反馈非常感激。

As mentioned, this works, but is it the quickest or most efficient? I'm guessing that quickness and efficiency may not necessarily go together, but your feedback is very appreciated.

推荐答案

稍微改进的版本Friedo的答案...

A slightly improved version of friedo's answer ...

my $start_of_week =
    DateTime->today()
            ->truncate( to => 'week' );

for ( 0..6 ) {
    print $start_of_week->clone()->add( days => $_ );
}

但是，假设星期一是星期一的第一天。对于星期天，从...开始

However, this assumes that Monday is the first day of the week. For Sunday, start with ...

my $start_of_week =
    DateTime->today()
            ->truncate( to => 'week' )
            ->subtract( days => 1 );

无论哪种方式，最好使用 truncate 方法比重新实现它，如friedo做的;）

Either way, it's better to use the truncate method than re-implement it, as friedo did ;)

这篇关于如何在Perl中获得本周的日期？的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！