Visual Basic 6中的控件属性 [英] Control Properties in Visual Basic 6

问题描述

有没有办法在一个循环中请求控件属性？

Is there a way to ask for a control property in a loop??

我需要这样的东西：

For each p in control.properties
    if p = "Value" then
        msgbox "I Have Value Property"
    elseif p = "Caption" then
        msgbox "I Have Caption Property"
    end if 
next

$ b $，则
结尾b

这可以通过某种方式完成吗？

It could be done somehow?

推荐答案

在Experts Exchange上找到了此代码。添加对 TypeLib信息的引用。

Found this code on Experts Exchange. Add a reference to TypeLib Information.

Public Enum EPType
    ReadableProperties = 2
    WriteableProperties = 4
End Enum

Public Function EnumerateProperties(pObject As Object, pType As EPType) As Variant
    Dim rArray() As String
    Dim iVal As Long
    Dim TypeLib As TLI.InterfaceInfo
    Dim Prop As TLI.MemberInfo
    On Error Resume Next
    ReDim rArray(0) As String
    Set TypeLib = TLI.InterfaceInfoFromObject(pObject)
    For Each Prop In TypeLib.Members
        If Prop.InvokeKind = pType Then
            iVal = UBound(rArray)
            rArray(iVal) = UCase$(Prop.Name)
            ReDim Preserve rArray(iVal + 1) As String
        End If
    Next
    ReDim Preserve rArray(UBound(rArray) - 1) As String
    EnumerateProperties = rArray
End Function

您可以要求提供可读的列表，或者可写属性。

You can ask for a list of the readable, or writeable properties.

奖金，请问是否存在特定属性。

Bonus, ask if a specific property exists.

Public Function DoesPropertyExist(pObject As Object, ByVal _
    PropertyName As String, pType As EPType) As Boolean
    Dim Item As Variant
    PropertyName = UCase$(PropertyName)
    For Each Item In EnumerateProperties(pObject, pType)
        If Item = PropertyName Then
            DoesPropertyExist = True
            Exit For
        End If
    Next
End Function

这篇关于Visual Basic 6中的控件属性的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！