UNC路径作为批处理文件中要求管理员权限的当前目录 [英] UNC paths as current directories in batch file where admin rights are requested

问题描述

我当前正在尝试编写一个批处理文件，该文件会自动创建一个包含快捷方式的文件夹结构. 为了创建快捷方式，我使用了"mklink"，它需要管理员权限. 我已经在此网站上使用了代码
( http://winaero.com/blog/how-to-auto-elevate-a-batch-file-to-run-it-as-administrator/)，以自动授予我这些权利.

I'm currently trying to write a batch files that automatically creates a folder structure including shortcuts. For creating the shortcuts I use "mklink" which requires administrator privileges. I have used the code on this site
(http://winaero.com/blog/how-to-auto-elevate-a-batch-file-to-run-it-as-administrator/) for giving me these rights automatically.

但是，当我在计算机上本地运行以下代码时，下面的代码可以很好地工作，但是当我将其放置在打算工作的服务器位置时，在我做出是/否选择后，命令提示符将立即关闭在管理员权限对话框窗口中. 我没有收到错误代码，但我发现它可能与 "CMD不支持UNC路径作为当前目录". 我曾尝试使用在论坛上找到的push和其他方法来解决此类问题，但现在我开始对想法产生怀疑.

However, the code down below works perfectly fine when I run it locally on my machine, but when I put it on a server location where it is intended to work the command prompt immediately closes after I have made my yes/no choice in the dialoge window for administrator rights. I don't get an error code but I have figured out that it probably has to do with that "CMD DOES NOT SUPPORT UNC PATHS AS CURRENT DIRECTORIES". I have tried using pushd and other things I found on forums to solve such problem but now I have started to run dry on ideas.

有人知道如何解决这个问题吗? 预先感谢！

Does anyone have I clue how to solve this? Thanks in advance!

chcp 1252 

::::::::::::::::::::::::::::::::::::::::::::
:: Run as admin
::::::::::::::::::::::::::::::::::::::::::::
@echo off
CLS
ECHO.
ECHO =============================
ECHO The name of the main folder?    
ECHO =============================

:init
setlocal DisableDelayedExpansion
set "batchPath=%~0"
for %%k in (%0) do set batchName=%%~nk
set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
setlocal EnableDelayedExpansion

:checkPrivileges
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges
if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
ECHO.
ECHO **************************************
ECHO Invoking UAC for Privilege Escalation
ECHO **************************************

ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
ECHO args = "ELEV " >> "%vbsGetPrivileges%"
ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"
ECHO Next >> "%vbsGetPrivileges%"
ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >>      "%vbsGetPrivileges%"
"%SystemRoot%\System32\WScript.exe" "%vbsGetPrivileges%" %*
exit /B

:gotPrivileges
setlocal & pushd .
cd /d %~dp0
if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

::::::::::::::::::::::::::::
::START
::::::::::::::::::::::::::::

::Dialogwindow.
@echo off
title message

echo Skriv nedan^^!
set/p "Projektnamn=>"

:: Creates the folder structure
md "%~dp0"%Projektnamn%

md "%~dp0""%Projektnamn%"/"1. Projektpärm"
md "%~dp0""%Projektnamn%"/"1. Projektpärm"/"1. Tekniska specifikationer"
md "%~dp0""%Projektnamn%"/"1. Projektpärm"/"2. ÄTA,Beställning & Fakturering"
md "%~dp0""%Projektnamn%"/"1. Projektpärm"/"3. Tidplan"
md "%~dp0""%Projektnamn%"/"1. Projektpärm"/"4. Projektmöten"
md "%~dp0""%Projektnamn%"/"1. Projektpärm"/"5. Dagbok"
md "%~dp0""%Projektnamn%"/"1. Projektpärm"/"6. Kvalitet"
:: Genväg enlinjeschema, se kod för genväg

md "%~dp0""%Projektnamn%"/"2. Kretsschema"
md "%~dp0""%Projektnamn%"/"2. Kretsschema"/"1. Konstruktionsunderlag från    kund"

md "%~dp0""%Projektnamn%"/"3. Stationsdokumentation"
md "%~dp0""%Projektnamn%"/"3. Stationsdokumentation"/"1. Enlinjeschema"
md "%~dp0""%Projektnamn%"/"3. Stationsdokumentation"/"2. Blockschema"
md "%~dp0""%Projektnamn%"/"3. Stationsdokumentation"/"3. Förreglingsschema"
md "%~dp0""%Projektnamn%"/"3. Stationsdokumentation"/"4. Ritningsnummer"

md "%~dp0""%Projektnamn%"/"4. Skåpsdokumentation"
md "%~dp0""%Projektnamn%"/"4. Skåpsdokumentation"/"1. Skåpslayout"
md "%~dp0""%Projektnamn%"/"4. Skåpsdokumentation"/"2. Apparatlista"
md "%~dp0""%Projektnamn%"/"4. Skåpsdokumentation"/"3. Förbindningstabell"
md "%~dp0""%Projektnamn%"/"4. Skåpsdokumentation"/"4. Skyltlista & Etiketter"

:: Skapar RELATIVA Genvägarna
mklink /D "%~dp0%Projektnamn%\1. Projektpärm\7. Enlinjeschema" "..\3.     Stationsdokumentation\1. Enlinjeschema"
mklink /D "%~dp0%Projektnamn%\1. Projektpärm\8. Blockschema" "..\3.    Stationsdokumentation\2. Blockschema"
mklink /D "%~dp0%Projektnamn%\1. Projektpärm\9. Förreglingsschema" "..\3. Stationsdokumentation\3. Förreglingsschema"
mklink /D "%~dp0%Projektnamn%\1. Projektpärm\10. Skåpslayout" "..\4. Skåpsdokumentation\1. Skåpslayout"

pause

推荐答案

以下是为此任务重写的批处理代码，并对其进行了完整注释:

Here is the batch code rewritten for this task and commented completely:

::::::::::::::::::::::::::::::::::::::::::::
:: Run as administrator
::::::::::::::::::::::::::::::::::::::::::::
@echo off
setlocal EnableExtensions
chcp 1252 >nul
cls

rem Define as target folder path the folder path of this batch file. This can
rem can be a folder on a local drive or on a network drive or even a UNC path.

rem It is also possible to use %CD% instead of %~dp0 to specify as target
rem folder path the current folder on starting this batch file which can
rem be different to batch file folder. But please note that Windows does
rem not support by default running a batch script from a network share
rem using UNC path. This is indicated by Windows with the message:

rem '\\ComputerName\ShareName\FolderName'
rem CMD.EXE was started with the above path as the current directory.
rem UNC paths are not supported.  Defaulting to Windows directory.

rem So on using %CD% and running this batch file from a network share using
rem UNC path the target folder would be %SystemRoot% which is usually the
rem folder C:\Windows which is most likely not wanted as target folder path.

set "TargetFolder=%~dp0"
set "vbsGetPrivileges=%TEMP%\OEgetPriv_%~n0.vbs"

rem The console application NET with parameter FILE can be executed
rem successfully only if the account used for running this batch file
rem has local administrator privileges. See the Microsoft TechNet article
rem https://technet.microsoft.com/en-us/library/bb490702.aspx for details
rem about NET FILE.

rem The output written to handle STDOUT on successful execution is redirected
rem to device NUL to suppress it. The exit code of NET assigned to ERRORLEVEL
rem is in this case 0 indicating a successful execution.

rem But on a failed execution because of not having administrator
rem privileges NET outputs to handle STDERR the two error messages
rem "System error 5 has occurred." and "Access is denied." which
rem are redirected from handle STDERR to device NUL to suppress them.
rem And exit/return code of NET is 1 indicating a failed execution.

rem Read https://technet.microsoft.com/en-us/library/bb490982.aspx
rem for details about using command redirection operators.

%SystemRoot%\System32\net.exe FILE >nul 2>nul
if not errorlevel 1 goto RunMainCode

if "%~1"=="ELEV" (

    rem This condition is just for safety. If the batch file was started
    rem already a second time with ELEV as first parameter and execution
    rem of NET FILE failed nevertheless because of missing permissions,
    rem the batch file outputs an error message, waits for any key press
    rem by the user to make sure that the user had the chance to read the
    rem error message and then exits the batch file processing without
    rem doing anything at all.

    echo %~nx0 should run already with elevated privileges, but it isn't.
    echo/
    echo Press any key to exit %~nx0 without doing anything ...
    pause >nul
    goto :EOF
)

rem This batch file can be started without any parameter result in %* being
rem expanded to nothing which results in environment variable BatchArgs being
rem deleted if already existing or with project name as parameter which must
rem be enclosed in double quotes in case of containing 1 or more spaces.

rem As the batch file needs to be executed once again in a separate command
rem process running as local administrator for full access at least on local
rem machine it is necessary to prepare the parameters/arguments list. Each
rem double quote in the arguments list must be doubled to be correct escaped
rem in the VBScript file.

rem This is necessary as otherwise running this batch file with "My Project"
rem as first parameter would result in execution of the batch file by
rem the Windows Script Host as My Project without the double quotes as
rem arguments for the batch file and therefore the first parameter is on
rem elevated execution "My" instead of "My Project" as it was initially.

rem Many "run as administrator" solutions which can be found in world wide web
rem don't handle parameter strings correct which are enclosed in double quotes
rem because the parameter string has 1 or more spaces or other critical
rem characters requiring enclosing the parameter string in double quotes.

set "BatchArgs=%*"
setlocal EnableDelayedExpansion
if defined BatchArgs set "BatchArgs= !BatchArgs:"=""!"

rem Everything output by the ECHO command lines within the next command block
rem is redirected into the VBScript file created in the folder for temporary
rem files of current user with name of batch file in VBScript file name. This
rem makes it possible that multiple batch files with different names can run
rem at the same time using same code for creating a VBScript file to run the
rem batch file once again as administrator with elevated privileges.

rem For details on ShellExecute parameters see the Microsoft MSDN article
rem https://msdn.microsoft.com/en-us/library/windows/desktop/gg537745.aspx

rem The tricky part is quoting the arguments list correct which should be
rem finally passed to cmd.exe executed from the VBScript. The command process
rem running the batch file with elevated privileges of local administrator
rem should automatically close after execution of batch file finished which
rem is the reason for first argument /C.

rem The second argument is the command to execute by `cmd.exe` which is
rem the batch file name with complete path which must be enclosed in double
rem quotes for safety in case of batch file name or path contains 1 or more
rem spaces. But additionally the batch file itself must be started with at
rem least 2 more arguments.

rem The first argument for the batch file is ELEV which is used as indication
rem to detected if this batch file is already started a second time with via
rem the VBScript using local built-in administrator account.

rem The second argument for the batch file is the target folder path which is
rem either the batch file folder or the current folder on starting this batch
rem file the first time depending or whatever is specified above as target
rem folder path.

rem And last all parameters passed to this batch file on initial run should
rem be also passed to second execution of this batch file under the different
rem environment of local built-in administrator account.

rem This nesting of batch file arguments in command processor arguments written
rem into a VBScript file which requires additionally escaping each double quote
rem within a string with one more double quote results in a strange syntax for
rem the line to write into the VBScript file.

(
    echo Set UAC = CreateObject^("Shell.Application"^)
    echo UAC.ShellExecute "%SystemRoot%\System32\cmd.exe", "/C """"%~f0"" ELEV ""!TargetFolder!""!BatchArgs!""", , "runas", 1
)>"%vbsGetPrivileges%"
endlocal

rem Now the created VBScript file can be executed with Windows Script Host.
rem Then the VBScript file can be deleted as not longer needed and processing
rem of this batch file under current user account ends resulting in returning
rem to command process which results in closing the console window if not
rem executed by cmd.exe started with option /K to keep the console window
rem open like on opening a command prompt window and running this batch
rem file from within the command prompt window.

%SystemRoot%\System32\wscript.exe "%vbsGetPrivileges%"
del "%vbsGetPrivileges%"
goto :EOF


rem Here starts the main code of the batch file which needs to be
rem executed with elevated privileges of a local administrator.

rem First is checked if the first parameter of the batch file is ELEV
rem which indicates that this batch file was started a second time
rem using local administrator account.

:RunMainCode
if "%~1"=="ELEV" (

    rem In this case the second argument is the target folder passed from
    rem initial run to this second run of the batch file. The current
    rem directory is now not anymore the initial current directory, but
    rem %SystemRoot%\System32 has set by Windows on starting a command
    rem process using RunAs and administrator account. This must be taken
    rem into account on further batch file processing.

    rem For this batch file it does not matter what is the current directory
    rem as it is written to work with the target folder defined on starting
    rem the batch file (initially). So there is no need to use  CD /D "%~dp0"
    rem or  PUSHD "%~dp0"  as many "run as administrator" solutions use to
    rem change the current directory to directory of the batch file. There
    rem is also no need for  CD /D "%~2"  or  PUSHD "%~2"  here.

    rem The two additionally added arguments ELEV and the target folder
    rem path are removed from the arguments lists by using twice the
    rem command SHIFT to restore the initial arguments list.

    set "TargetFolder=%~2"
    shift /1
    shift /1
)

setlocal EnableDelayedExpansion

rem Now it is checked if the last character of the target folder path is
rem a backslash character which is not the case when using %CD% and the
rem current directory on starting the batch file is not the root directory
rem of a drive. In this case append a backslash to target folder path.

if not "%TargetFolder:~-1%" == "\" set "TargetFolder=%TargetFolder%\"

rem If this batch file was started (initially) without any parameter string,
rem prompt the batch file user for the project folder name and use the input
rem string without checking if being valid as folder name. Otherwise interpret
rem the first parameter string as project folder name.

if "%~1" == "" (
    echo/
    echo ============================
    echo The name of the main folder?
    echo ============================
    echo/
    set "Projektnamn=:invalid:"
    set /P "Projektnamn=>"
    echo/
) else (
    set "Projektnamn=%~1"
)

rem Create the main project folder and check if this was successful. On an
rem error like such a folder exists already, or the user has no permissions
rem to create this folder, or the folder name contains characters being not
rem valid for a folder name like the default string :invalid: used in case
rem of user just hits RETURN or ENTER instead of entering a folder name,
rem the command MD outputs an appropriate error message. The batch file
rem halts in this case the batch file execution until the user hits any
rem key before exiting without doing anything at all.

md "%TargetFolder%!Projektnamn!"
if errorlevel 1 (
    echo/
    echo Press any key to exit %~nx0 without doing anything ...
    pause >nul
    endlocal
    goto :EOF
)

rem Create the folder structure and the symbolic directory links.
rem The command MD with command extensions enabled as done at top of this
rem batch file creates automatically the entire directory tree if necessary.

md "%TargetFolder%!Projektnamn!\1. Projektpärm\1. Tekniska specifikationer"
md "%TargetFolder%!Projektnamn!\1. Projektpärm\2. ÄTA,Beställning & Fakturering"
md "%TargetFolder%!Projektnamn!\1. Projektpärm\3. Tidplan"
md "%TargetFolder%!Projektnamn!\1. Projektpärm\4. Projektmöten"
md "%TargetFolder%!Projektnamn!\1. Projektpärm\5. Dagbok"
md "%TargetFolder%!Projektnamn!\1. Projektpärm\6. Kvalitet"

:: Genväg enlinjeschema, se kod för genväg
md "%TargetFolder%!Projektnamn!\2. Kretsschema\1. Konstruktionsunderlag från kund"

md "%TargetFolder%!Projektnamn!\3. Stationsdokumentation\1. Enlinjeschema"
md "%TargetFolder%!Projektnamn!\3. Stationsdokumentation\2. Blockschema"
md "%TargetFolder%!Projektnamn!\3. Stationsdokumentation\3. Förreglingsschema"
md "%TargetFolder%!Projektnamn!\3. Stationsdokumentation\4. Ritningsnummer"

md "%TargetFolder%!Projektnamn!\4. Skåpsdokumentation\1. Skåpslayout"
md "%TargetFolder%!Projektnamn!\4. Skåpsdokumentation\2. Apparatlista"
md "%TargetFolder%!Projektnamn!\4. Skåpsdokumentation\3. Förbindningstabell"
md "%TargetFolder%!Projektnamn!\4. Skåpsdokumentation\4. Skyltlista & Etiketter"

:: Skapar RELATIVA Genvägarna
mklink /D "%TargetFolder%!Projektnamn!\1. Projektpärm\7. Enlinjeschema" "..\3. Stationsdokumentation\1. Enlinjeschema" >nul
mklink /D "%TargetFolder%!Projektnamn!\1. Projektpärm\8. Blockschema" "..\3. Stationsdokumentation\2. Blockschema" >nul
mklink /D "%TargetFolder%!Projektnamn!\1. Projektpärm\9. Förreglingsschema" "..\3. Stationsdokumentation\3. Förreglingsschema" >nul
mklink /D "%TargetFolder%!Projektnamn!\1. Projektpärm\10. Skåpslayout" "..\4. Skåpsdokumentation\1. Skåpslayout" >nul
endlocal
endlocal

此批处理文件可以在使用当前用户帐户或内置的本地管理员帐户启动批处理文件时使用当前目录中的任何目录，因为所有内容的编写都独立于当前目录是什么.

This batch file works with whatever is the current directory on starting the batch file with current user account or with built-in local administrator account as everything is written to work independent on what is the current directory.

如果批处理文件存储在使用UNC路径打开并双击执行的网络共享的文件夹中，则当前目录为%SystemRoot%.

The current directory is %SystemRoot% in case of the batch file is stored in a folder on a network share opened using UNC path and executed by double clicking on it.

如果当前用户没有管理员权限，则当前目录为%SystemRoot%\System32并以提升的特权第二次运行.

The current directory is %SystemRoot%\System32 on running it a second time with elevated privileges if the current user has no administrator privileges.

但是，如果本地管理员帐户没有读取&对网络共享具有执行权限，cmd.exe无法直接使用网络共享中的UNC路径来执行批处理文件.

However, if the local administrator account has no read & execute permissions on the network share, cmd.exe can't execute the batch file with using UNC path directly from network share.

在写为VBScript文件的第二行的长行中，将/C替换为/K，以保持打开控制台窗口的状态，该控制台窗口是在提升到管理员级别后第二次执行批处理文件时打开的，以便能够读取错误消息Windows命令解释器输出.

In the long line written as second line into the VBScript file replace /C by /K to keep open the console window opened on second execution of the batch file after elevation to administrator level to be able to read the error messages output by Windows command interpreter.

要了解所使用的命令及其工作方式，请打开命令提示符窗口，在其中执行以下命令，并非常仔细地阅读每个命令显示的所有帮助页面.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• chcp /?
• cls /?
• del /?
• echo /?
• goto /?
• if /?
• md /?
• mklink /?
• pause /?
• rem /?
• set /?
• setlocal /?
• shift /?
• wscript /?(或也可以使用cscript /?作为cscript.exe.)

• chcp /?
• cls /?
• del /?
• echo /?
• goto /?
• if /?
• md /?
• mklink /?
• pause /?
• rem /?
• set /?
• setlocal /?
• shift /?
• wscript /? (or cscript /? as cscript.exe could be also used.)

批处理代码注释中引用的Microsoft文章:

Microsoft articles referenced in the comments of the batch code:

• 网络文件
• Shell.ShellExecute方法
• 使用命令重定向运算符

• Net file
• Shell.ShellExecute method
• Using command redirection operators

注意:与所有以::开头的行(用于注释行的无效标签)一样，可以安全删除以0或更多前导空格开头的以rem开头的所有行.

Note: All lines starting with rem after 0 or more leading spaces can be safely removed like all lines starting with :: (invalid label used for comment lines).

这篇关于UNC路径作为批处理文件中要求管理员权限的当前目录的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！