扩展圆形AS3时如何创建多种颜色? [英] How to create multiple colors when expanding circle shape AS3?

问题描述

所以我试图弄清楚如何做到这一点，甚至可能的话.我通过代码动态创建我的圆形形状，并希望能够在mouse_UP上使圆形停止，并在触发mouse_DOWN时使圆形保持扩展，但具有新的颜色.等等，每次都添加新的颜色.我将代码设置为在mouse_DOWN上展开的位置，它更改了颜色，但更改了整个圆圈的颜色，这不是我想要的.

So I am trying to figure out how to do this or if even possible. I create my circle shape dynamically through code and want to be able upon mouse_UP have the circle stop and when the mouse_DOWN is triggered have the circle keep expanding but with a new color. So on and so on adding new colors every time. I have the code setup to where it expands on mouse_DOWN and it changes color but it changes the whole circle color which is not what I want.

这是我的代码:

//创建圈子

//MC's 
        circle = new Shape();
        circle.graphics.beginFill(0x990000, 1); // Fill the circle with the color 990000
        circle.graphics.drawCircle((stage.stageWidth) / 2, (stage.stageHeight ) / 2, cirRadius); // Draw the circle, assigning it a x position, y position, raidius.
        circle.graphics.endFill(); // End the filling of the circle
        addChild(circle); // Add a child

//输入框架功能

private function logicHandler(e:Event):void 
    {
        if (bDown)  // Have New color Expand from prev point with new color
        {
            cirRadius ++;
            circle.graphics.beginFill(randColor, 1); // Fill the circle with the color 990000
            circle.graphics.drawCircle((stage.stageWidth) / 2, (stage.stageHeight ) / 2, cirRadius);

        }
    }

//鼠标监听器

private function onUp(e:MouseEvent):void 
    {
        bUp = true;
        bDown = false;
        trace("onUp");
        circle.graphics.endFill();
    }

    private function onDown(e:MouseEvent):void 
    {
        bDown = true;
        bUp = false;
        trace("onDOWN");
        randColor = Math.random() * 0xFFFFFF;
    }

这是我的目标:

推荐答案

此处需要一些逻辑.未经测试，但我认为它可以工作.

You need a bit of logic here. Not tested, but I think it'll work.

var aColor:uint;
var aRadius:int;
var aShape:Shape;

// Subscribe for MOUSE_DOWN event.
stage.addEventListener(MouseEvent.MOUSE_DOWN, onDown);

function onDown(e:MouseEvent):void
{
    // Set up the new color.
    changeColor();

    // Set up the new circle and assign its reference to the variable.
    // The previous shape, if any, doesn't get destroyed,
    // just no longer accessible via the same variable.
    aShape = new Shape;
    aShape.x = stage.stageWidth / 2;
    aShape.y = stage.stageHeight / 2;
    aShape.graphics.lineStyle(0, 0x000000);

    // Put it UNDER all the other circles.
    addChildAt(aShape, 0);

    // Turn ENTER_FRAME handler on.
    addEventListener(Event.ENTER_FRAME, onFrame);

    // Prepare to intercept the MOUSE_UP event.
    stage.addEventListener(MouseEvent.MOUSE_UP, onUp);
}

function onFrame(e:Event):void
{
    // Increase the radius.
    aRadius++;

    // Draw the circle inside the last added shape.
    aShape.graphics.clear();
    aShape.graphics.beginFill(aColor);
    aShape.graphics.drawCircle(0, 0, aRadius);
    aShape.graphics.endFill();
}

function onUp(e:MouseEvent):void
{
    // Turn ENTER_FRAME handler OFF.
    removeEventListener(Event.ENTER_FRAME, onFrame);

    // Stop intercepting the MOUSE_UP event.
    stage.removeEventListener(MouseEvent.MOUSE_UP, onUp);
}

function changeColor():void
{
    aColor = 0x1000000 * Math.random();
}

这篇关于扩展圆形AS3时如何创建多种颜色?的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！