CMake编译生成的文件 [英] CMake Compiling Generated Files

问题描述

我有一个在CMake构建过程中生成的文件的列表。我想稍后使用 add_library来编译这些文件，但是直到生成文件后，我才知道它们是生成的。

I have a list of files that get generated during the CMake build process. I want to compile these files using "add_library" afterward, but I won't know which files get generated until after they get generated. Is there anyway to build this into a CMake script?

推荐答案

嗯，可以使用CMake的 CMAKE_CONFIGURE_DEPENDS 目录属性。如果任何给定文件发生更改，这将强制CMake重新配置。

Well, it is possible to do so with CMake's CMAKE_CONFIGURE_DEPENDS directory property. This forces CMake to reconfigure if any of the given files changed.

以下代码显示了单个模型文件的一种方法，用作代码生成的输入：

The following code shows the approach for a single model file, that is used as input for the code generation:

set(MODEL_FILE your_model_file)
set_directory_properties(PROPERTIES CMAKE_CONFIGURE_DEPENDS ${MODEL_FILE})
set(GENERATED_SOURCE_DIR ${CMAKE_CURRENT_BINARY_DIR}/${MODEL_FILE})

file(REMOVE_RECURSE ${GENERATED_SOURCE_DIR})
file(MAKE_DIRECTORY ${GENERATED_SOURCE_DIR})
execute_process(COMMAND your_code_generation_tool -o ${GENERATED_SOURCE_DIR} ${MODEL_FILE})

file(GLOB LIBGENERATED_FILES ${GENERATED_SOURCE_DIR}/*)
add_library(libgenerated ${LIBGENERATED_FILES})
target_include_directories(libgenerated ${GENERATED_SOURCE_DIR})

使用上述方法，每次更改模型文件时，CMake都会重新配置，从而导致重新生成模型

With the above approach, each time the model file has changed CMake will reconfigure which results in the model being regenerated.

简单解决方案的问题在于，即使模型中的变化尽可能小

The problem with the simple solution is that even for the smallest possible change in the model the entire dependencies of the generated files have to be rebuilt.

高级方法使用CMake的 copy_if_different 功能仅允许受模型影响的生成文件更改为看起来已修改，从而缩短了构建时间。为了实现这一点，我们将登台目录用作生成器的目标，并随后将内容与上一次编译运行的生成器输出进行同步：

The advanced approach uses CMake's copy_if_different feature to let only generated files that are affected by the model change to appear modified which results in better build times. To achieve that we use a staging directory as destination for the generator and sync the contents subsequently with the generator output of the previous compile run:

set(MODEL_FILE your_model_file)
set(GENERATOR_STAGING_DIR ${CMAKE_CURRENT_BINARY_DIR}/${MODEL_FILE}.staging)
set(GENERATOR_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/${MODEL_FILE})

set_directory_properties(PROPERTIES CMAKE_CONFIGURE_DEPENDS ${MODEL_FILE})

# Create fresh staging/final output directory
file(REMOVE_RECURSE ${GENERATOR_STAGING_DIR})
file(MAKE_DIRECTORY ${GENERATOR_STAGING_DIR})
file(MAKE_DIRECTORY ${GENERATOR_OUTPUT_DIR})

# Run code generation
execute_process(COMMAND your_code_generation_tool -o ${GENERATOR_STAGING_DIR} "${CMAKE_CURRENT_SOURCE_DIR}/${MODEL_FILE}")

# Remove stale files from final generator output directory
file(GLOB GENERATED_FILES RELATIVE "${GENERATOR_OUTPUT_DIR}/" "${GENERATOR_OUTPUT_DIR}/*")
foreach(FILE ${GENERATED_FILES})
    if(NOT EXISTS "${GENERATOR_STAGING_DIR}/${FILE}")
        file(REMOVE "${GENERATOR_OUTPUT_DIR}/${FILE}")
    endif()    
endforeach()

# Copy modified files from staging to final generator output directory
file(GLOB GENERATED_FILES RELATIVE "${GENERATOR_STAGING_DIR}/" "${GENERATOR_STAGING_DIR}/*")
foreach(FILE ${GENERATED_FILES})
    execute_process(COMMAND ${CMAKE_COMMAND} -E copy_if_different "${GENERATOR_STAGING_DIR}/${FILE}" "${GENERATOR_OUTPUT_DIR}")
endforeach()

file(GLOB LIBGENERATED_FILES "${GENERATOR_OUTPUT_DIR}/*")
add_library(libgenerated ${LIBGENERATED_FILES})
target_include_directories(libgenerated PUBLIC ${GENERATOR_OUTPUT_DIR})

这篇关于CMake编译生成的文件的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！