如何获取文件夹中的图标文件的文件名，以创建/更新文件夹的desktop.ini? [英] How to get file name of an icon file in a folder for creating/updating desktop.ini for folder(s)?

问题描述

我需要帮助返回位于文件夹中的文件的文件名.

I need help returning the file name of a file located in a folder.

我已经阅读了几次其他问题，答案似乎是:

I have read other questions asked a few times and the answer seems to be:

for /d %F in (*.*) do echo %~nxF

尽管这似乎对其他所有人都有效，但是当我在批处理文件中运行该文件时，它有一个例外，并指出目前不希望使用〜nxF".

Although this seems to work for everyone else, when I run this within a batch file it has an exception and states that '~nxF' is not expected at this time.

我要做的是创建一个批处理文件，该文件将读取图标文件名，然后将特定信息输入desktop.ini，最后创建具有相应权限或属性的文件.

What I am trying to do is create a batch file that will read the icon file name, then enter the specific information into desktop.ini and finally create that file with the respective rights or attributes.

@echo off

set NAME=%~dp0
for %%* in (.) do set NAME=%%~n*

set FOLDERICO=%NAME%
set ICONSIZES=16 24 32 48 64 128 256
set FOLDERINI=Desktop.ini

attrib +s "%CD%"

if exist %FOLDERINI% attrib -s -h %FOLDERINI%

echo [.ShellClassInfo] > %FOLDERINI%
echo IconResource=\[Video]\[HD Films]\%FOLDERICO%\Icon\%FOLDERICO%.ico,0 >> %FOLDERINI%

if not "%2"=="" (
    echo FolderType=%2 >> %FOLDERINI%
)
attrib -a +s +h %FOLDERINI%

我认为可以对代码进行某种改进，以便从根目录而不是特定文件夹运行它.

I think the code could be improved somehow to run it from a root directory as opposed to the specific folder.

编辑:我更新了文件，现在看起来像这样:

Updated my file so it now looks like this:

@ECHO OFF

attrib +s "%CD%"
set ICODIR=%CD%\Icon\

for %%F in ("%ICODIR%"*.ico) do set ICO=%%~nxF
echo %ICO%

set ICOINI=Desktop.ini
if exist %ICOINI% attrib -s -h %ICOINI%

echo [.ShellClassInfo] > %ICOINI%
echo IconResource=%ICODIR:~2%%ICO%,0 >> %ICOINI%

if not "%2"=="" (
    echo FolderType=%2 >> %ICOINI%
)

attrib -a +s +h %ICOINI%

Pause

我需要在for循环中扫描根目录的每个子目录.

Which I need to put into a for loop scanning each subdirectory of the root.

推荐答案

以下是带有批注的批处理代码，用于创建或更新 desktop.ini 的文件夹图标以及(可选)其中一个的文件夹类型指定的文件夹或当前驱动器(或删除/注释一行的当前目录)根目录中的所有文件夹.

Here is a fully commented batch code for creating or updating desktop.ini for a folder icon and optionally also for folder type for either a specified folder or all folders in root of current drive (or current directory with deleting/commenting a single line).

创建 desktop.ini 非常简单，因为可以通过查看代码来看到它.仅使用Windows命令处理器cmd.exe的内部命令(不是专为此类任务设计的)，更新现有的INI文件以替换行或在必要时在正确的部分添加行会更加困难.

Creating a desktop.ini is quite simple as it can be seen by looking on code. Updating an existing INI file to replace lines or add them if necessary in correct section is much more difficult on using only internal commands of Windows command processor cmd.exe which is not designed for such tasks.

@echo off

rem CreateDesktopIni.bat [FolderName | FolderType] [FolderType]

rem This batch file can be started without any parameter to create or
rem update desktop.ini for all subfolders in root of current drive or
rem current working directory with removing or commenting one line in
rem code below, see comment below label AllFolders.

rem But the batch file can be also started with a folder name
rem to create or update file desktop.ini of this folder only.

rem Optionally it is possible to specify as only parameter a folder type
rem or append as second parameter after folder name the folder type.

rem The folder type can be one of the following strings (not verified):

rem CommonDocuments, Contacts, Documents, Music, MusicAlbum, MusicArtist,
rem MusicIcons, MyDocuments, MyMusic, MyPictures, MyVideos, PhotoAlbum,
rem Pictures, UseLegacyHTT, VideoAlbum, Videos

setlocal EnableExtensions DisableDelayedExpansion
set "FolderType=%~2"

rem Define the subfolder containing the icon for the folder.
set "IconFolder=Icon"

rem Is the batch file called with at least one parameter?
if "%~1" == "" goto AllFolders

rem Yes! It could be a folder name or the folder type.
if not exist "%~1" set "FolderType=%~1" & goto AllFolders

rem First parameter specifies a folder (most likely as not verified).
set "Folder=%~1"
rem Remove trailing backslash if there is one.
rem The batch file should not be called with just \ as folder path.
if "%Folder:~-1%" == "\" set "Folder=%Folder:~0,-1%"

rem Call subroutine to create or update the desktop file for this folder.
call :DesktopINI "%Folder%"
goto EndBatch

:AllFolders
rem Change working directory to root of current drive. Remove or comment
rem the next line to process instead all subfolders in current directory.
cd \
rem Call subroutine to create/update the desktop file for each subfolder.
for /F "eol=| delims=" %%I in ('dir /AD /B 2^>nul') do call :DesktopINI "%%I"
goto EndBatch


rem Subroutine to create or update the desktop file for a folder.

rem This subroutine first searches for the icon file and does nothing
rem if no icon file could be found in the defined subfolder because
rem the subfolder does not exist at all or there is no *.ico file.

rem After determining the icon file (first found *.ico file) with full path
rem including drive letter (remove character d for relative path without
rem drive letter in line with %%~dpnxI), this subroutine checks next for
rem existence of file desktop.ini (case-insensitive) in current folder.

rem desktop.ini with the two or three lines is simply created if this file
rem does not already exist and the user of the batch file has permissions
rem to create this file in the current folder.

rem For an already existing desktop.ini the necessary process to update it
rem is much more complex. All lines outside the section [.ShellClassInfo]
rem must be kept and are therefore just copied to a temporary file, except
rem empty lines ignored by command FOR. Also all lines within the section
rem [.ShellClassInfo] not starting with the string IconFile= or optionally
rem FolderType= (both case-insensitive) must be also simply kept by copying
rem them to the temporary file.

rem An existing line starting with IconFile= in section [.ShellClassInfo]
rem is not copied to temporary file, but instead this line is written to
rem the temporary file with determined icon file name with path.

rem An existing line starting with FolderType= in section [.ShellClassInfo]
rem is also not copied to temporary file, but instead this line is written
rem to the temporary file with folder type as specified on starting batch.

rem If section [.ShellClassInfo] was found and beginning of a new section is
rem detected because of a line starting with an opening square bracket and
rem the line with IconFile= and/or the line with FolderType= was not found
rem in this section during processing the existing desktop.ini, the lines
rem are written next to temporary file to insert them before continuing
rem with the next section.

rem Finally it could happen that section [.ShellClassInfo] is missing in
rem existing desktop.ini and must be therefore added to the file. And it
rem could be that this section exists at end of desktop.ini, but either
rem the line with IconFile= or with FolderType= or both are missing and
rem those lines must be therefore appended to the file.

rem The temporary file is next copied over the existing desktop.ini and
rem then deleted as not further needed. Finally the system and hidden
rem attributes are set on file desktop.ini and the system attribute is
rem set on the current folder as otherwise desktop.ini would be ignored.

:DesktopINI
set "Folder=%~1"

for %%I in ("%Folder%\%IconFolder%\*.ico") do (
    set "IconFile=%%~dpnxI"
    goto IconFound
)
goto :EOF

:IconFound
set "DesktopFile=%Folder%\desktop.ini"

if not exist "%DesktopFile%" (
    echo [.ShellClassInfo]>"%DesktopFile%"
    if not exist "%DesktopFile%" goto :EOF
    echo Iconfile=%IconFile%>>"%DesktopFile%"
    if defined FolderType echo FolderType=%FolderType%>>"%DesktopFile%"
    %SystemRoot%\System32\attrib.exe +h +s "%DesktopFile%"
    %SystemRoot%\System32\attrib.exe +s "%Folder%"
    goto :EOF
)

set "IconLine="
set "ShellClassInfo="
set "UpdateComplete="
set "TempFile=%TEMP%\Desktop.tmp"
if exist "%TempFile%" del /F "%TempFile%"
if not defined FolderType (set "TypeLine=1") else set "TypeLine="
%SystemRoot%\System32\attrib.exe -h -s "%DesktopFile%"

(for /F "usebackq delims=" %%L in ("%DesktopFile%") do (
    set "LineOutput="
    if defined ShellClassInfo (
        for /F "delims==" %%V in ("%%L") do (
            if /I "%%V" == "IconFile" (
                echo Iconfile=%IconFile%
                set "IconLine=1"
                set "LineOutput=1"
            ) else if /I "%%V" == "FolderType" (
                if defined FolderType (
                    echo FolderType=%FolderType%
                    set "TypeLine=1"
                    set "LineOutput=1"
                )
            ) else (
                set "NewSection=1"
                for /F "eol=[" %%G in ("%%V") do set "NewSection="
                if defined NewSection (
                    if not defined IconLine echo Iconfile=%IconFile%
                    if not defined TypeLine echo FolderType=%FolderType%
                    set "ShellClassInfo="
                    set "UpdateComplete=1"
                )
            )
        )
    ) else if /I "%%L" == "[.ShellClassInfo]" (
        echo [.ShellClassInfo]
        set "ShellClassInfo=1"
        set "LineOutput=1"
    )
    if not defined LineOutput echo(%%L
)) >"%TempFile%"

if not defined UpdateComplete if not defined ShellClassInfo (
    echo [.ShellClassInfo]>>"%TempFile%"
    set "ShellClassInfo=1"
)

if defined ShellClassInfo (
    if not defined IconLine echo Iconfile=%IconFile%
    if not defined TypeLine echo FolderType=%FolderType%
) >>"%TempFile%"

move /Y "%TempFile%" "%DesktopFile%" >nul
if exist "%TempFile%" del "%TempFile%"

%SystemRoot%\System32\attrib.exe +h +s "%DesktopFile%"
%SystemRoot%\System32\attrib.exe +s "%Folder%"
goto :EOF

:EndBatch
endlocal

建议删除所有以命令rem开头的行中的注释，以加快批处理文件的处理速度.

It is advisable to remove all comments which are the lines starting with command rem for faster processing of the batch file.

如果在启动批处理文件时批处理文件应处理当前文件夹的所有子文件夹而不是当前驱动器的子文件夹，则必须删除命令行cd \或将其注释掉.

The command line cd \ must be removed or commented out if the batch file should process all subfolders of the current folder on starting the batch file instead of the subfolders of the current drive.

DIR 选项/S可以附加到dir /AD /B，以在此批处理文件开始时处理当前文件夹或当前驱动器的整个目录树.

The DIR option /S can be appended to dir /AD /B to process the entire directory tree of current folder or current drive on start of this batch file.

可以仅用.而不是Icon定义环境变量IconFolder，以在文件夹本身而不是子文件夹Icon中搜索第一个* .ico文件.

The environment variable IconFolder can be defined with just . instead of Icon to search for first *.ico file in the folder itself instead of a subfolder Icon.

要了解所使用的命令及其工作方式，请打开命令提示符窗口，然后在此处执行以下命令，并非常仔细地阅读每个命令显示的所有帮助页面.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• attrib /?
• call /?
• cd /?
• del /?
• dir /?
• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• move /?
• rem /?
• set /?
• setlocal /?

• attrib /?
• call /?
• cd /?
• del /?
• dir /?
• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• move /?
• rem /?
• set /?
• setlocal /?

阅读有关使用命令重定向运算符来解释>和>>和2>nul.当Windows命令解释器在执行命令之前处理此命令行时，重定向操作符>必须在 FOR 命令行上的 FOR 命令行中使用脱字符号^进行转义，以将其解释为文字字符. FOR ，它将在后台启动的单独命令过程中执行嵌入式dir命令行.

Read the Microsoft article about Using command redirection operators for an explanation of > and >> and 2>nul. The redirection operator > must be escaped with caret character ^ on FOR command line with 2^>nul to be interpreted as literal character when Windows command interpreter processes this command line before executing command FOR which executes the embedded dir command line in a separate command process started in background.

这篇关于如何获取文件夹中的图标文件的文件名，以创建/更新文件夹的desktop.ini?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！