简化AS3绑定/事件调度代码 [英] Simplify AS3 binding/event-dispatching code

问题描述

有3个属性（示例1）：

There are 3 properties (example 1):

[Bindable] public var name:String;
[Bindable] public var email:Number;
[Bindable] public var address:Boolean;

我需要有3个可以绑定的辅助方法（示例2）：

I needed to have 3 helper methods that will be bindable too (example 2):

[Bindable] public var name:String;
[Bindable] public var email:Number;
[Bindable] public var address:Boolean;

public function get nameIsOk():Boolean     { return !Strings.isEmpty(name) }
public function get emailIsOk():Boolean    { return email == 3 }
public function get addressIsOk():Boolean  { return address }

以上代码无效。我做了这个工作（示例3）：

Sure, the code above doesn't work. I made it work by doing this (example 3):

private var _name:String
[Bindable("nameChanged")]
public function get name():String       { return _name }
public function set name(v:String):void { _name = v; dispatchEvent(new Event("nameChanged")) }
[Bindable("nameChanged")]
public function get nameIsOk():Boolean  { return !Strings.isEmpty(name) }

private var _email:Number
[Bindable("emailChanged")]
public function get email():Number       { return _email }
public function set email(v:Number):void { _email = v; dispatchEvent(new Event("emailChanged")) }
[Bindable("emailChanged")]
public function get emailIsOk():Boolean  { return email == 3 }

private var _address:Boolean
[Bindable("addressChanged")]
public function get address():Boolean       { return _address }
public function set address(v:Boolean):void { _address = v; dispatchEvent(new Event("addressChanged")) }
[Bindable("addressChanged")]
public function get addressIsOk():Boolean  { return address }

它的工作，但现在它是膨胀的。

It does work, but now it is bloated.

有没有办法减少这个代码（示例3）到更小的东西（例如例2）？

Is there a way to reduce this code (example 3) to something smaller (like example 2)?

更新：
为了很好的回答，可以使用just_a_dude。这是最终版本：

UPDATE: Kudos to just_a_dude for nice answer. Here is the final version:

[Bindable] public var name:String;
[Bindable] public var email:Number;
[Bindable] public var address:Boolean;

public function Remixer() {
    for each (var f:String in Strings.split("name email address")) {
        ChangeWatcher.watch(this, f, onChange)
    }
}

private function onChange(e:PropertyChangeEvent):void {
    dispatchEvent(new Event(e.property + "Changed"))
}

[Bindable("nameChanged")]
public function get nameIsOk():Boolean  { return !Strings.isEmpty(name) }

[Bindable("emailChanged")]
public function get emailIsOk():Boolean  { return email == 3 }

[Bindable("addressChanged")]
public function get addressIsOk():Boolean  { return address }

推荐答案

如果这是您正在寻找的，但您可以使用mx.binding.utils.ChangeWatcher监视属性更改

Not sure if this is what you're looking for but you can use mx.binding.utils.ChangeWatcher to "watch" for property changes

<?xml version="1.0" encoding="utf-8"?>

<mx:Script>
    <![CDATA[
        import mx.events.PropertyChangeEvent;
        import mx.binding.utils.ChangeWatcher;


        [Bindable] public var firstName:String;
        [Bindable] public var email:Number;
        [Bindable] public var address:Boolean;

        private var _watcher:ChangeWatcher;

        private function init():void {
            ChangeWatcher.watch(this, "firstName", propertyChangeHandler);
            ChangeWatcher.watch(this, "email", propertyChangeHandler);
            ChangeWatcher.watch(this, "address", propertyChangeHandler);

            firstName = "foo";
            email = 0;
            address = true;

            firstName = "bar";
            email = 1;
            address = false;
        }

        protected function propertyChangeHandler(event:PropertyChangeEvent):void {

            var prop:Object = event.property;
            var name:String = prop.toString() + "Changed";

            // trace(name); // displays firstNameChanged or emailChanged or addressChanged

            dispatchEvent(new Event(name));
        }


    ]]>
</mx:Script>

让我知道这是否有帮助

干杯

这篇关于简化AS3绑定/事件调度代码的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！