而写回新的IPS显示器定义DNS解析和变更路线 [英] Monitor defined DNS resolutions and change routes while writing back new IPs
本文介绍了而写回新的IPS显示器定义DNS解析和变更路线的处理方法，对大家解决问题具有一定的参考价值，需要的朋友们下面随着小编来一起学习吧！
问题描述
我有一些FTP服务器不是由IP定义了这个问题。相反，DNS名称provieded，所以他们可能会切换服务器之后容易，同时使客户处理问题，因为没有路由器和防火墙可以通过DNS名称（谢天谢地，是这样）得到定义。
I have the problem that some FTP servers are not defined by IP anymore. Instead DNS names are provieded, so they may switch servers behind easily, while leaving customers with the problem of handling, because no routers and firewalls can get defined with DNS names (thank god it is this way).
我有想法写一个简单的脚本，需要通过脚本来监视定义DNS解析和更改路线。
I had the idea to write a simple script to monitor defined DNS resolutions and change routes as needed by script.
请参阅所产生的脚本我的答案underneth。日Thnx到MC ND。
See the resulting scripts underneth in my answers. Thnx to MC ND.
我相信人们可以在几个项目进一步优化我的code：）
I am sure one could optimize my code at several further items :)
要考验你将需要一个文件 C：\\包含例如两行日志\\ dnstests.txt ：
To test you will need to make a file C:\log\dnstests.txt which contains for example two lines:
www.stackoverflow.com=7.7.7.7
www.heise.de=198.252.206.16
这是两个很好的例子，因为第一个域确实提供了IP地址后的别名，我可以通过过滤找到，但第二个不另外提供一个IP6应该得到过滤了。
This are two nice examples because, first domain does provide an alias after the IP adress which I could filter by find, but second does provide an ip6 additionally which should get filtered too.
如果有人告诉我如何读取和写入一行行，并从文件这可以提高脚本的稳定性，如果脚本断了， testfile将几乎是空的。所以，如果你改变这种过度的测试脚本code小心地测试所有可能的情况下，D）。
If someone would show me how to read and write line by line to and from file this could improve stability of script, as if the script breaks, the testfile will almost be empty. So if you change this excessive tested scriptcode be careful to test all possible cases D).
任何帮助将是非常美联社preciated，而我可以想像很多人会需要这个脚本在那里，我不知道，没有什么是可以找到？
Any help would be really appreciated, while I could imagine a lot people could need this script out there and I wondered that nothing was to find?
推荐答案
以防万一有人可能有一天觉得有必要通过sheduled脚本（包括设置线路：dails还活着的电子邮件，IP6过滤和智能行为在loadbalanced IP的，只要它列出），以保持旧的。
所有你需要的是语法的文件dnstests.txt在文件目录：
All you need is a file "dnstests.txt" in script directory with syntax:
first.domain.tld=1.2.3.4
your.second.tld=5.6.7.8
下面是code（感谢名单，以MC ND智能NSlookup的过滤器）：
Here is the code (thanx to MC ND for smart NSlookup filter):
@ECHO OFF
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
REM ++++++++++++++++++++++++++++ BLAT EMAIL CONFIG ++++++++++++++++++++++++++++++++++++
set eMailTO=someone@somedomain.somewhere
set eMailCC=someone@somedomain.somewhere
set eMailFROM=dnstestscript
set server=0.0.0.0
REM you have to install blat of course, here "echo blat ..." is used where it would be
REM useful to send an email on interesting items, but it is also sent to shell and log
REM +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM ++++++++++++++++++++++++++++ MAKE DATE ++++++++++++++++++++++++++++++++++++++++++++
for /F "usebackq tokens=1,2 delims==" %%i in (`wmic os get LocalDateTime /VALUE 2^>NUL`) do if '.%%i.'=='.LocalDateTime.' set ldt=%%j
REM make timestamp (date reverse)
set STAMP=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2%--%ldt:~8,2%-%ldt:~10,2%--%ldt:~12,2%-%ldt:~15,3%
set ACTUALDATE=%ldt:~0,4%-%ldt:~4,2%-%ldt:~6,2%
REM +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM ++++++++++++++++++++++++++++ SCRIPT CONFIG ++++++++++++++++++++++++++++++++++++++++
set "XScriptnamE=%~n0"
set "XSCRIPTDIR=%~dp0"
set "LOGDIR=%XSCRIPTDIR%\%XScriptnamE%"
if not exist "%LOGDIR%" mkdir "%LOGDIR%"
set "LOG=%LOGDIR%\%XScriptnamE%.log"
REM +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM ++++++++++++++++++++++++++++ SCRIPT ALIVE ++++++++++++++++++++++++++++++++++++++++
REM now tell us once a day that script is up and running
set DateLOG=%XSCRIPTDIR%\%XScriptnamE%-date.txt
if not exist "%DateLOG%" echo %ACTUALDATE% > %DateLOG%
set /p BEFOREDATE=< %DateLOG%
if NOT %ACTUALDATE% == %BEFOREDATE% (
echo %ACTUALDATE% > %DateLOG%
echo blat %0 -subject "DNS Routes Script is alive and running! OK" -body "DNS-routing-script up and running - DNS routing is OK!" -to %eMailTO% -cc %eMailCC% -f %eMailFROM% %server%
)
REM +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM make errorlooging expand
set "XLOGX=xpipex && type xpipex && type xpipex >> %LOG%"
REM or make individual run logs
REM set "LOG=%LOGDIR%\%XScriptnamE%\%XScriptnamE%-%STAMP%.log"
REM not global vars come here
set "DNSTESTFILE=%XSCRIPTDIR%\dnstests.txt"
REM set GATEWAY here
set GW=7.7.7.7
REM to reflect GW changes here a route has to be set with each run if this is needed turn switch to 2
REM otherwise only missing routes get re set by switch 1 (default)
set REFRESH-GW=1
REM +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM do never set something here at errorlog plz otherwise compare of happened errors wont work
set errorlog=
pushd=%XSCRIPTDIR%
REM +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
echo ================================================== >> %LOG%
echo Script run at %STAMP% >> %LOG%
REM +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM ++++++++++++++++++++++++++++ START ++++++++++++++++++++++++++++++++++++++++++++++++
REM if the script is run in cmd we see enough information to follow actions but they are written to a log file too for sheduled use
REM ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM when a batch script needs to use drives not local, eg shares it always needs special rights,
REM means you need to use an account to run the script which is allowed to log on as batch task in
REM secpol - (click start type secpol.msc and start it - Select "Local Policies" in MSC snap
REM in - Select "User Rights Assignment" - Right click on "Log on as batch job" and select
REM Properties - Click "Add User or Group", and include the relevant user.)
REM ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM ++++++++++++ make a loop for each line in file ++++++++++++++++++++++++++++++++++++
REM first we test if script is able to set routes and got admin rights
REM if delete fails, with false parameter -> script is elevated
REM otherwise the missing elevated rights get reported to log
echo.
echo "if route delete fails, with false parameter -> script is elevated"
echo "otherwise the missing elevated rights get reported to console"
echo.
route delete 999.999.999.999
echo. >> %LOG%
echo "if route delete fails, missing elevated rights get reported to log " >> %LOG%
echo "otherwise the script is elevated and you find only this text in log" >> %LOG%
echo. >> %LOG%
route delete 999.999.999.999 >> %LOG%
REM read them in different vars to call processing
REM check for test file
if NOT exist "%DNSTESTFILE%" (
set errorlog=%errorlog% : error dns file not exist :
echo blat error dnsfile
echo error dnsfile not exist >> %log%
)
REM read test file
set Counter=1
for /f %%s in (%DNSTESTFILE%) do (
set "Line_!Counter!=%%s"
set /a Counter+=1
)
set /a NumLines=Counter - 1
REM make a backup of old test file before nulling it
copy /y %DNSTESTFILE% %DNSTESTFILE%.bak 2>&1 > %XLOGX%
REM as i found no easy way to rewrite the specific line i choose to read out all lines in vars,
REM now we nul the file and rewrite lines later, BE aware if script breaks all lines are lost most times
REM instead of only one, so edit it carefully and test carefully all cases possible
type NUL > %DNSTESTFILE%
REM now use vars to call processing
for /l %%r in (1,1,%NumLines%) do (
set "q=!Line_%%r!"
echo. >> %log%
echo.
call :check !q!
)
REM did all go well or what did we miss?
if NOT "%errorlog%."=="." (
echo.
echo blat summary %errorlog%!
echo. >> %LOG%
echo %errorlog%! >> %LOG%
)
REM ++++++++++++++++++++++++++++ END +++++++++++++++++++++++++++++++++++++++++++++++++++
REM next line tells us script did run through code while one may want to save this lines
echo ==================script finished================= >> %log%
del xpipex
break
goto :eof
REM ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
REM +++++++++++++++++++++++++++++ PROCESSING +++++++++++++++++++++++++++++++++++++++++++
:check
REM trim whitespace from beginning and end of line
for /f "tokens=* delims=" %%z in ("!q!") do (
set "line=!q!"
REM test if line is valid dns AND ip address syntax BUT only informational because of limited regular expression support of findstr and "1234.2.3.4" is also accepted as well formatted address
echo !line! | findstr /i /r "^[a-z0-9-]*\.[a-z0-9-]*\.[a-z0-9-]*=[0-9]*\.[0-9]*\.[0-9]*\.[0-9]*" >NUL || (
echo blat error in dns test line syntax with: !line!
set errorlog=%errorlog% : error in dns test line syntax with: !line! :
)
REM test that trimmed line matches at least once "^char=number$" and set vars for test
echo !line! | findstr /i "^[a-z]*=[0-9]*$" >NUL && do (
for /f "tokens=1,2 delims==" %%x in ("!q!") do set TESTDNS=%%x&set TESTIP=%%y
)
REM trim whitespace from vars
set TESTDNS=%TESTDNS: =%
set TESTIP=%TESTIP: =%
echo testing %TESTDNS% to %TESTIP%
echo checking %TESTDNS%: >> %LOG%
REM useful to test script
REM nslookup %TESTDNS%
REM useful to test script
REM go get dns resolution and set vars to test and compare
set "XIP="
for /f "skip=1 tokens=*" %%a in ('nslookup "%TESTDNS%" 2^>nul ^| findstr /i /r /c:"address[e]*[s]*:.*\." /c:"address[ ]*=.*\." /c:"^[ ][ ]*[0-9].*\." ') do (
rem get nslookup output
set "_line=%%a"
rem remove spaces
set "_line=!_line: =!"
rem parse line
for /f "tokens=1,* delims=:=" %%b in ("!_line!") do (
rem retrieve the correct section of the line
if "%%c"=="" (
set "XTIPX=%%b"
) else (
set "XTIPX=%%c"
)
REM again trim whitespace from var
set XTIPX=!XTIPX: =!
rem test address match to old address
if "!XTIPX!"=="%TESTIP%" (
set "XIP=!XTIPX!"
goto endRESTESTDNS
)
rem if no match, the first address found is saved
if not defined XIP set "XIP=!XTIPX!"
)
)
:endRESTESTDNS
REM if dsn did change
if NOT %XIP%==%TESTIP% (
echo %TESTDNS% NOW is %XIP%
REM delete the old route and set new one
REM first check if the old false ip was set to prevent error if not found
netsh interface ipv4 show route | find /i "%TESTIP%" >NUL
if errorlevel 1 (
echo blat there was no route for given %TESTIP% from file, routes manipulated or file updated?
echo there was no route for given %TESTIP% from file, routes manipulated or file updated? >> %LOG%
set errorlog=%errorlog% : there was no route for given %TESTIP% from file, routes manipulated or file updated? :
) else (
Route DELETE %TESTIP% >> %LOG%
)
Route ADD -P %XIP% mask 255.255.255.255 %GW% >> %LOG%
echo blat route %TESTDNS% was changed from %TESTIP% to %XIP% by script!
echo %TESTDNS% was changed from %TESTIP% to %XIP% by script! >> %LOG%
REM write it back to the testfile (which was reset above)
echo %TESTDNS%=%XIP% >> %DNSTESTFILE%
REM fill a log-var to report allover later in mail for example
set errorlog=%errorlog% : route %TESTDNS% was changed from %TESTIP% to %XIP% by script! :
)
if %XIP%==%TESTIP% (
REM if dns did not change
echo ip did not change
echo checking if route exist
REM now the gateway switch comes in, if set to 1 we check if route exist and if so we go on, otherwise we set the route again
if %REFRESH-GW% == 1 (
netsh interface ipv4 show route | find /i "%XIP%" >NUL
if errorlevel 1 (
Route ADD -P %XIP% mask 255.255.255.255 %GW% >> %LOG%
echo blat %XIP% route was deleted by unknown manipulation and reset by script!
echo %XIP% route was deleted by unknown manipulation and reset by script! >> %LOG%
set errorlog=%errorlog% : %XIP% route was deleted by unknown manipulation and reset by script! :
)
)
if %REFRESH-GW% == 2 (
REM here we check if route was deleted from elsewhere (and report it) but we set it anyway to make shure the gateway gets updated in case it was changed in the var on top
netsh interface ipv4 show route | find /i "%XIP%" >NUL
if errorlevel 1 (
echo blat %XIP% was deleted by unknown manipulation!
echo %XIP% was deleted by unknown manipulation! >> %LOG%
set errorlog=%errorlog% : %XIP% was deleted by unknown manipulation! :
)
REM first delete the old and then set the new route
Route DELETE %TESTIP% >> %LOG%
Route ADD -P %XIP% mask 255.255.255.255 %GW% >> %LOG%
echo blat route %TESTDNS% was reset by script!
)
REM we should not forget to write back the route to our testfile
echo %TESTDNS%=%XIP% >> %DNSTESTFILE%
)
REM now we tell ourself we are through on all should be fine with the address and route
netsh interface ipv4 show route | find /i "%XIP%" >NUL
if errorlevel 1 (
echo blat route %XIP% could not be set - ERROR setting route
echo route %XIP% could not be set - ERROR setting route >> %LOG%
set errorlog=%errorlog% : route %XIP% could not be set - ERROR setting route :
) else (
echo OKI
echo OK >> %LOG%
)
:EOF
这篇关于而写回新的IPS显示器定义DNS解析和变更路线的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！
查看全文
