我可以在VB6中生成一个同步过程并检索其返回值吗? [英] Can I spawn a synchronous process in VB6 and retrieve its return value?
问题描述
是否可以在VB6中生成一个同步进程(即调用一个外部.exe),等待它终止并获取返回值?
Is it possible to spawn a synchronous process in VB6 (i.e. calling an external .exe), wait for it to terminate, and grab the return value?
我们有旧代码(显然在VB6中),我们需要调用.NET应用程序来执行一些复杂的任务,并且基于.NET应用程序的返回值,执行还是失败.有做这种事情的更好的方法吗?
We have legacy code (in VB6 obviously) that we need to call a .NET application to perform some complicated tasks, and based on the .NET app's return value, either proceed or fail. Is there a better way of doing such a thing?
推荐答案
您的第一个选择可能应该是公开一个接口,以将.NET接口公开给COM并使用它(这样会更清洁),但是如果出于某种原因您必须使用此VB6代码通过生成的过程来完成此操作.
Your first option should probably be to expose an interface to expose the .NET interfaces to COM and use that (it is much cleaner), but if for some reason you have to do it through a spawned process use this VB6 code.
Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type
Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function CreateProcessA Lib "kernel32" (ByVal lpApplicationName As Long, ByVal lpCommandLine As String, ByVal lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, lpStartupInfo As STARTUPINFO, lpProcessInformation As PROCESS_INFORMATION) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function GetExitCodeProcess Lib "kernel32" (ByVal hProcess As Long, lpExitCode As Long) As Long
Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&
Private Const SW_HIDE = 0
Private Const SW_SHOWMINNOACTIVE = 7
Public Function ExecCmd(cmdline As String, workdir As String) As Integer
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO
Dim ret as Long
ChDrive Left(workdir, 1) & ":"
ChDir workdir
start.cb = Len(start)
start.wShowWindow = SW_SHOWMINNOACTIVE
Call CreateProcessA(0&, cmdline, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, start, proc)
Call WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret)
Call CloseHandle(proc.hThread)
Call CloseHandle(proc.hProcess)
ExecCmd=ret
End Function
这篇关于我可以在VB6中生成一个同步过程并检索其返回值吗?的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!