如何在F#的运行时创建新类型? [英] How to create new type at runtime in F#?

问题描述

请举例说明如何在运行时使用反射在F#中创建新类型(例如，两种笛卡尔积)?

Please give an example of how to create new type (say, two types Cartesian product) in F# at runtime with reflection?

更新

我正在寻找一种具有一流类型的语言.有人告诉我F#可以做到这一点.我没有尝试过F#，所以没有尝试.我只想看看它是怎么制成的.

I am looking for a language with first class types. I was told F# can this. I tried nothing since didn't learned F# yet. I just want to see how it's made.

推荐答案

以下F#代码采用2个值序列(在示例中为rank和suit)，并使用对数(卡)作为一系列对(卡)返回笛卡尔积.使用反射在运行时动态生成的配对类型:

The following F# code takes 2 sequences of values (rank and suit in the example) and returns the cartesian product as a sequence of pairs (cards), using a pair type dynamically generated at runtime using Reflection:

open System
open System.Reflection
open System.Reflection.Emit
open Microsoft.FSharp.Reflection

/// Creates a dynamic module via reflection
let createModule () =
    let name = Guid.NewGuid().ToString()
    let d = AppDomain.CurrentDomain
    let a = d.DefineDynamicAssembly(AssemblyName(name), AssemblyBuilderAccess.Run)
    a.DefineDynamicModule(name)
/// Creates a dynamic pair type using the specified x and y types
let createPairType (x:Type, y:Type) =
    let m = createModule()
    let t = m.DefineType("Pair", TypeAttributes.Public ||| TypeAttributes.Class)
    let x = t.DefineField(x.Name, x, FieldAttributes.Public)
    let y = t.DefineField(y.Name, y, FieldAttributes.Public)
    t.CreateType()
/// Creates a pair value using the specified pair type
let createPairValue (pairType:Type) (x:'X, y:'Y) =
    let instance = Activator.CreateInstance(pairType)
    pairType.GetField(typeof<'X>.Name).SetValue(instance, x)
    pairType.GetField(typeof<'Y>.Name).SetValue(instance, y)
    instance
/// Creates a cartesian product 
let createCartesianProduct (xs:'X seq, ys:'Y seq) =
    let pairType = createPairType (typeof<'X>,typeof<'Y>) 
    seq { for x in xs do for y in ys -> createPairValue pairType (x, y) }
/// Defines dynamic lookup operator for accessing a named field
let inline (?) (x:obj) name = x.GetType().GetField(name).GetValue(x)
/// Card suit discriminated union type
type Suit = Club | Diamond | Heart | Spade
/// Card rank discriminated union type 
type Rank = | One | Two | Three | Four | Five | Six | Seven | Eight | Nine | Ten
            | Jack | Queen | King | Ace
/// Gets union case values
let getUnionValues<'T>() = 
    FSharpType.GetUnionCases(typeof<'T>) 
    |> Seq.map (fun x -> FSharpValue.MakeUnion(x,[||]) :?> 'T)
let ranks, suits = getUnionValues<Rank>(), getUnionValues<Suit>()
/// Sequence of dynamically generated pairs
let cards = createCartesianProduct (ranks, suits)
// Paste this into F# interactive to print the generated cards
for card in cards do printfn "%A %A" card?Rank card?Suit

这篇关于如何在F#的运行时创建新类型?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！