使用Prolog DCG分割字符串 [英] Using a Prolog DCG to split a string

问题描述

我正在尝试使用DCG将字符串拆分为两个由空格分隔的部分.例如. 'abc def'应该还给我"abc"& "def".该程序和DCG在下面.

I'm trying to use a DCG to split a string into two parts separated by spaces. E.g. 'abc def' should give me back "abc" & "def". The program & DCG are below.

main:-
    prompt(_, ''),
    repeat,
    read_line_to_codes(current_input, Codes),
    (
        Codes = end_of_file
    ->
        true
    ;
        processData(Codes),
        fail
    ).

processData(Codes):-
    (
        phrase(data(Part1, Part2), Codes)
    ->
        format('~s, ~s\n', [ Part1, Part2 ])
    ;
        format('Didn''t recognize data.\n')
    ).

data([ P1 | Part1 ], [ P2 | Part2 ]) --> [ P1 | Part1 ], spaces(_), [ P2 | Part2 ].
spaces([ S | S1 ]) --> [ S ], { code_type(S, space) }, (spaces(S1); "").

这正常工作.但是我发现必须输入[ P1 | Part1 ]& [ P2 | Part2 ]真的很冗长.因此，我尝试替换所有[ P1 | Part1 ] w/Part1&在data的定义中同样使用w/[ P2 | Part2 ]，即以下内容.

This works correctly. But I found that having to type [ P1 | Part1 ] & [ P2 | Part2 ] was really verbose. So, I tried replacing all instances of [ P1 | Part1 ] w/ Part1 & likewise w/ [ P2 | Part2 ] in the definition of data, i.e. the following.

data(Part1, Part2) --> Part1, spaces(_), Part2.

输入起来容易得多，但这给了我一个Arguments are not sufficiently instantiated错误.因此，看起来未绑定的变量不会自动解释为DCG中的代码列表.还有什么其他方法可以使它变得不太冗长?我的意图是在其他编程语言中使用正则表达式的地方使用DCG.

That's much easier to type, but that gave me an Arguments are not sufficiently instantiated error. So it looks like an unbound variable isn't automatically interpreted as a list of codes in a DCG. Is there any other way to make this less verbose? My intent is to use DCG's where I would use regular expressions in other programming languages.

推荐答案

您的直觉是正确的；修改后的data版本的DCG的术语扩展过程(至少在SWI-Prolog中，但应适用于其他术语)给出以下内容:

Your intuition is correct; the term-expansion procedure for DCGs (at least in SWI-Prolog, but should apply to others) with your modified version of data gives the following:

?- listing(data). 

data(A, D, B, F) :-
    phrase(A, B, C),
    spaces(_, C, E),
    phrase(D, E, F).

如您所见，DCG规则的变量Part1和Part2部分已再次解释为对phrase/3的调用，而不是列表.您需要明确指定它们是列表，以便对其进行相应处理.

As you can see, the variable Part1 and Part2 parts of your DCG rule have been interpreted into calls to phrase/3 again, and not lists; you need to explicitly specify that they are lists for them to be treated as such.

我可以建议一个更通用的替代版本.请考虑以下DCG规则:

I can suggest an alternative version which is more general. Consider the following bunch of DCG rules:

data([A|As]) --> 
    spaces(_), 
    chars([X|Xs]), 
    {atom_codes(A, [X|Xs])}, 
    spaces(_), 
    data(As).
data([]) --> [].

chars([X|Xs]) --> char(X), !, chars(Xs).
chars([]) --> [].

spaces([X|Xs]) --> space(X), !, spaces(Xs).
spaces([]) --> [].

space(X) --> [X], {code_type(X, space)}. 
char(X) --> [X], {\+ code_type(X, space)}.

看看顶部的第一个子句；现在，data规则尝试匹配0到许多空格(由于切入而尽可能多)，然后使用一对非空格字符从代码中构造一个原子(A)，然后再次使用0对多的空格，然后递归以在字符串(As)中找到更多的原子.您最终得到的是一个原子列表，这些原子出现在输入字符串中，没有任何空格.您可以使用以下代码将此版本合并到您的代码中:

Take a look at the first clause at the top; the data rule now attempts to match 0-to-many spaces (as many as possible, because of the cut), then one-to-many non-space characters to construct an atom (A) from the codes, then 0-to-many spaces again, then recurses to find more atoms in the string (As). What you end up with is a list of atoms which appeared in the input string without any spaces. You can incorporate this version into your code with the following:

processData(Codes) :-
    % convert the list of codes to a list of code lists of words
    (phrase(data(AtomList), Codes) ->
        % concatenate the atoms into a single one delimited by commas
        concat_atom(AtomList, ', ', Atoms),
        write_ln(Atoms)
    ;
        format('Didn''t recognize data.\n')
    ).

此版本将单词之间的任意数量的空格分隔开，即使它们出现在字符串的开头和结尾.

This version breaks a string apart with any number of spaces between words, even if they appear at the start and end of the string.

这篇关于使用Prolog DCG分割字符串的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！