向递归中的所有链添加公共属性 [英] Adding common attribute to all chains in recursion
本文介绍了向递归中的所有链添加公共属性的处理方法,对大家解决问题具有一定的参考价值,需要的朋友们下面随着小编来一起学习吧!
问题描述
后续问题:用一个最深的循环限制递归并为所有元素分配精确的 id
此代码收集递归.同时,所有递归元素都必须接收一个 COMMON-ID
属性,该属性具有来自链的第一个元素的值.第一个元素也有一个属性 STATUS="0"
.其他元素有 STATUS="1"
(对于解决方案,它可能有用).
This code collects recursion.
It is necessary that at the same time all recursion elements receive a COMMON-ID
attribute with the value from the first element of the chain. This first element has also an attribue STATUS="0"
. Other elements have STATUS="1"
(for solution it may be useful).
1 个来源
<root>
<object id="a" id-3="COMMON-ID-1" STATUS="0"/>
<object id="b" id-3="COMMON-ID-2" STATUS="0"/>
<object id="c" id-3="COMMON-ID-3" STATUS="0"/>
<object id="aa" parent-id="a" id-3="value" STATUS="1"/>
<object id="bb" parent-id="b" id-3="value" STATUS="1"/>
<object id="cc" parent-id="c" id-3="value" STATUS="1"/>
<object id="aaa" parent-id="aa" id-3="value" STATUS="1"/>
<object id="bbb" parent-id="bb" id-3="value" STATUS="1"/>
<object id="ccc" parent-id="cc" id-3="value" STATUS="1"/>
<object id="bbbb" parent-id="bbb" id-3="value" STATUS="1"/>
<object id="cccc" parent-id="ccc" id-3="value" STATUS="1"/>
<object id="bbbbb" parent-id="bbbb" id-3="value" STATUS="1"/>
</root>
2-present XSLT(不分配COMMON-ID
)
2-present XSLT (do not assign COMMON-ID
)
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:key name="child" match="object" use="@parent-id" />
<xsl:template match="/root">
<!-- generate chains -->
<xsl:variable name="chains">
<xsl:apply-templates select="object[not(@parent-id)]"/>
</xsl:variable>
<!-- find the longest chain -->
<xsl:for-each select="exsl:node-set($chains)/object">
<xsl:sort select="count(descendant::object)" data-type="number" order="descending"/>
<xsl:if test="position()">
<xsl:copy-of select="."/>
</xsl:if>
</xsl:for-each>
</xsl:template>
<xsl:template match="object">
<xsl:copy>
<xsl:copy-of select="@*"/>
<xsl:apply-templates select="key('child', @id)"/>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
3-期望的输出
<?xml version="1.0" encoding="UTF-8"?>
<object id="b" id-3="COMMON-ID-1" STATUS="0" COMMON-ID="COMMON-ID-2">
<object id="bb" parent-id="b" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2>
<object id="bbb" parent-id="bb" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2>
<object id="bbbb" parent-id="bbb" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2>
<object id="bbbbb" parent-id="bbbb" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-2/>
</object>
</object>
</object>
</object>
<object id="c" id-3="COMMON-ID-3" STATUS="0" COMMON-ID="COMMON-ID-3">
<object id="cc" parent-id="c" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-3">
<object id="ccc" parent-id="cc" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-3">
<object id="cccc" parent-id="ccc" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-3"/>
</object>
</object>
</object>
<object id="a" id-3="COMMON-ID-1" STATUS="0" COMMON-ID="COMMON-ID-1">
<object id="aa" parent-id="a" id-3="value" STATUS="1" COMMON-ID="COMMON-ID-1">
<object id="aaa" parent-id="aa" id-3="COMMON-ID-1" STATUS="1" COMMON-ID="COMMON-ID-1"/>
</object>
</object>
推荐答案
将您的第二个模板更改为:
Change your 2nd template to:
<xsl:template match="object">
<xsl:param name="common-id" select="@id-3"/>
<xsl:copy>
<xsl:copy-of select="@*"/>
<xsl:attribute name="COMMON-ID">
<xsl:value-of select="$common-id"/>
</xsl:attribute>
<xsl:apply-templates select="key('child', @id)">
<xsl:with-param name="common-id" select="$common-id"/>
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
这篇关于向递归中的所有链添加公共属性的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!
查看全文