我的语法怎么了 [英] What's wrong with my grammar

问题描述

我尝试将以下内容输入到我的yacc解析器中:

I try to input the following into my yacc parser:

int main(void)
{
return;
}

根据yacc文件中定义的内容，它对我来说似乎有效，但是返回后我收到语法错误"消息.为什么会这样?

It looks valid to me according to what's defined in the yacc file, but I get a "syntax error" message after the return. Why is that?

yacc文件:

/* C-Minus BNF Grammar */
%{
#include "parser.h"
#include <string.h>
%}
%union 
{
    int intval;
    struct symtab *symp;
}

%token ELSE
%token IF
%token INT
%token RETURN
%token VOID
%token WHILE

%token <symp> ID
%token <intval> NUM

%token LTE
%token GTE
%token EQUAL
%token NOTEQUAL

type <string> paramlist


%%

program : declaration_list ; 

declaration_list : declaration_list declaration | declaration ;

declaration : var_declaration 
            | fun_declaration 
            | '$' { printTable();};

var_declaration : type_specifier ID ';' {$2->value = 0; $2->arraysize = 0;};
                | type_specifier ID '[' NUM ']' ';' {$2->arraysize = $4;printf("Array size is %d", $2->arraysize);} ;

type_specifier : INT | VOID ;

fun_declaration : type_specifier ID '(' params ')' compound_stmt {printf("function declaration\n"); $2->args = 'a'; printf("Parameters: \n", $2->args); } ;


params : param_list | VOID ;

param_list : param_list ',' param
           | param ;

param : type_specifier ID | type_specifier ID '[' ']' ;

compound_stmt : '{' local_declarations statement_list '}' {printf("exiting scope\n"); } ;

local_declarations : local_declarations var_declaration
                   | /* empty */ ;

statement_list : statement_list statement
               | /* empty */ ;

statement : expression_stmt
          | compound_stmt
          | selection_stmt
          | iteration_stmt
          | return_stmt ;

expression_stmt : expression ';'
                | ';' ;

selection_stmt : IF '(' expression ')' statement
               | IF '(' expression ')' statement ELSE statement ;

iteration_stmt : WHILE '(' expression ')' statement ;

return_stmt : RETURN ';' | RETURN expression ';' ;

expression : var '=' expression | simple_expression ;

var : ID | ID '[' expression ']' ;

simple_expression : additive_expression relop additive_expression
                  | additive_expression ;

relop : LTE | '<' | '>' | GTE | EQUAL | NOTEQUAL ;

additive_expression : additive_expression addop term | term ;

addop : '+' | '-' ;

term : term mulop factor | factor ;

mulop : '*' | '/' ;

factor : '(' expression ')' | var | call | NUM ;

call : ID '(' args ')' ;

args : arg_list | /* empty */ ;

arg_list : arg_list ',' expression | expression ;

%%
/* look up a symbol table entry, add if not present */
struct symtab *symlook(char *s) {

    printf("Putting %s into the symbol table\n", s);
    //char *p;
    struct symtab *sp;
    for(sp = symtab; sp < &symtab[NSYMS]; sp++) {
        /* is it already here? */
        if(sp->name && !strcmp(sp->name, s))
        {
            yyerror("already in symbol table\n");
            exit(1);
            return sp;
        }
        if(!sp->name) { /* is it free */
            sp->name = strdup(s);
            return sp;
        }
        /* otherwise continue to next */
    }
    yyerror("Too many symbols");
    exit(1); /* cannot continue */
} /* symlook */
yyerror(char *s)
{
    printf( "yyerror: %s\n", s);
}

printTable()
{
    printf("Print out the symbol table:\n\n");

    struct symtab *sp;
    for(sp = symtab; sp < &symtab[NSYMS]; sp++) 
    {
        printf("name: %s\t"
                "args: %s\t"
                "value %d\t"
                "arraysize %d\n", 
                sp->name, 
                sp->args, 
                sp->value, 
                sp->arraysize);
    }


}

推荐答案

您的yacc语法文件看不到任何错误；我最好的猜测是您的扫描仪没有正确返回RETURN令牌.如果我与一起编译您的yacc源码

I can't see anything wrong with your yacc grammar file; my best guess is that your scanner isn't returning the RETURN token properly. If I compile your yacc source along with

parser.h

#define NSYMS   100
struct symtab {
    char    *name;
    int     value;
    int     arraysize;
    char    *args;
} symtab[NSYMS];

scanner.l

%{
#include "parser.tab.h"
extern struct symtab *symlook(char *);
extern void printTable();
%}
%option noyywrap

NUM [0-9][0-9]*
ID  [_a-zA-Z][_a-zA-Z0-9]*

%%

else   return ELSE;
if     return IF;
int    return INT;
return return RETURN;
void   return VOID;
while  return WHILE;
"=="   return EQUAL;
"!="   return NOTEQUAL;
">="   return LTE;
"<="   return GTE;
[ \t\n]  ;
{NUM}  { yylval.intval = atoi(yytext); return NUM; }
{ID}   { yylval.symp = symlook(yytext); return ID; }
.      return *yytext;

%%

int main()
{
    yyparse();
    printTable();
    return 0;
}

然后它接受您的示例程序，并且没有错误，并且仅使用 main 符号

Then it accepts your example program just fine with no errors, and prints out the symbol table with just the main symbol

这篇关于我的语法怎么了的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！