直接索引fortran函数返回值 [英] direct indexing on function return value in fortran
问题描述
是否可以直接在函数的返回值上使用索引?就像这样:
Is there posibility to use indexing directly on a function's return value? Something like this:
readStr()(2:5)
其中 readStr()
是一个返回字符串的函数。在其他许多语言中,这很可能,但Fortran呢?我的例子中的语法当然不会编译。是否还有其他语法可用?
where readStr()
is a function which returns a character string. In many other languages it is quite possible, but what about Fortran? The syntax in my example of course does not compile. Is there any other syntax to be used?
推荐答案
不,这在Fortran中不可行。然而,你可以改变你的函数来获取一个额外的索引数组,以确定返回哪些元素。这个例子说明了这种可能性,使用一个接口来允许一个可选的索引规范(简化得非常感谢IanH的评论):
No, that is not possible in Fortran. You could, however, alter your function to take an additional index array that determines which elements are returned. This example illustrates this possibility using an interface to allow for an optional specification of the indices (simplified greatly thanks to the comment by IanH):
module test_mod
implicit none
contains
function squareOpt( arr, idx ) result(res)
real, intent(in) :: arr(:)
integer, intent(in), optional :: idx(:)
real,allocatable :: res( : )
real :: res_( size(arr) )
integer :: stat
! Calculate as before
res_ = arr*arr
if ( present(idx) ) then
! Take the sub-set
allocate( res(size(idx)), stat=stat )
if ( stat /= 0 ) stop 'Cannot allocate memory!'
res = res_(idx)
else
! Take the the whole array
allocate( res(size(arr)), stat=stat )
if ( stat /= 0 ) stop 'Cannot allocate memory!'
res = res_
endif
end function
end module
program test
use test_mod
implicit none
real :: arr(4)
integer :: idx(2)
arr = [ 1., 2., 3., 4. ]
idx = [ 2, 3]
print *, 'w/o indices',squareOpt(arr)
print *, 'w/ indices',squareOpt(arr, idx)
end program
这篇关于直接索引fortran函数返回值的文章就介绍到这了,希望我们推荐的答案对大家有所帮助,也希望大家多多支持IT屋!