创建批处理脚本来解压缩，无需额外压缩工具的文件 [英] creating batch script to unzip a file without additional zip tools

问题描述

我试图做一个.BAT脚本为Windows 7 64位系统创建一个文件夹，解压缩文件到该文件夹​​，而无需使用额外的插件像7zip的或解压缩。一直在寻找，它似乎像Windows不具备内建允许解压容易命令。我可以解压缩/扩展文件，而无需额外的插件？

I'm trying to make a .bat script for windows 7 x64 to create a folder, unzip a file into that folder without having to use additional addons like 7zip or unzip. Been searching and it seemed like windows doesn't have builtins to allow unzip easily in command. Can I unzip/expand files without additional addons?

推荐答案

试试这个：

@echo off
setlocal
cd /d %~dp0
Call :UnZipFile "C:\Temp\" "c:\path\to\batch.zip"
exit /b

:UnZipFile <ExtractTo> <newzipfile>
set vbs="%temp%\_.vbs"
if exist %vbs% del /f /q %vbs%
>%vbs%  echo Set fso = CreateObject("Scripting.FileSystemObject")
>>%vbs% echo If NOT fso.FolderExists(%1) Then
>>%vbs% echo fso.CreateFolder(%1)
>>%vbs% echo End If
>>%vbs% echo set objShell = CreateObject("Shell.Application")
>>%vbs% echo set FilesInZip=objShell.NameSpace(%2).items
>>%vbs% echo objShell.NameSpace(%1).CopyHere(FilesInZip)
>>%vbs% echo Set fso = Nothing
>>%vbs% echo Set objShell = Nothing
cscript //nologo %vbs%
if exist %vbs% del /f /q %vbs%

修改

要拥有它的每个压缩文件创建每次使用一个文件夹执行解压：

To have it perform the unzip on each zip file creating a folder for each use:

@echo off
setlocal
cd /d %~dp0
for %%a in (*.zip) do (
    Call :UnZipFile "C:\Temp\%%~na\" "c:\path\to\%%~nxa"
)
exit /b

如果你不希望它为每个拉链，更改创建一个文件夹
呼叫：UnZipFileC：\\ TEMP \\ %%〜呐\\C：\\路径\\为\\ %%〜NXA来
呼叫：UnZipFileC：\\ TEMP \\C：\\路径\\为\\ %%〜NXA

If you don't want it to create a folder for each zip, change Call :UnZipFile "C:\Temp\%%~na\" "c:\path\to\%%~nxa" to Call :UnZipFile "C:\Temp\" "c:\path\to\%%~nxa"

这篇关于创建批处理脚本来解压缩，无需额外压缩工具的文件的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！