如何将Delphi中的文件读入字节数组? [英] How do you read a file in Delphi into a byte array?

查看:0
本文介绍了如何将Delphi中的文件读入字节数组?的处理方法,对大家解决问题具有一定的参考价值,需要的朋友们下面随着小编来一起学习吧!

问题描述

我正在尝试在Delphi XE2中将文件读入字节数组。

这是我当前的代码:

function FileToBytes(const AName: string; var Bytes: TBytes): Boolean;
var
  Ms: TMemoryStream;
begin
  Result := False;
  if not FileExists(AName) then
    Exit;
  Ms := TMemoryStream.Create;
  try
    Ms.LoadFromFile(AName);
    if Ms.Size > 0 then
    begin
      Ms.Position := 0;
      MS.ReadBuffer(Bytes[0], Ms.Size);
      Result := True;
    end;
  finally
    Ms.Free;
  end;
end;

procedure runFile();
var
  Bytes: TBytes;
  OpFile: String;
begin
  OpFile := 'C:UsersKennyDocumentscalc.exe';
  Bytes := nil;
  if FileToBytes(OpFile, Bytes) then
  begin
    //do someting with Bytes(array of Byte)

  end;
end;

我在以下行收到错误:

MS.ReadBuffer(Bytes[0], Ms.Size);

错误为:

0x00404727处的访问冲突:写入地址0x00000008

如能帮助解决此问题,我们将不胜感激。

推荐答案

您没有分配数组,这解释了错误。您可以这样修复代码:

Ms.LoadFromFile(AName);
SetLength(Bytes, Ms.Size);
Ms.Position := 0;
MS.ReadBuffer(Pointer(Bytes)^, Ms.Size);
Result := True;

请注意,我已经避免了检查零长度文件的需要,并使用了Pointer(Bytes),以便代码可以在范围检查处于活动状态时工作。

我还会注意到,您的代码与我所说的Delphi内存流反模式冲突。您将文件读入内存流,该内存流本质上是一个字节数组。然后从那个字节数组复制到另一个字节数组。将整个文件写入两个单独的字节数组。这比必要的多了一个。最好这样写:

function FileToBytes(const AName: string; var Bytes: TBytes): Boolean;
var
  Stream: TFileStream;
begin
  if not FileExists(AName) then
  begin
    Result := False;
    Exit;
  end;
  Stream := TFileStream.Create(AName, fmOpenRead);
  try
    SetLength(Bytes, Stream.Size);
    Stream.ReadBuffer(Pointer(Bytes)^, Stream.Size);
  finally
    Stream.Free;
  end;
  Result := True;
end;

这样,您可以直接从文件读取到目标字节数组。

我不太喜欢将其作为返回布尔值以指示成功的函数。除了不存在的文件之外,代码失败的方式有很多。这些都会导致您的设计出现异常。我更愿意看到纯粹基于异常的错误处理,或者纯粹基于错误代码的错误处理。但不是您设计的混合方法。

正如Andreas在评论中指出的,您还可以使用RTL库函数System.IOUtils.TFile.ReadAllBytes来执行此任务。尽管就我个人而言,我倾向于避免整个System.IOUtils单元,因为有许多设计问题。虽然在最近的版本中已经解决了其中的一些问题,但我认为XE2版本可能会有一些问题。

这篇关于如何将Delphi中的文件读入字节数组?的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!

查看全文
登录 关闭
扫码关注1秒登录
发送“验证码”获取 | 15天全站免登陆