在 Perl 中，如何更改、删除或在文件中插入一行，或附加到文件的开头? [英] In Perl, how do I change, delete, or insert a line in a file, or append to the beginning of a file?

问题描述

我想通过修改、删除或插入行或附加到文件的开头来更改文件的内容.我怎样才能在 Perl 中做到这一点?

I want to make changes to the contents of a file by modifying, deleting or inserting lines or appending to the beginning of the file. How can I do that in Perl?

这是来自 问题.perl.org/" rel="noreferrer">官方常见问题解答.我们将 perlfaq 导入 Stack Overflow..>

This is a question from the official FAQ. We're importing the perlfaq to Stack Overflow.

推荐答案

(这是官方perlfaq 答案，减去任何后续编辑)

(This is the official perlfaq answer, minus any subsequent edits)

在文本文件中插入、更改或删除一行的基本思想涉及读取和打印文件到您想要制作的点更改，进行更改，然后读取并打印文件的其余部分.Perl 不提供对行的随机访问(特别是因为记录输入分隔符 $/ 是可变的)，尽管模块如Tie::File 可以伪造.

The basic idea of inserting, changing, or deleting a line from a text file involves reading and printing the file to the point you want to make the change, making the change, then reading and printing the rest of the file. Perl doesn't provide random access to lines (especially since the record input separator, $/, is mutable), although modules such as Tie::File can fake it.

执行这些任务的 Perl 程序采用打开文件的基本形式，打印其行，然后关闭文件:

A Perl program to do these tasks takes the basic form of opening a file, printing its lines, then closing the file:

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

while( <$in> )
    {
    print $out $_;
    }

close $out;

在该基本表格中，添加您需要插入、更改或删除行.

Within that basic form, add the parts that you need to insert, change, or delete lines.

要在开头添加行，请在输入之前打印这些行打印现有行的循环.

To prepend lines to the beginning, print those lines before you enter the loop that prints the existing lines.

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n"; # <--- HERE'S THE MAGIC

while( <$in> )
    {
    print $out $_;
    }

close $out;

要更改现有行，请插入代码以修改其中的行while 循环.在这种情况下，代码会找到perl"的所有小写版本并将它们大写.每一行都会发生这种情况，所以请确保您应该在每一行都这样做！

To change existing lines, insert the code to modify the lines inside the while loop. In this case, the code finds all lowercased versions of "perl" and uppercases them. The happens for every line, so be sure that you're supposed to do that on every line!

open my $in,  '<',  $file      or die "Can't read old file: $!";
open my $out, '>', "$file.new" or die "Can't write new file: $!";

print $out "# Add this line to the top\n";

while( <$in> )
    {
    s/\b(perl)\b/Perl/g;
    print $out $_;
    }

close $out;

要仅更改特定行，输入行号 $. 很有用.首先阅读并打印到您要更改的行.接下来，阅读要更改的单行，更改并打印.在那之后，阅读其余的行并打印出来:

To change only a particular line, the input line number, $., is useful. First read and print the lines up to the one you want to change. Next, read the single line you want to change, change it, and print it. After that, read the rest of the lines and print those:

while( <$in> )   # print the lines before the change
    {
    print $out $_;
    last if $. == 4; # line number before change
    }

my $line = <$in>;
$line =~ s/\b(perl)\b/Perl/g;
print $out $line;

while( <$in> )   # print the rest of the lines
    {
    print $out $_;
    }

要跳过行，请使用循环控件.本示例中的下一个跳过注释行，最后一个在遇到任何一个时停止所有处理__END__ 或 __DATA__.

To skip lines, use the looping controls. The next in this example skips comment lines, and the last stops all processing once it encounters either __END__ or __DATA__.

while( <$in> )
    {
    next if /^\s+#/;             # skip comment lines
    last if /^__(END|DATA)__$/;  # stop at end of code marker
    print $out $_;
    }

通过使用 next 跳过，做同样的事情来删除特定的行您不想在输出中显示的行.这个例子跳过了每个第五行:

Do the same sort of thing to delete a particular line by using next to skip the lines you don't want to show up in the output. This example skips every fifth line:

while( <$in> )
    {
    next unless $. % 5;
    print $out $_;
    }

如果出于某种奇怪的原因，您真的想一次查看整个文件而不是逐行处理，你可以把它吞进去(只要你能将整个内容放入内存中！):

If, for some odd reason, you really want to see the whole file at once rather than processing line-by-line, you can slurp it in (as long as you can fit the whole thing in memory!):

open my $in,  '<',  $file      or die "Can't read old file: $!"
open my $out, '>', "$file.new" or die "Can't write new file: $!";

my @lines = do { local $/; <$in> }; # slurp!

    # do your magic here

print $out @lines;

模块，例如 File::Slurp而 Tie::File 可以帮助解决这个问题也.但是，如果可以，请避免一次读取整个文件.Perl 不会将该内存还给操作系统，直到进程完成.

Modules such as File::Slurp and Tie::File can help with that too. If you can, however, avoid reading the entire file at once. Perl won't give that memory back to the operating system until the process finishes.

您还可以使用 Perl 单行程序就地修改文件.下列将 inFile.txt 中的所有 'Fred' 更改为 'Barney'，用新内容.使用 -p 开关，Perl 在代码周围包裹一个 while 循环你用 -e 指定，-i 开启就地编辑.目前行在 $_ 中.使用 -p，Perl 自动打印 $_ 的值在循环的结束.有关详细信息，请参阅 perlrun.

You can also use Perl one-liners to modify a file in-place. The following changes all 'Fred' to 'Barney' in inFile.txt, overwriting the file with the new contents. With the -p switch, Perl wraps a while loop around the code you specify with -e, and -i turns on in-place editing. The current line is in $_. With -p, Perl automatically prints the value of $_ at the end of the loop. See perlrun for more details.

perl -pi -e 's/Fred/Barney/' inFile.txt

要备份 inFile.txt，给 -i 一个要添加的文件扩展名:

To make a backup of inFile.txt, give -i a file extension to add:

perl -pi.bak -e 's/Fred/Barney/' inFile.txt

如果只改变第五行，可以添加一个测试检查$.，输入行号，然后只在测试通过时执行操作:

To change only the fifth line, you can add a test checking $., the input line number, then only perform the operation when the test passes:

perl -pi -e 's/Fred/Barney/ if $. == 5' inFile.txt

要在某行之前添加行，您可以在之前添加一行(或多行！)Perl 打印 $_:

To add lines before a certain line, you can add a line (or lines!) before Perl prints $_:

perl -pi -e 'print "Put before third line\n" if $. == 3' inFile.txt

你甚至可以在文件的开头添加一行，因为当前行在循环结束时打印:

You can even add a line to the beginning of a file, since the current line prints at the end of the loop:

perl -pi -e 'print "Put before first line\n" if $. == 1' inFile.txt

要在文件中已有的一行之后插入一行，请使用 -n 开关.它是就像 -p 一样，只是它在循环结束时不打印 $_，所以你必须自己做.在这种情况下，先打印 $_，然后打印要添加的行.

To insert a line after one already in the file, use the -n switch. It's just like -p except that it doesn't print $_ at the end of the loop, so you have to do that yourself. In this case, print $_ first, then print the line that you want to add.

perl -ni -e 'print; print "Put after fifth line\n" if $. == 5' inFile.txt

要删除行，只打印你想要的行.

To delete lines, only print the ones that you want.

perl -ni -e 'print unless /d/' inFile.txt

这篇关于在 Perl 中，如何更改、删除或在文件中插入一行，或附加到文件的开头?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！