WebGL GLSL片段着色器无法在iOS上使用 [英] WebGL GLSL fragment shader not working on iOS

问题描述

我正在使用此处的经典Perlin Noise(vec3)函数. a>.

I am using the Classic Perlin Noise (vec3) functions from here.

当我在MacBook上渲染此着色器时，该着色器运行良好，并按照我期望的颜色显示了噪波.

When I render this shader on my MacBook, the shader runs fine and shows the noise as color like I expect.

当我在iPhone上渲染此着色器时，画布完全是黑色的.

When I render this shader on my iPhone, the canvas is totally black.

此代码是否存在任何错误，会导致cnoise函数始终返回0?还是有些功能不适用于Metal?

Is there anything wrong with this code that would cause the cnoise function to return 0 always? Or is there some function that does not work with Metal?

这是完整的着色器:

#ifdef GL_ES
precision mediump float;
#endif

uniform vec2 u_resolution;
uniform float u_time;

vec4 permute(vec4 x){return mod(((x*34.0)+1.0)*x, 289.0);}
vec4 taylorInvSqrt(vec4 r){return 1.79284291400159 - 0.85373472095314 * r;}
vec3 fade(vec3 t) {return t*t*t*(t*(t*6.0-15.0)+10.0);}

float cnoise(vec3 P){
  vec3 Pi0 = floor(P); // Integer part for indexing
  vec3 Pi1 = Pi0 + vec3(1.0); // Integer part + 1
  Pi0 = mod(Pi0, 289.0);
  Pi1 = mod(Pi1, 289.0);
  vec3 Pf0 = fract(P); // Fractional part for interpolation
  vec3 Pf1 = Pf0 - vec3(1.0); // Fractional part - 1.0
  vec4 ix = vec4(Pi0.x, Pi1.x, Pi0.x, Pi1.x);
  vec4 iy = vec4(Pi0.yy, Pi1.yy);
  vec4 iz0 = Pi0.zzzz;
  vec4 iz1 = Pi1.zzzz;

  vec4 ixy = permute(permute(ix) + iy);
  vec4 ixy0 = permute(ixy + iz0);
  vec4 ixy1 = permute(ixy + iz1);

  vec4 gx0 = ixy0 / 7.0;
  vec4 gy0 = fract(floor(gx0) / 7.0) - 0.5;
  gx0 = fract(gx0);
  vec4 gz0 = vec4(0.5) - abs(gx0) - abs(gy0);
  vec4 sz0 = step(gz0, vec4(0.0));
  gx0 -= sz0 * (step(0.0, gx0) - 0.5);
  gy0 -= sz0 * (step(0.0, gy0) - 0.5);

  vec4 gx1 = ixy1 / 7.0;
  vec4 gy1 = fract(floor(gx1) / 7.0) - 0.5;
  gx1 = fract(gx1);
  vec4 gz1 = vec4(0.5) - abs(gx1) - abs(gy1);
  vec4 sz1 = step(gz1, vec4(0.0));
  gx1 -= sz1 * (step(0.0, gx1) - 0.5);
  gy1 -= sz1 * (step(0.0, gy1) - 0.5);

  vec3 g000 = vec3(gx0.x,gy0.x,gz0.x);
  vec3 g100 = vec3(gx0.y,gy0.y,gz0.y);
  vec3 g010 = vec3(gx0.z,gy0.z,gz0.z);
  vec3 g110 = vec3(gx0.w,gy0.w,gz0.w);
  vec3 g001 = vec3(gx1.x,gy1.x,gz1.x);
  vec3 g101 = vec3(gx1.y,gy1.y,gz1.y);
  vec3 g011 = vec3(gx1.z,gy1.z,gz1.z);
  vec3 g111 = vec3(gx1.w,gy1.w,gz1.w);

  vec4 norm0 = taylorInvSqrt(vec4(dot(g000, g000), dot(g010, g010), dot(g100, g100), dot(g110, g110)));
  g000 *= norm0.x;
  g010 *= norm0.y;
  g100 *= norm0.z;
  g110 *= norm0.w;
  vec4 norm1 = taylorInvSqrt(vec4(dot(g001, g001), dot(g011, g011), dot(g101, g101), dot(g111, g111)));
  g001 *= norm1.x;
  g011 *= norm1.y;
  g101 *= norm1.z;
  g111 *= norm1.w;

  float n000 = dot(g000, Pf0);
  float n100 = dot(g100, vec3(Pf1.x, Pf0.yz));
  float n010 = dot(g010, vec3(Pf0.x, Pf1.y, Pf0.z));
  float n110 = dot(g110, vec3(Pf1.xy, Pf0.z));
  float n001 = dot(g001, vec3(Pf0.xy, Pf1.z));
  float n101 = dot(g101, vec3(Pf1.x, Pf0.y, Pf1.z));
  float n011 = dot(g011, vec3(Pf0.x, Pf1.yz));
  float n111 = dot(g111, Pf1);

  vec3 fade_xyz = fade(Pf0);
  vec4 n_z = mix(vec4(n000, n100, n010, n110), vec4(n001, n101, n011, n111), fade_xyz.z);
  vec2 n_yz = mix(n_z.xy, n_z.zw, fade_xyz.y);
  float n_xyz = mix(n_yz.x, n_yz.y, fade_xyz.x);
  return 2.2 * n_xyz;
}

float map(float s, float a1, float a2, float b1, float b2) {
  return b1 + (s - a1) * (b2 - b1) / (a2 - a1);
}

void main() {
  vec2 st = gl_FragCoord.xy / u_resolution.xy;

  float r = cnoise(vec3(st.x, st.y, u_time / 1.0));
  float g = cnoise(vec3(st.x + 100.0, st.y + 100.0, u_time / 1.0));
  float b = cnoise(vec3(st.x + 200.0, st.y + 200.0, u_time / 1.0));

  r = map(r, -1.0, 1.0, 0.0, 1.0);
  g = map(g, -1.0, 1.0, 0.0, 1.0);
  b = map(b, -1.0, 1.0, 0.0, 1.0);

  vec3 color = vec3(r, g, b);
  // vec3 color = vec3(r, 1.0, 1.0);

  gl_FragColor = vec4(color, 1.0);
}

推荐答案

gman在上面贴了它，但问题出在浮点精度上.

gman posted it above but the problem was with floating point precision.

mediump不起作用，highp完全按预期工作.

mediump wouldn't work, highp worked exactly as expected.

谢谢！

这篇关于WebGL GLSL片段着色器无法在iOS上使用的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！