如何将电子邮件的一部分从RichText转换为HTML格式? [英] How can I convert a selection of emails from RichText to HTML Format?
问题描述
背景: 我的工作地点的默认电子邮件格式为RichText. 许多人正在将图像添加到他们的电子邮件中. 带有图片的RichText电子邮件比带有图片的HTML电子邮件大得多.
Background: My work location has a default email format of RichText. Many people are adding images to their emails. RichText emails with images are much larger than HTML emails with images.
我可以手动打开,编辑,将格式更改为HTML,然后保存以大大减小电子邮件的大小.在转换过程中会保留格式.
I can manually open, edit, changed format to HTML, and save to greatly reduce the size of the email. The formatting is maintained during conversion.
但是,当我使用VBA打开邮件项,更改格式并保存时,不会转换电子邮件.
However, when I use VBA to open the mail item, change the format and save, the email is not converted.
如何使用vba将一组Richtext电子邮件更改为格式正确的html电子邮件,从而获得与使用功能区手动编辑和保存相同的结果?
How can I use vba to change a set of Richtext emails into properly formatted html emails, achieving the same results as manually editing and saving using the Ribbon?
这是下面的示例代码,运行此行的代码时,我可以看到:
Here is my sample code below, and I can see when I run the code that this line:
myMailItem.BodyFormat = olFormatHTML
转换的方式与功能区转换的方式不同.
is not converting in the same way that the Ribbon is converting.
Public Sub myConvertHTML()
Dim mySelectedItems As Selection
Dim myMailItem As MailItem
Dim myRichText As String
Dim myHtmlText As String
' Set reference to the Selection.
Set mySelectedItems = ActiveExplorer.Selection
' Loop through each item in the selection.
For Each myMailItem In mySelectedItems
'if the current format is RichText proceed
If myMailItem.BodyFormat = olFormatRichText Then
myMailItem.Display
'this line does not convert the RichText to Html properly
'it seems to convert the images into an attached file ATT#### that is an ole object
'instead of converting the image and using it in html format
'when using the Ribbon and changing the format to HTML,
'the email is converted and formatting maintained
myMailItem.BodyFormat = olFormatHTML
myMailItem.Save
myMailItem.Close olSave
Else
MsgBox "Already in RichText Format: " & myMailItem.Subject, vbInformation
End If
Next
MsgBox "All Done. Email converted to HTML.", vbOKOnly, "Message"
Set mySelectedItems = Nothing
Set myMailItem = Nothing
End Sub
我尝试从VBA内部操作功能区,但无法弄清楚如何调用功能区元素
I tried manipulating the Ribbon from inside VBA, but I have not been able to figure out how to call the Ribbon element
(Format Text/Format/HTML).
任何建议都值得赞赏.
感谢Niton,这是我的最终解决方案.
Thanks to Niton here is my working final solution.
Public Sub myConvertHTML002()
'takes selected list of items in Outlook and converts all mailItems that are RichText into HTML Format
Dim mySelectedObjects As Selection
Dim myObject As Object
Dim myMailItem As MailItem
Dim objItem As Object
' Set reference to the Selection.
Set mySelectedObjects = ActiveExplorer.Selection
' Loop through each item in the selection.
For Each myObject In mySelectedObjects
If myObject.Class = olMail Then
Set myMailItem = myObject
'if the current format is RichText proceed
If myMailItem.BodyFormat = olFormatRichText Then
'have to display the email so we can use the command bars
myMailItem.Display
'special code because we can't change the format of the item from within the item
'we have to use the ActiveInspector
On Error Resume Next
Set objItem = ActiveInspector.CurrentItem
On Error GoTo 0
If Not objItem Is Nothing Then
If objItem.Class = olMail Then
ActiveInspector.CommandBars.ExecuteMso ("EditMessage")
ActiveInspector.CommandBars.ExecuteMso ("MessageFormatHtml")
End If
End If
myMailItem.Close olSave
Else
'MsgBox "Already in RichText Format: " & myMailItem.Subject, vbInformation
End If
End If
Next
MsgBox "All Done. Email converted to HTML.", vbOKOnly, "Message"
Set mySelectedItems = Nothing
Set myMailItem = Nothing
End Sub
推荐答案
您可以单击ExecuteMso按钮.
You can click a button with ExecuteMso.
CommandBars.ExecuteMso方法使用内置按钮的控件..."
CommandBars.ExecuteMso Method "Works on controls that are built-in buttons..."
Sub ChangeToHTML()
Dim objItem As Object
Dim objMail As mailitem
On Error Resume Next
Set objItem = ActiveInspector.currentItem
On Error GoTo 0
If Not objItem Is Nothing Then
If objItem.Class = olMail Then
ActiveInspector.CommandBars.ExecuteMso ("MessageFormatHtml")
End If
End If
End Sub
当为快速访问工具栏或功能区添加内置按钮时,将鼠标悬停在所选内容上时,您会看到IdMso MessageFormatHtml作为文本的最后一位.
You can see MessageFormatHtml, the IdMso, as the last bit of text when you hover over the selection when adding a built-in button for the Quick Access Toolbar or a ribbon.
这篇关于如何将电子邮件的一部分从RichText转换为HTML格式?的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!