如何使用awk处理文件 [英] How to treat a file use awk

问题描述

我想使用 awk 读取文件，但是我被卡在第四个字段上，该字段在逗号后会自动中断.

I want to read a file using awk but I got stuck on fourth field where it automatically breaks after a comma.

数据:-test.txt

Data:- test.txt

"A","B","ls","This,is,the,test"
"k","O","mv","This,is,the,2nd test"
"C","J","cd","This,is,the,3rd test"

cat test.txt | awk -F , '{ OFS="|" ;print $2 $3 $4 }'

输出

"B"|"ls"|"This
"O"|"mv"|"This
"J"|"cd"|"This

但是输出应该是这样

"B"|"ls"|"This,is,the,test"
"O"|"mv"|"This,is,the,2nd test"
"J"|"cd"|"This,is,the,3rd test"

任何想法

推荐答案

将GNU awk用于FPAT:

Use GNU awk for FPAT:

$ awk -v FPAT='([^,]+)|(\"[^\"]+\")' -v OFS='|' '{print $2,$3,$4}' file
"B"|"ls"|"This,is,the,test"
"O"|"mv"|"This,is,the,2nd test"
"J"|"cd"|"This,is,the,3rd test"

请参见 http://www.gnu.org/software/gawk/manual/gawk.html#Splitting-By-Content

您会做其他的事情:

$ cat tst.awk
BEGIN { OFS="|" }
{
    nf=0
    delete f
    while ( match($0,/([^,]+)|(\"[^\"]+\")/) ) {
        f[++nf] = substr($0,RSTART,RLENGTH)
        $0 = substr($0,RSTART+RLENGTH)
    }
    print f[2], f[3], f[4]
}

$ awk -f tst.awk file
"B"|"ls"|"This,is,the,test"
"O"|"mv"|"This,is,the,2nd test"
"J"|"cd"|"This,is,the,3rd test"

这篇关于如何使用awk处理文件的文章就介绍到这了，希望我们推荐的答案对大家有所帮助，也希望大家多多支持IT屋！