Inno Setup：扩展Windows默认应用列表 [英] Inno Setup: Extending Windows default apps list

问题描述

如何在Windows默认应用列表中列出我的应用程序？

我有一个特殊的基于Java的视频播放器应用程序，其中包含由Inno Setup创建的安装程序。我希望我的应用程序列在Windows 10上的可选视频播放器列表中（我也不知道如何使用较旧的Windows版本）。

解决方案

有关一般信息，请参阅：

• 
  
  
  
  

  How is it possible to have listed my application on the Windows default apps list?

  I have a special Java based video player application with an installer created by Inno Setup. I want my application to be listed on the selectable video players list on Windows 10 (I also don't know how to do it with older Windows versions).

  解决方案

  For generic information, see:

  • Registering an Application for Use with Default Programs on MSDN.
  • How do I add my application in the Default Programs list of Windows Vista/7? on Stack Overflow

  In Inno Setup, you implement this using [Registry] section:

  [Registry]
  ; Create the application capability key
  Root: HKLM; Subkey: "Software\My Company"; Flags: uninsdeletekeyifempty
  Root: HKLM; Subkey: "Software\My Company\My Program"; Flags: uninsdeletekeyifempty
  Root: HKLM; Subkey: "Software\My Company\My Program\Capability"; \
      ValueType: string; ValueName: "ApplicationDescription"; \
      ValueData: "This is My Program that does stuff"; Flags: uninsdeletevalue
  Root: HKLM; Subkey: "Software\My Company\My Program\Capability"; \
      ValueType: string; ValueName: "ApplicationName"; ValueData: "My Program"; \
      Flags: uninsdeletevalue
  ; List of extensions the application supports
  Root: HKLM; Subkey: "Software\My Company\My Program\Capability\FileAssociations"; \
      ValueType: string; ValueName: ".jpg"; ValueData: "MyProgram.JPEG"; \
      Flags: uninsdeletevalue
  
  ; Add the capability key to list of registered applications
  Root: HKLM; Subkey: "Software\RegisteredApplications"; \
      ValueType: string; ValueName: "My Program"; \
      ValueData: "Software\My Company\My Program\Capability"; \
      Flags: uninsdeletevalue
  
  ; For each extension that the application supports
  Root: HKCR; Subkey: "MyProgram.JPEG"; Flags: uninsdeletekeyifempty
  Root: HKCR; Subkey: "MyProgram.JPEG"; \
      ValueType: string; ValueName: ""; ValueData: "MyProgram JPEG"; Flags: uninsdeletevalue
  Root: HKCR; Subkey: "MyProgram.JPEG\DefaultIcon"; Flags: uninsdeletekeyifempty
  Root: HKCR; Subkey: "MyProgram.JPEG\DefaultIcon"; \
      ValueType: string; ValueName: ""; ValueData: "{app}\MyProg.exe,1"; \
      Flags: uninsdeletevalue
  Root: HKCR; Subkey: "MyProgram.JPEG\Shell"; Flags: uninsdeletekeyifempty
  Root: HKCR; Subkey: "MyProgram.JPEG\Shell\open"; Flags: uninsdeletekeyifempty
  Root: HKCR; Subkey: "MyProgram.JPEG\Shell\open\Command"; Flags: uninsdeletekeyifempty
  Root: HKCR; Subkey: "MyProgram.JPEG\Shell\open\Command"; \
      ValueType: string; ValueName: ""; ValueData: """{app}\MyProg.exe"" ""%1"""; \
      Flags: uninsdeletevalue
  

  这篇关于Inno Setup：扩展Windows默认应用列表的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！