perl，使用 IO::Select 和 IO::Socket::INET 读取阻塞 [英] perl, read blocking using IO::Select and IO::Socket::INET

问题描述

这个服务器工作正常，但如果我这样做

This server works fine but if I do this

bash$ (echo -n "abcd" ;sleep 50 ; echo "efgh") |nc 本地主机 9090

bash$ (echo -n "abcd" ;sleep 50 ; echo "efgh") | nc localhost 9090

服务器阻塞了 50 秒.在我的完整代码中，我有多个 IO::Select::INET.我有另一个套接字侦听其他端口(1234)，当服务器被睡眠阻塞时，我无法处理该端口中的任何内容.我尝试通过 getc 更改 getline 但我只读取了第一个字母a"并且它阻塞了.

The server blocks for 50 seconds.In my complete code I have more than one IO::Select::INET. I have another socket listen other port (1234), and I can't process anything in that port while the server is blocking by the sleep. I try change the getline by getc but I only read the first letter "a" and it blocks.

有人可以帮助我吗?

use common::sense;
use IO::Select;
use IO::Socket;

use constant PORT1 => 9090;
use constant TIMEOUT => 1;

my $event_socket  = new IO::Socket::INET(Listen => 1, LocalPort => PORT1, ReuseAddr => 1) 
    or die "Can't bind event_socket: $@\n";

my $sel = IO::Select->new;
$sel->add($event_socket);

my $event_emiter = undef;

while(1){ 
    foreach my $sock (my @ready = $sel->can_read(TIMEOUT)) {
        if ($sock == $event_socket) {
            my $new = $event_socket->accept;
            binmode($new, ":encoding(UTF-8)");
            $sel->add($new);

            $event_emiter=$new;

            warn "[event socket] connect from ",$new->peerhost, "\n";
        } elsif ($sock == $event_emiter) {
            unless($sock->eof){
                my $recv_data = $sock->getline;
                warn "[event socket] LOL '$recv_data'\n";
            } else {
                $sel->remove($sock);
                $sock->close;
                $event_emiter = undef;
                warn "[socket] disconnect\n";
            }
        } else {

            $sel->remove($sock);
            $sock->close;

            warn "[socket] disconnect\n";
        }
    }   
}

推荐答案

不是读取可用数据，而是读取直到读取换行符.始终使用 sysread.

Rather than reading available data, you're reading until you read a newline. Always use sysread.

改变

    elsif ($sock == $event_emiter) {
        unless($sock->eof){
            my $recv_data = $sock->getline;
            warn "[event socket] LOL '$recv_data'\n";
        } else {
            $sel->remove($sock);
            $sock->close;
            $event_emiter = undef;
            warn "[socket] disconnect\n";
        }
    }

到

    elsif ($sock == $event_emiter) {
        our $buf; local *buf = \$bufs{$fh};  # alias $buf = $bufs{$fh};

        my $rv = sysread($fh, $buf, 64*1024, length($buf));
        if (!$rv) {
            if (defined($rv)) {  # EOF
                # ... Handle anything left in $buf ...
            } else {  # Error
                # ... Handle error ...
            }

            delete $bufs{$fh};
            $sel->remove($sock);
            $sock->close;
            $event_emiter = undef;
            warn "[socket] disconnect\n";
            next;
        }

        while ($buf =~ s/^(.*)\n//) {
            warn "[event socket] LOL '$1'\n";
        }
    }

并在选择循环之外添加my %bufs;.

And add my %bufs; outside the select loop.

这篇关于perl，使用 IO::Select 和 IO::Socket::INET 读取阻塞的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！