Array和Split命令创建二维数组 [英] Array and Split commands to create a 2 dimensional array

问题描述

使用split命令填充数组时遇到麻烦.

I'm having some trouble populating an array using a split command.

我当前的字符串在下面

MyString = "Row1 Column1[~]Row1 Column2[~]Row1 Column3" & vbNewLine & _
"Row2 Column1[~]Row2 Column2[~]Row2 Column3" & vbNewLine & _
"Row3 Column1[~]Row3 Column2[~]Row3 Column3" & vbNewLine & _
"Row4 Column1[~]Row4 Column2[~]Row4 Column3"

我有一个想要多维的数组，并且希望每个Row#Column#根据其编号位于数组的正确部分.

I have an array that I want to be multi-dimensional and would like each Row# Column# to be in the correct part of the array based on its number.

例如

MyArray(1,1) = "Row1 Column1"
MyArray(2,1) = "Row2 Column1"
MyArray(3,1) = "Row3 Column1"
MyArray(4,1) = "Row4 Column1"

MyArray(1,2) = "Row1 Column2"
MyArray(2,2) = "Row2 Column2"
MyArray(3,2) = "Row3 Column2"
MyArray(4,2) = "Row4 Column2"

MyArray(1,3) = "Row1 Column3"
MyArray(2,3) = "Row2 Column3"
MyArray(3,3) = "Row3 Column3"
MyArray(4,3) = "Row4 Column3"

现在，我了解了如何使用split命令填充一维数组

Now I understand how to populate a single dimension array using the split command

MyArray = Split(MyString, vbNewLine)

这意味着

MyArray(1) = "Row1 Column1[~]Row1 Column2[~]Row1 Column3"
MyArray(2) = "Row2 Column1[~]Row2 Column2[~]Row2 Column3"
MyArray(3) = "Row3 Column1[~]Row3 Column2[~]Row3 Column3"
MyArray(4) = "Row4 Column1[~]Row4 Column2[~]Row4 Column3"

但是我不知道如何使用split命令填充第二维.

But I don't know how to use a split command to populate the second dimension.

这是可能的，如果是这样的话吗?
如果不可能的话，有人可以建议如何实际填充吗?

Is this possible and if it is how?
If it isn't possible, can anyone suggest how to actually populate this?

推荐答案

除了String或包含String的Variant之外，不能在其他任何东西上使用Split().如果要生成二维字符串数组，则需要遍历Split()返回的数组，并在每个字符串上运行Split().下面的函数应该执行您想要的操作:

You can't use Split() on anything other than a String, or a Variant containing a String. If you want to generate a two dimensional string array, you will have iterate through the array returned by Split(), and run Split() on each string. The following function should do what you want:

Private Function SplitTo2DArray(ByRef the_sValue As String, ByRef the_sRowSep As String, ByRef the_sColSep As String) As String()

    Dim vasValue                    As Variant
    Dim nUBoundValue                As Long
    Dim avasCells()                 As Variant
    Dim nRowIndex                   As Long
    Dim nMaxUBoundCells             As Long
    Dim nUBoundCells                As Long
    Dim asCells()                   As String
    Dim nColumnIndex                As Long

    ' Split up the table value by rows, get the number of rows, and dim a new array of Variants.
    vasValue = Split(the_sValue, the_sRowSep)
    nUBoundValue = UBound(vasValue)
    ReDim avasCells(0 To nUBoundValue)

    ' Iterate through each row, and split it into columns. Find the maximum number of columns.
    nMaxUBoundCells = 0
    For nRowIndex = 0 To nUBoundValue
        avasCells(nRowIndex) = Split(vasValue(nRowIndex), the_sColSep)
        nUBoundCells = UBound(avasCells(nRowIndex))
        If nUBoundCells > nMaxUBoundCells Then
            nMaxUBoundCells = nUBoundCells
        End If
    Next nRowIndex

    ' Create a 2D string array to contain the data in <avasCells>.
    ReDim asCells(0 To nUBoundValue, 0 To nMaxUBoundCells)

    ' Copy all the data from avasCells() to asCells().
    For nRowIndex = 0 To nUBoundValue
        For nColumnIndex = 0 To UBound(avasCells(nRowIndex))
            asCells(nRowIndex, nColumnIndex) = avasCells(nRowIndex)(nColumnIndex)
        Next nColumnIndex
    Next nRowIndex

    SplitTo2DArray = asCells()

End Function

示例:

Dim asCells() As String

asCells() = SplitTo2DArray(MyString, vbNewline, "~")

这篇关于Array和Split命令创建二维数组的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！