如何自动调整虚拟模式中列表视图的列宽？ [英] how auto size the columns width of a list view in virtual mode?

问题描述

当我使用TListView（ViewStyle = vsReport）时，我可以自动调整列的宽度，设置 LVSCW_AUTOSIZE 或 LVSCW_AUTOSIZE_USEHEADER 每列，现在我开始在虚拟模式下使用Listview，但不会根据这些值修改列的宽度。所以问题是：当lisvtiew处于虚拟模式时，我可以如何调整列的宽度以适合内容或标题？

When I use a TListView (ViewStyle = vsReport) I can autofit the width of the columns setting the LVSCW_AUTOSIZE or LVSCW_AUTOSIZE_USEHEADER values in the Width property of each column, now I start to use the Listview in virtual mode, but the width of the columns is not modified according to these values. So the question is : How I can adjust the width of the columns to fit to the content or header, when the lisvtiew is in virtual mode?

推荐答案

由于虚拟模式中的列表视图不提前知道项目标题（因为它只询问可见区域的数据），所以它也不知道最宽的一个的宽度，所以这就是为什么 <$ c的自动尺寸标记$ c> LVM_SETCOLUMNWIDTH 以这种方式行事。

Since the list view in virtual mode don't know the item captions in advance (because it asks only for data of the visible area) it also cannot know the width of the widest one, so that's the reason why the autosize flag of the LVM_SETCOLUMNWIDTH behaves this way.

因此，唯一的方法是编写一个自定义函数，它将查询所有数据，测量所有未来字幕的文本宽度，并将列宽设置为最宽的值。

Thus the only way is to write a custom function which will query all your data, measure the text widths of all future captions and set the column width to the value of the widest one.

以下示例显示如何执行它。它使用 ListView_GetStringWidth 宏的文本宽度计算（这似乎是最自然的方法）。但问题是文本填充的值。如文档中所述：

The following example shows how to do it. It uses the ListView_GetStringWidth macro for the text width calculations (it seems to be the most natural way to do this). However the problem is the value of the text padding. As it's stated in the documentation:

ListView_GetStringWidth宏返回指定字符串的确切宽度（以像素为单位）
。如果在调用ListView_SetColumnWidth宏时使用返回的字符串宽度作为
列宽，
字符串将被截断。要检索可以
包含字符串但不截断它的列宽度，您必须添加填充到
返回的字符串宽度。

The ListView_GetStringWidth macro returns the exact width, in pixels, of the specified string. If you use the returned string width as the column width in a call to the ListView_SetColumnWidth macro, the string will be truncated. To retrieve the column width that can contain the string without truncating it, you must add padding to the returned string width.

但是他们没有提到如何获取填充值（并且似乎 他们不会 这样做）。有人说（例如 这里 ），对于项目的填充使用6 px，子项的填充使用12像素，但它不是（至少在Windows 7中为此示例）。

But they didn't mention there how to get the padding value (and seems they won't to do so). Some people say (e.g. here) that it's enough to use 6 px for item's padding and 12 px for subitem's padding, but it isn't (at least for this example on Windows 7).

///////////////////////////////////////////////////////////////////////////////
/////   List View Column Autosize (Virtual Mode)   ////////////////////////////
///////////////////////////////////////////////////////////////////////////////

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, StdCtrls,
  Forms, Dialogs, StrUtils, ComCtrls, CommCtrl;

type
  TSampleRecord = record
    Column1: string;
    Column2: string;
    Column3: string;
  end;
  TSampleArray = array [0..49] of TSampleRecord;

type
  TForm1 = class(TForm)
    Button1: TButton;
    ListView1: TListView;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    SampleArray: TSampleArray;
    procedure AutoResizeColumn(const AListView: TListView;
      const AColumn: Integer);
    procedure OnListViewData(Sender: TObject; Item: TListItem);
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.AutoResizeColumn - auto-size column   //////////////////////////
///////////////////////////////////////////////////////////////////////////////

// AListView - list view object instance
// AColumn - index of the column to be auto-sized

procedure TForm1.AutoResizeColumn(const AListView: TListView;
  const AColumn: Integer);
var
  S: string;
  I: Integer;
  MaxWidth: Integer;
  ItemWidth: Integer;
begin
  // set the destination column width to the column's caption width
  // later on we'll check if we have a wider item
  MaxWidth := ListView_GetStringWidth(AListView.Handle,
    PChar(AListView.Columns.Items[AColumn].Caption));
  // iterate through all data items and check if their captions are
  // wider than the currently widest item if so then store that value
  for I := 0 to High(SampleArray) do
  begin
    case AColumn of
      0: S := SampleArray[I].Column1;
      1: S := SampleArray[I].Column2;
      2: S := SampleArray[I].Column3;
    end;
    ItemWidth := ListView_GetStringWidth(AListView.Handle, PChar(S));
    if MaxWidth < ItemWidth then
      MaxWidth := ItemWidth;
  end;
  // here is hard to say what value to use for padding to prevent the
  // string to be truncated; I've found the suggestions to use 6 px
  // for item caption padding and 12 px for subitem caption padding,
  // but a few quick tests confirmed me to use at least 7 px for items
  // and 14 px for subitems
  if AColumn = 0 then
    MaxWidth := MaxWidth + 7
  else
    MaxWidth := MaxWidth + 14;
  // and here we set the column width with caption padding included
  AListView.Columns.Items[AColumn].Width := MaxWidth;
end;

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.FormCreate - setup the list view and fill custom data   ////////
///////////////////////////////////////////////////////////////////////////////

procedure TForm1.FormCreate(Sender: TObject);
var
  I: Integer;
begin
  ListView1.ViewStyle := vsReport;
  ListView1.Columns.Add.Caption := 'Column 1';
  ListView1.Columns.Add.Caption := 'Column 2';
  ListView1.Columns.Add.Caption := 'Column 3';
  ListView1.OwnerData := True;
  ListView1.OnData := OnListViewData;
  ListView1.Items.Count := High(SampleArray);

  for I := 0 to High(SampleArray) do
  begin
    SampleArray[I].Column1 := 'Cell [0, ' + IntToStr(I) + '] ' +
      DupeString('x', I);
    SampleArray[I].Column2 := 'Cell [1, ' + IntToStr(I) + '] ' +
      DupeString('x', High(SampleArray) - I);
    SampleArray[I].Column3 := '';
  end;
end;

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.FormCreate - custom handler for OnData event   /////////////////
///////////////////////////////////////////////////////////////////////////////

procedure TForm1.OnListViewData(Sender: TObject; Item: TListItem);
begin
  Item.Caption := SampleArray[Item.Index].Column1;
  Item.SubItems.Add(SampleArray[Item.Index].Column2);
  Item.SubItems.Add(SampleArray[Item.Index].Column3);
end;

///////////////////////////////////////////////////////////////////////////////
/////   TForm1.Button1Click - auto-resize all 3 columns   /////////////////////
///////////////////////////////////////////////////////////////////////////////

procedure TForm1.Button1Click(Sender: TObject);
begin
  AutoResizeColumn(ListView1, 0);
  AutoResizeColumn(ListView1, 1);
  AutoResizeColumn(ListView1, 2);
end;

end.

这篇关于如何自动调整虚拟模式中列表视图的列宽？的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！