如何使用VBScript从驱动器号中获取硬盘编号 [英] How to get Hard Disk number from drive letter using VBScript

问题描述

如何使用VBScript从盘符中获取硬盘编号?

How to get Hard Disk number from drive letter using VBScript?

提前致谢.

推荐答案

Remou 对 WMI 的看法是正确的，只是需要让它更乱一点.如果有更简单/更好的方法来执行此操作，您一点都不会感到惊讶，但此脚本至少应该为您提供一个执行所需操作的良好起点.

Remou is right about WMI, just have to make it a little bit more messy. Wouldn't be at all surprised if there's an easier/better way of doing this, but this script should at least give you a good starting point for doing what you need.

Dim query 
Dim objWMI 
Dim diskDrives 
Dim diskDrive 
Dim partitions 
Dim partition ' will contain the drive & partition numbers
Dim logicalDisks 
Dim logicalDisk ' will contain the drive letter

Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
Set diskDrives = objWMI.ExecQuery("SELECT * FROM Win32_DiskDrive") ' First get out the physical drives
For Each diskDrive In diskDrives 
    query = "ASSOCIATORS OF {Win32_DiskDrive.DeviceID='" + diskDrive.DeviceID + "'} WHERE AssocClass = Win32_DiskDriveToDiskPartition" ' link the physical drives to the partitions
    Set partitions = objWMI.ExecQuery(query) 
    For Each partition In partitions 
        query = "ASSOCIATORS OF {Win32_DiskPartition.DeviceID='" + partition.DeviceID + "'} WHERE AssocClass = Win32_LogicalDiskToPartition"  ' link the partitions to the logical disks 
        Set logicalDisks = objWMI.ExecQuery (query) 
        For Each logicalDisk In logicalDisks      
            Wscript.Echo logicalDisk.DeviceID & " - " & partition.Caption
        Next
    Next 
Next 

这将枚举所有驱动器号并为您提供结果，例如:C: - Disk #2, Partion #0

This will enumerate all drive letters and give you the results as for example: C: - Disk #2, Partion #0

这篇关于如何使用VBScript从驱动器号中获取硬盘编号的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！