根据用户名获取 AD 详细信息 [英] Getting AD Details based on username

问题描述

我有一个代码可以从 AD 中检索用户的详细信息，例如电子邮件地址、电话号码等.我目前使用的代码是:

I have a code to retrieve the details of a user from the AD such as email address, phone number etc, etc. The codes I am currently using is:

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = objSysInfo.UserName
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

它获取当前登录用户的详细信息.但我现在需要做的是解析用户的用户名并基于此检索详细信息.

It gets the currently logged in user's details. But what I need to do now is to parse in the user's username and retrieve the details based on that.

我尝试将 objSysinfo.UserName 更改为用户名，但返回空白.

I have tried to change objSysinfo.UserName to the username and it returned blank.

Set objSysInfo = CreateObject("ADSystemInfo")
strUser = "SomeUserName"
msgbox(strUser)
Set objUser = GetObject("LDAP://" & strUser)

我应该如何根据提供的用户名从 AD 中检索详细信息?

How should I go about retrieving the details from the AD based on a user name provided?

推荐答案

LDAP URI 需要专有名称.帐户名称不起作用.如果您想根据帐户名称获取用户对象，您需要一个常规"的LDAP 查询:

LDAP URIs require a distinguished name. Account names won't work. If you want to get user objects based on the account name you need a "regular" LDAP query:

username = "SomeUserName"

Set rootDSE = GetObject("LDAP://RootDSE")
base  = "<LDAP://" & rootDSE.Get("defaultNamingContext") & ">"
'filter on user objects with the given account name
fltr  = "(&(objectClass=user)(objectCategory=Person)" & _
        "(sAMAccountName=" & username & "))"
'add other attributes according to your requirements
attr  = "distinguishedName,sAMAccountName"
scope = "subtree"

Set conn = CreateObject("ADODB.Connection")
conn.Provider = "ADsDSOObject"
conn.Open "Active Directory Provider"

Set cmd = CreateObject("ADODB.Command")
Set cmd.ActiveConnection = conn
cmd.CommandText = base & ";" & fltr & ";" & attr & ";" & scope

Set rs = cmd.Execute
Do Until rs.EOF
  WScript.Echo rs.Fields("distinguishedName").Value
  rs.MoveNext
Loop
rs.Close

conn.Close

由于我对一遍又一遍地编写所有样板代码感到恼火，所以我将它封装在一个类中 (ADQuery) 前一段时间.

Since I got annoyed from having to write all that boilerplate code over and over again, I wrapped it in a class (ADQuery) some time ago.

这篇关于根据用户名获取 AD 详细信息的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！