通过Excel自动执行IE，以填写下拉菜单并继续 [英] Automate IE via Excel to fill in a dropdown and continue

问题描述

诚然仍然是通过Excel自动化IE的新手，但希望任何人都可以提供与此相关的帮助.基本上，这将打开一个网页，选择一个按钮，填写2个下拉菜单，输入一个值，然后按另一个按钮显示我需要的内容.我确实通过将SendKeys与一堆{Tabs}，{`}，{Down}等一起使用来完成这项工作，但它相当笨拙.我宁愿以正确的方式执行此操作，但只能进入第一个下拉菜单，选择所需的值，然后它停止.我想，我所缺少的是告诉IE接受我输入的内容并继续.编码如下.包含注释，以显示它在做什么以及它在哪里停止.

Admittedly still a newbie with automating IE via Excel but would appreciate whatever help anyone can offer with this. Basically, this opens up a webpage, selects a button, fills in 2 dropdowns, enters a value and then presses another button to display what I need. I do have this working using SendKeys with a bunch of {Tabs}, {`}, {Down}, etc but it's rather clunky. I'd rather do this the right way but I can only get to the 1st dropdown, select the value that I need and then it stops. What I'm missing, I guess, is telling IE to accept what I've entered and continue on. Coding is below. Comments included to show what it's doing and where it stops.

Dim WebIDStr As String: WebIDStr = "CD00003630"
Dim IE As Object
WebNavStr = "https://a810-dobnow.nyc.gov/Publish/#!/"
On Error Resume Next
Set IE = Nothing
Set IE = CreateObject("InternetExplorer.Application")
With IE
    .Visible = True
    .navigate WebNavStr
    Do Until .readyState = 4: DoEvents: Loop
End With
' Won't work without a delay??
Application.Wait (Now + TimeValue("00:00:03"))
IE.document.getElementsByClassName("white ng-scope")(3).Click
' the next command works and fills-in the dropdown with the value
' that I need but then locks up. Can't move on from here.
IE.document.getElementById("DeviceOptions").selectedIndex = 4
' GOOD to HERE. Tried the next 2 lines but they don't do anything, unfortunately
IE.document.getElementById("DeviceOptions").Focus
IE.document.getElementById("DeviceOptions").Click
' This is where I need to get to. Next Dropdown Value = 1
IE.document.getElementById("craneDeviceOption").selectedIndex = 1
' Once 2nd dropdown selected, fill in "DevCraneID" box
IE.document.getElementById("DevCraneID").Value = WebIDStr
' Press the "Select" button
IE.document.getElementById("Search4")(0).Click
' IE.Quit
' Set IE = Nothing

推荐答案

好吧，因为您写的是想了解它的工作原理，所以我对整个代码进行了详细的注释.

Ok, because you wrote you want to understand how it works I have commented the whole code by detail.

这是工作代码:

Sub DeviceSearch()

  'Define constants
  Const url As String = "https://a810-dobnow.nyc.gov/Publish/#!/"
  
  'Declare variables
  Dim ie As Object
  Dim htmlDoc As Object
  Dim nodeDeviceTypeDropdown As Object
  Dim nodeCraneDeviceDropdown As Object
  Dim nodeCraneDeviceID As Object
  
  Dim searchTerm As String
  
  'Initialize variables
  searchTerm = "CD00003630" 'craneID
  
  'Initialize Internet Explorer, set visibility,
  'call URL and wait until page is fully loaded
  Set ie = CreateObject("InternetExplorer.Application")
  ie.Visible = True
  ie.navigate url
  Do Until ie.readyState = 4: DoEvents: Loop
  'Wait to load dynamic content after IE reports it's ready
  Application.Wait (Now + TimeSerial(0, 0, 3))
  'Shorten html document string for lazy coders ;-)
  'Seriously: You can of course also use "With ie.document"
  Set htmlDoc = ie.document
  
  'Open the Device Search section
  htmlDoc.getElementsByClassName("white ng-scope")(3).Click
  
  'Try to get the first dropdown.
  'Never use "On Error Resume Next" for the whole code.
  'We use it here because if an html id can't be found
  'a runtime error occours. But after the critical part
  'we switch the error detection back on with "On Error GoTo 0"
  '(I use this here only to show you what to do if not sure if
  'you can get an element by id. In this case it's not realy
  'requiered because we can assume the dropdown is present.)
  On Error Resume Next
  Set nodeDeviceTypeDropdown = htmlDoc.getElementById("DeviceOptions")
  On Error GoTo 0
  
  'Now we can check if the dropdown element was found
  'If an object variable has no value it is "Nothing"
  'To check if it has a value we must check if it's
  '"Not" "Nothing"
  'You can use this mechanism for every object variable
  'in VBA
  If Not nodeDeviceTypeDropdown Is Nothing Then
    'Select the wanted dropdown entry
    nodeDeviceTypeDropdown.selectedIndex = 4
    
    'To make the selection work you must trigger the
    'html change event of the dropdown
    Call TriggerEvent(htmlDoc, nodeDeviceTypeDropdown, "change")
    
    'Give time to generate the code for the second dropdown
    Application.Wait (Now + TimeSerial(0, 0, 1))
  Else
    'Dropdown not found
    MsgBox "The Dropdown for Device Search was not found"
    'Stop makro
    Exit Sub
  End If
  
  'Here we can use the second dropdown "Search Crane Device"
  'We do it from here without error handling
  Set nodeCraneDeviceDropdown = htmlDoc.getElementById("craneDeviceOption")
  'Select the wanted dropdown entry
  nodeCraneDeviceDropdown.selectedIndex = 1
  'Trigger the change event of this dropdown
  Call TriggerEvent(htmlDoc, nodeCraneDeviceDropdown, "change")
  'Give time to generate the code for the text field
  Application.Wait (Now + TimeSerial(0, 0, 1))
    
  'Now we have the text field present and can enter the search term (craneID)
  'Get the html input element
  Set nodeCraneDeviceID = htmlDoc.getElementById("DevCraneDeviceID")
  '
  'It is not enough to enter the ID. The input field also has html events
  'that must be triggered so that the entered value is not only displayed
  'but also taken over to submit.
  'We have to embed the entering of the crane id in the both events
  '"compositionstart" and "compositionend"
  Call TriggerEvent(htmlDoc, nodeCraneDeviceID, "compositionstart")
  nodeCraneDeviceID.Value = searchTerm
  Call TriggerEvent(htmlDoc, nodeCraneDeviceID, "compositionend")
  
  'Click the submit button
  htmlDoc.getElementById("search4").Click
  
  'Give time to load the result page
  Application.Wait (Now + TimeSerial(0, 0, 5))
  
  'Do here what you want with the result
  '...
End Sub

这是触发html事件的过程

Private Sub TriggerEvent(htmlDocument As Object, htmlElementWithEvent As Object, eventType As String)

  Dim theEvent As Object

  htmlElementWithEvent.Focus
  Set theEvent = htmlDocument.createEvent("HTMLEvents")
  theEvent.initEvent eventType, True, False
  htmlElementWithEvent.dispatchEvent theEvent
End Sub

这是FireFox html检查器的两个屏幕快照，其中包含元素的事件
如果您不知道需要哪个事件，则必须尝试直到它起作用;-)

Here are two screenshots from FireFox html inspector with the events of the elements
If you don't know which event(s) are needed you must try till it works ;-)

页面上已使用下拉菜单的所有事件

页面上已使用输入字段的事件

这篇关于通过Excel自动执行IE，以填写下拉菜单并继续的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！