用gnuplot绘制过程树 [英] Draw process tree with gnuplot
问题描述
类似于此问题的此处 我想在给定PID的情况下绘制进程树，我应该能够将该进程及其子级绘制为树.但是，我想保留节点/边之间的父子关系.我的意思是，任何两个孩子之间都不应该有优势.坐标实际上并不重要.另外，我也开放其他绘图工具选项.我尝试了提到的问题的可接受答案，但它链接了所有节点.
similar to this question here I want to draw process tree where a PID is given, I should be able to draw that process and its children as a tree. However, I want to preserve parent children relationship between nodes/edges. What I mean is, any two children should not have edge between. Coordinates actually do not matter. Also, I am open for other drawing tool options. I tried the accepted answer of mentioned question but it links all nodes.
任何建议/帮助都会使我高兴.
Any kind of suggestion/help would make my day.
注意:我正在使用Ubuntu
Note: I am using Ubuntu
推荐答案
您不会提供太多详细信息，无论您拥有什么以及想要什么.所以我假设一些事情.当然，还有改进的空间.要了解有关打印样式的更多信息，请在gnuplot控制台中检查help points，help vectors，help labels.
You don't give too many details what you have and what you exactly want. So I assume something. Certainly, room for improvements. To learn more about plotting styles, in gnuplot console check help points, help vectors, help labels.
代码:
### drawing a simple tree
reset session
$Children <<EOD
23
34
45
56
67
78
EOD
$Parent <<EOD
123
EOD
unset border
unset tics
Size = 8
set offsets 0.2,0.2,0.2,0.2
plot $Children u (Last=$0):(1):1 w labels not, \
'' u 0:(1):(Last/2-$0):(1) w vectors nohead lc rgb "black" notitle, \
'' u 0:(1):(Size) w p pt 7 ps var lc rgb "yellow" not, \
'' u 0:(1):1 w labels not, \
$Parent u (Last/2):(2):(Size) w p pt 7 ps var lc rgb "light-grey" not, \
'' u (Last/2):(2):1 w labels center not
### end of code
结果:
添加:
实际上，您可以使用gnuplot做一些更复杂的树图.幸运的是，gnuplot允许使用递归函数.
Actually, you can do a bit more complex tree diagrams with gnuplot. Fortunately, gnuplot allows for recursive functions.
输入由3列组成，不包含标题. 每个ID只有一个父节点，一个是顶级节点.一个ID可以有几个孩子.
The input consists out of 3 columns without header. Each ID has only one parent, except one which is the top node. An ID can have several children.
先决条件:
- 第1列包含唯一的整数ID号
- 第2列包含第1列中的子ID的父ID，或者是顶部节点的
NaN. - 第3列节点的标签名称
欢迎改进.
代码:(实际上是一些废话"树)
Code: (actually some "nonsense" tree)
### tree diagram with gnuplot
reset session
#ID Parent Name
$Data <<EOD
1 NaN Ant
2 1 Ape
3 1 Ass
4 2 Bat
5 2 Bee
6 2 Cat
7 3 Cod
8 3 Cow
9 3 Dog
10 7 Eel
11 7 Elk
12 7 Emu
13 9 Fly
14 9 Fox
15 4 Gnu
16 1 Hen
17 16 Hog
18 12 Jay
19 12 Owl
20 15 Pig
21 15 Pug
22 12 Ram
23 14 Rat
24 12 Sow
25 7 Yak
EOD
# put datablock into strings
IDs = Parents = Names = ''
set table $Dummy
plot $Data u (IDs = IDs.strcol(1).' '): \
(Parents = Parents.strcol(2).' '): \
(Names = Names.strcol(3).' ') w table
unset table
# Top node has no parent ID 'NaN'
Start(n) = int(sum [i=1:words(Parents)] (word(Parents,i) eq 'NaN' ? int(word(IDs,i)) : 0))
# get list index by ID
ItemIdx(s,n) = n == n ? (tmp=NaN, sum [i=1:words(s)] ((word(s,i)) == n ? (tmp=i,0) : 0), tmp) : NaN
# get parent of ID n
Parent(n) = word(Parents,ItemIdx(IDs,n))
# get level of ID n, recursive function
Level(n) = n == n ? Parent(n)>0 ? Level(Parent(n))-1 : 0 : NaN
# get number of children of ID n
ChildCount(n) = int(sum [i=1:words(Parents)] (word(Parents,i)==n))
# Create child list of ID n
ChildList(n) = (Ch = ' ', sum [i=1:words(IDs)] (word(Parents,i)==n ? (Ch = Ch.word(IDs,i).' ',1) : (Ch,0) ), Ch )
# m-th child of ID n
Child(n,m) = word(ChildList(n),m)
# List of leaves, recursive function
LeafList(n) = (LL='', ChildCount(n)==0 ? LL=LL.n.' ' : sum [i=1:ChildCount(n)] (LL=LL.LeafList(Child(n,i)), 0),LL)
# create list of all leaves
LeafAll = LeafList(Start(0))
# get x-position of ID n, recursive function
XPos(n) = ChildCount(n) == 0 ? ItemIdx(LeafAll,n) : (sum [i=1:ChildCount(n)] (XPos(Child(n,i))))/(ChildCount(n))
# create the tree datablock for plotting
set print $Tree
do for [j=1:words(IDs)] {
n = int(word(IDs,j))
print sprintf("% 3d % 7.2f % 4d % 5s", n, XPos(n), Level(n), word(Names,j))
}
set print
print $Tree
# get x and y distance from ID n to its parent
dx(n) = XPos(Parent(int(n))) - XPos(int(n))
dy(n) = Level(Parent(int(n))) - Level(int(n))
unset border
unset tics
set offsets 0.25, 0.25, 0.25, 0.25
plot $Tree u 2:3:(dx($1)):(dy($1)) w vec nohead ls -1 not,\
'' u 2:3 w p pt 7 ps 6 lc rgb 0xccffcc not, \
'' u 2:3 w p pt 6 ps 6 lw 1.5 lc rgb "black" not, \
'' u 2:3:4 w labels offset 0,0.1 center not
### end of code
结果:
这篇关于用gnuplot绘制过程树的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！
