使用INDY SMTPServer [英] Using INDY SMTPServer
问题描述
以下代码是我修改(使用10.5.8)形式的示例,以便使用 Indy邮件服务器
following code is what i modified(to work with 10.5.8) form the sample in order to send email independently using the smtp client described in Indy Mail server
以下是INDY smtpserver示例
following is from INDY smtpserver sample
procedure TForm1.btnServerOnClick(Sender: TObject);
begin
IdSMTPServer1.active := true;
end;
procedure TForm1.btnServerOffClick(Sender: TObject);
begin
IdSMTPServer1.active := false;
end;
procedure TForm1.IdSMTPServer1MailFrom(ASender: TIdSMTPServerContext;
const AAddress: string; AParams: TStrings; var VAction: TIdMailFromReply);
begin
// Here we are testing the MAIL FROM line sent to the server.
// MAIL FROM address comes in via AAddress. VAction sets the return action to the server.
// The following actions can be returned to the server:
{ mAccept, mReject }
// For now, we will just always allow the mail from address.
VAction := mAccept;
end;
procedure TForm1.IdSMTPServer1MsgReceive(ASender: TIdSMTPServerContext;
AMsg: TStream; var LAction: TIdDataReply);
var
LMsg : TIdMessage;
LStream : TFileStream;
begin
// When a message is received by the server, this event fires.
// The message data is made available in the AMsg : TStream.
// In this example, we will save it to a temporary file, and the load it using
// IdMessage and parse some header elements.
LStream := TFileStream.Create(ExtractFilePath(Application.exename) + 'test.eml', fmCreate);
Try
LStream.CopyFrom(AMsg, 0);
Finally
FreeAndNil(LStream);
End;
LMsg := TIdMessage.Create;
Try
LMsg.LoadFromFile(ExtractFilePath(Application.exename) + 'test.eml', False);
ToLabel.Caption := LMsg.Recipients.EMailAddresses;
FromLabel.Caption := LMsg.From.Text;
SubjectLabel.Caption := LMsg.Subject;
Memo1.Lines := LMsg.Body;
Finally
FreeAndNil(LMsg);
End;
end;
procedure TForm1.IdSMTPServer1UserLogin(ASender: TIdSMTPServerContext;
const AUsername, APassword: String; var VAuthenticated: Boolean);
begin
// This event is fired if a user attempts to login to the server
// Normally used to grant relay access to specific users etc.
VAuthenticated := True;
end;
procedure TForm1.IdSMTPServer1RcptTo(ASender: TIdSMTPServerContext;
const AAddress: string; AParams: TStrings; var VAction: TIdRCPToReply;
var VForward: string);
begin
VAction := rAddressOk;
end;
procedure TForm1.IdSMTPServer1Received(ASender: TIdSMTPServerContext;
var AReceived: string);
begin
//
end;
我必须添加到此项目中作为电子邮件发送服务器工作。
what do i have to add to this project to work as email sending server.
我没有对原始示例进行许多更改(仅用于兼容性),因为我无法理解电子邮件如何发送和接收的大多数概念。请说明如何使此代码发送电子邮件到此问题中给出的目的地(例如:someone@gmail.com) Indy邮件服务器(smtpclient),
I haven't done many changes to the original sample(only for compatibility) as i can't understand most of the concepts behind how email is sent and received. please explain me how to make this code to send email to the destination(eg: someone@gmail.com) given in this question Indy Mail server (smtpclient),
推荐答案
将电子邮件传递到另一个系统(在这种情况下为Gmail) ),使用 TIdSMTPRelay
组件,例如:
To pass the email on to another system (Gmail in this case), use the TIdSMTPRelay
component, eg:
procedure TForm1.IdSMTPServer1RcptTo(ASender: TIdSMTPServerContext;
const AAddress: string; AParams: TStrings; var VAction: TIdRCPToReply;
var VForward: string);
begin
if (AAddress represents a user in your network) then
VAction := rAddressOk
else if (AAddress is outside of your network) then
VAction := rWillForward;
end;
procedure TForm1.IdSMTPServer1MsgReceive(ASender: TIdSMTPServerContext; AMsg: TStream; var LAction: TIdDataReply);
var
LMsg : TIdMessage;
LMsgClient: TIdMessageClient;
LStream : TFileStream;
LRelayRecipients: TIdEMailAddressList;
LRelay: TIdSMTPRelay;
I: Integer;
begin
// When a message is received by the server, this event fires.
// The message data is made available in the AMsg : TStream.
// In this example, we will save it to a temporary file, and load it using
// IdMessage to parse some header elements.
LStream := TFileStream.Create(ExtractFilePath(Application.exename) + 'test.eml', fmCreate);
Try
LStream.CopyFrom(AMsg, 0);
Finally
LStream.Free;
End;
AMsg.Position := 0;
LMsg := TIdMessage.Create;
Try
//LMsg.LoadFromFile(ExtractFilePath(Application.exename) + 'test.eml', False);
// Do not use the TIdMessage.LoadFrom...() methods here! The email
// data contained in the AMsg stream does not escape leading periods
// on lines of text. That escaping is only used when the email was
// transmitted over the socket, as a period character has special
// meaning to the SMTP protocol. TIdSMTPServer removes the escaping
// from the data before firing this event. However, the LoadFrom...()
// methods (which uses TIdMessageClient internally) require the
// data to be escaped! This is a known limitation in Indy's core
// architecture and will be addressed in Indy 11. Until then,
// use TIdMessageClient manually so the necessary escaping can be
// re-introduced into the data while it is being parsed...
LMsgClient := TIdMessageClient.Create(nil);
try
LMsgClient.IOHandler := TIdIOHandlerStreamMsg.Create(LMsgClient, AMsg);
with TIdIOHandlerStreamMsg(LMsgClient.IOHandler) do
begin
FreeStreams := False;
EscapeLines := True;
end;
LMsgClient.IOHandler.Open;
LMsgClient.ProcessMessage(LMsg, False);
finally
LMsgClient.Free;
end;
// process LMsg as needed...
// save the email for local users and forward it to other SMTP servers as needed...
LRelayRecipients := nil;
try
for I := 0 to ASender.RCPTList.Count-1 do
begin
if (ASender.RCPTList[I] represents a user in your network) then
begin
// save AMsg in the user's mailbox somewhere on the local
// machine/network where an POP3/IMAP4 client can retreive
// it from later...
end else
begin
if not Assigned(LRelayRecipients) then LRelayRecipients := TIdEMailAddressList.Create(nil);
LRelayRecipients.Add.Assign(ASender.RCPTList[I]);
end;
end;
if Assigned(LRelayRecipients) then
begin
LRelay := TIdSMTPRelay.Create(nil);
try
// you must supply the IP/Host of a DNS server that
// will be used for determining the SMTP server of
// each recipient domain...
LRelay.DNSServer := ...;
LRelay.Send(LMsg, LRelayRecipients);
finally
LRelay.Free;
end;
end;
finally
LRelayRecipients.Free;
end;
Finally
LMsg.Free;
End;
end;
这篇关于使用INDY SMTPServer的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!