Inno Setup-如何本地化组件和类型名称? [英] Inno Setup - How to localize component and type names?

问题描述

如何本地化组件和类型名称?例如:

How to localize component and type names? For example:

[Languages]
Name: "eng"; MessagesFile: "Idiomas\English.isl"
Name: "spa"; MessagesFile: "Idiomas\Spanish.isl"

如果我选择英语:

[Types]
Name: "full"; Description: "Full installation"
Name: "compact"; Description: "Compact installation"
Name: "custom"; Description: "Custom installation"; Flags: iscustom

[Components]
Name: "program"; Description: "Program Files"; Types: full compact custom; Flags: fixed
Name: "readme"; Description: "Readme File"; Types: full

或者如果我选择西班牙语:

or if I choose Spanish:

[Types]
Name: "full"; Description: "Instalación Completa"
Name: "compact"; Description: "Instalación Mínima"
Name: "custom"; Description: "Instalación Personalizada"; Flags: iscustom

[Components]
Name: "program"; Description: "Archivos de Programa"; Types: full compact custom; Flags: fixed
Name: "readme"; Description: "Archivo de Ayuda"; Types: full

推荐答案

定义自定义消息在语言文件中:

• idiomas\English.isl:

[CustomMessages]
FullInstallation=Full installation
CompactInstallation=Compact installation
CustomInstallation=Custom installation
ProgramFilesComponent=Program Files
ReadmeFileComponent=Readme File

idiomas\Spanish.isl:

[CustomMessages]
FullInstallation=Instalación Completa
CompactInstallation=Instalación Mínima
CustomInstallation=Instalación Personalizada
ProgramFilesComponent=Archivos de Programa
ReadmeFileComponent=Archivo de Ayuda

或，您可以在主.iss文件中使用[CustomMessages]部分:

or you can use the [CustomMessages] section in the main .iss file:

[CustomMessages]
eng.FullInstallation=Full installation
spa.FullInstallation=Instalación Completa
...

，然后使用 {cm:MessageName}常量在您的脚本中:

And then use these custom messages using the {cm:MessageName} constant in your script:

[Types]
Name: "full"; Description: "{cm:FullInstallation}"
Name: "compact"; Description: "{cm:CompactInstallation}"
Name: "custom"; Description: "{cm:CustomInstallation}"; Flags: iscustom

[Components]
Name: "program"; Description: "{cm:ProgramFilesComponent}"; Types: full compact custom; Flags: fixed
Name: "readme"; Description: "{cm:ReadmeFileComponent}"; Types: full

这篇关于Inno Setup-如何本地化组件和类型名称?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！