在 XSLT 中实现键值概念 [英] Implementing Key Value Concept in XSLT
问题描述
我正在研究 XSLT,我需要实现以下内容.我的源 XML 示例如下所示.
I am working on XSLT, where I need to implement something as follows. My Source XML sample looks like this.
<?xml version="1.0" encoding="ISO-8859-1"?>
<catalog>
<cd>
<title>A</title>
<title>B</title>
<title>C</title>
</cd>
</catalog>
考虑有一些键值对列表.
Consider there is some key value pair list is there.
Key Value
A Algebra
B Biology
C Chemistry
D Data Analysis
--- ---
---- ---
我需要编写一个 xslt,以便每次出现键 'A' 时,都需要用适当的值替换.
I need to write an xslt such that for every occurance of key 'A', need to replace with appropriate value.
我还需要提到同一个 XSLT 中的键值对列表.示例输出:
I also need to mention the list of Key value pairs in the same XSLT. Sample Output:
<Data>
<Subject>Algebra</Subject>
<Subject>Biology</Subject>
<Subject>Chemistry</Subject>
</Data>
谁能帮我看看怎么做.
谢谢.
推荐答案
I.简单的 XSLT 1.0 解决方案
这种转变:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="my:my">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<my:codes>
<code key="A" value="Algebra"/>
<code key="B" value="Biology"/>
<code key="C" value="Chemistry"/>
<code key="D" value="Data Analysis"/>
</my:codes>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match=
"title/text()[. = document('')/*/my:codes/*/@key]">
<xsl:value-of select=
"document('')/*/my:codes/*[@key=current()]/@value"/>
</xsl:template>
</xsl:stylesheet>
应用于提供的 XML 文档时:
<catalog>
<cd>
<title>A</title>
<title>B</title>
<title>C</title>
</cd>
</catalog>
产生想要的、正确的结果:
<catalog>
<cd>
<title>Algebra</title>
<title>Biology</title>
<title>Chemistry</title>
</cd>
</catalog>
说明:
这是包含内联 XML 节点作为全局元素(xsl:stylesheet
的子元素)的标准方式,该元素属于(非空)命名空间,不同于 xsl 命名空间.
This is the standard way of including inline XML node as a global element (child element of xsl:stylesheet
) that belongs to a (non-empty) namespace, different than the xsl namespace.
二.更高效的 XSLT 1.0 解决方案,使用密钥:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="my:my">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<my:codes>
<code key="A" value="Algebra"/>
<code key="B" value="Biology"/>
<code key="C" value="Chemistry"/>
<code key="D" value="Data Analysis"/>
</my:codes>
<xsl:key name="kCodeByName" match="code" use="@key"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match=
"title/text()[. = document('')/*/my:codes/*/@key]">
<xsl:variable name="vCur" select="."/>
<xsl:for-each select="document('')">
<xsl:value-of select=
"key('kCodeByName', $vCur)/@value"/>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
当这个转换应用于同一个 XML 文档(上图)时,会产生同样正确的、想要的结果:
<catalog>
<cd>
<title value="Algebra"/>
<title value="Biology"/>
<title value="Chemistry"/>
</cd>
</catalog>
说明:
通过 key()
函数访问数据通常是次线性的——通常是 O(1) 并且比线性搜索快得多(如果要搜索的节点数是大).
Accessing data via the key()
function is typically sub-linear -- often O(1) and is extremely faster than linear search (which is important if the number of nodes to be searched is big).
如果包含要查找的节点的文档是当前文档,则可以在处理另一个文档的节点时通过索引 (xsl:key
) 访问一个文档的节点.要从另一个文档访问节点,它的根(或感兴趣的节点需要保存并从变量中引用.)
Accessing a node of one document via an index (xsl:key
) while processing a node of another document is possible if the document containing the node to be looked-up is the current document. To access nodes from the other document, its root (or node of interest need to be saved and referenced off a variable.)
三.XSLT 2.0 解决方案:
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="my:my">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:variable name="vCodes">
<codes>
<code key="A" value="Algebra"/>
<code key="B" value="Biology"/>
<code key="C" value="Chemistry"/>
<code key="D" value="Data Analysis"/>
</codes>
</xsl:variable>
<xsl:key name="kCodeByName" match="code" use="string(@key)"/>
<xsl:template match="node()|@*">
<xsl:copy>
<xsl:apply-templates select="node()|@*"/>
</xsl:copy>
</xsl:template>
<xsl:template match=
"title/text()[key('kCodeByName', ., $vCodes)]">
<xsl:sequence select=
"key('kCodeByName', ., $vCodes)/@value"/>
</xsl:template>
</xsl:stylesheet>
当这个转换应用于同一个 XML 文档(上图)时,会产生同样正确的、想要的结果:
<catalog>
<cd>
<title value="Algebra"/>
<title value="Biology"/>
<title value="Chemistry"/>
</cd>
</catalog>
说明:
与高效的 XSLT 1.0 解决方案几乎相同,但是:
Almost the same as the efficient XSLT 1.0 solution, but:
在 XSLT 2.0 中,模板匹配模式可以包含变量引用.
在 XSLT 2.0 中,不需要操作当前和索引文档的杂技——key()
函数的第三个参数是指定要使用其索引的树.
In XSLT 2.0 there is no need for acrobatic tricks manipulating the current and the indexed documents -- the 3rd argument of the key()
function is to specify the tree whose index to use.
这篇关于在 XSLT 中实现键值概念的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!