Excel计数范围内是否唯一 [英] Excel count unique in range if

问题描述

如果B列是一个值，则可以使用什么公式来计算A列中的唯一值.我在网上看到了很多，但是当仅使用Column range时，它们似乎都不起作用，数据的长度是可变的，因此只能使用column ref

What formula can be used to count unique values in column A if Column B is a value. i have seen many online but none of them seem to work when only using Column ranges , the data will be of varied length so only column ref can be used

这有效

=SUMPRODUCT((A1:A18<>"")*(B1:B18=$D$1)/COUNTIF(A1:A18,A1:A18))

但更改为

=SUMPRODUCT((A:A<>"")*(B:B=$D$1)/COUNTIF(A:A,A:A))

表

  A           B         C         D          E
12/12/2015  criteria1           criteria1      3
12/12/2015  criteria1           
13/12/2015  criteria1           
13/12/2015  criteria1           
14/12/2015  criteria1           
14/12/2015  criteria1           
18/12/2015  criteria2           
19/12/2015  criteria2           
20/12/2015  criteria2           
21/12/2015  criteria2           
22/12/2015  criteria2           
23/12/2015  criteria2           
24/12/2015  criteria3           
25/12/2015  criteria3           
26/12/2015  criteria3           
27/12/2015  criteria3           
28/12/2015  criteria3           
29/12/2015  criteria3       

我也尝试过用频率求和，但是总是不适用

I Have also tried sumproduct with frequency but always got N/A

推荐答案

如果您的数据在A1:B18中，而criteria1在C1中，请尝试:

If your data are in A1:B18, and criteria1 is in C1, try:

{=SUM(IF(FREQUENCY(IF(A1:A18<>"", IF(B1:B18=C1, MATCH(A1:A18, A1:A18, 0))), ROW(A1:A18)-ROW(A1)+1), 1))}

展开:

{=SUM(
    IF(
        FREQUENCY(
            IF(A1:A18<>"", 
                IF(B1:B18=C1, 
                    MATCH(A1:A18, A1:A18, 0)
                )
            ), 
            ROW(A1:A18)-ROW(A1)+1
        ), 
    1)
)}

使用 Ctrl Shift Enter

这篇关于Excel计数范围内是否唯一的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！